MPUI_Setup.nsi

   1 ; ///////////////////////////////////////////////////////////////////////////////
   2 ; // MPlayer for Windows - Install Script
   3 ; // Copyright (C) 2004-2018 LoRd_MuldeR <MuldeR2@GMX.de>
   4 ; //
   5 ; // This program is free software; you can redistribute it and/or modify
   6 ; // it under the terms of the GNU General Public License as published by
   7 ; // the Free Software Foundation; either version 2 of the License, or
   8 ; // (at your option) any later version.
   9 ; //
  10 ; // This program is distributed in the hope that it will be useful,
  11 ; // but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 ; // MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 ; // GNU General Public License for more details.
  14 ; //
  15 ; // You should have received a copy of the GNU General Public License along
  16 ; // with this program; if not, write to the Free Software Foundation, Inc.,
  17 ; // 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  18 ; //
  19 ; // http://www.gnu.org/licenses/gpl-2.0.txt
  20 ; ///////////////////////////////////////////////////////////////////////////////
  21
  22
  23 ;--------------------------------------------------------------------------------
  24 ; BASIC DEFINES
  25 ;--------------------------------------------------------------------------------
  26
  27 !ifndef NSIS_UNICODE
  28   !error "NSIS_UNICODE is undefined, please compile with Unicode NSIS !!!"
  29 !endif
  30
  31 !ifndef MPLAYER_BUILDNO
  32   !error "MPLAYER_BUILDNO is not defined !!!"
  33 !endif
  34
  35 !ifndef MPLAYER_REVISION
  36   !error "MPLAYER_REVISION is not defined !!!"
  37 !endif
  38
  39 !ifndef MPLAYER_DATE
  40   !error "MPLAYER_DATE is not defined !!!"
  41 !endif
  42
  43 !ifndef SMPLAYER_VERSION
  44   !error "SMPLAYER_VERSION is not defined !!!"
  45 !endif
  46
  47 !ifndef MPUI_VERSION
  48   !error "MPUI_VERSION is not defined !!!"
  49 !endif
  50
  51 !ifndef CODECS_DATE
  52   !error "CODECS_DATE is not defined !!!"
  53 !endif
  54
  55 !ifndef MPLAYER_OUTFILE
  56   !error "MPLAYER_OUTFILE is not defined !!!"
  57 !endif
  58
  59 !ifndef UPX_PATH
  60   !error "UPX_PATH is not defined !!!"
  61 !endif
  62
  63 ; UUID
  64 !define MPlayerRegPath "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\{97D341C8-B0D1-4E4A-A49A-C30B52F168E9}"
  65
  66 ; Web-Site
  67 !define MPlayerWebSite "http://mplayerhq.hu/"
  68
  69
  70 ;--------------------------------------------------------------------------------
  71 ; INSTALLER ATTRIBUTES
  72 ;--------------------------------------------------------------------------------
  73
  74 RequestExecutionLevel admin
  75 ShowInstDetails show
  76 ShowUninstDetails show
  77
  78 Name "$(MPLAYER_LANG_MPLAYER_WIN32) ${MPLAYER_DATE} (Build #${MPLAYER_BUILDNO})"
  79 Caption "$(MPLAYER_LANG_MPLAYER_WIN32) ${MPLAYER_DATE} (Build #${MPLAYER_BUILDNO})"
  80 BrandingText "MPlayer-Win32 (Build #${MPLAYER_BUILDNO})"
  81 InstallDir "$PROGRAMFILES\MPlayer for Windows"
  82 InstallDirRegKey HKLM "${MPlayerRegPath}" "InstallLocation"
  83 OutFile "${MPLAYER_OUTFILE}"
  84
  85
  86 ;--------------------------------------------------------------------------------
  87 ; COMPRESSOR
  88 ;--------------------------------------------------------------------------------
  89
  90 SetCompressor /SOLID /FINAL LZMA
  91 SetCompressorDictSize 112
  92
  93 !tempfile PACKHDRTEMP
  94 !packhdr "${PACKHDRTEMP}" '"Utils\MT.exe" -manifest "Resources\Setup.manifest" -outputresource:"${PACKHDRTEMP};1"'
  95
  96 !packhdr "$%TEMP%\exehead.tmp" '"${UPX_PATH}\upx.exe" --brute "$%TEMP%\exehead.tmp"'
  97
  98
  99 ;--------------------------------------------------------------------------------
 100 ; RESERVE FILES
 101 ;--------------------------------------------------------------------------------
 102
 103 ReserveFile "${NSISDIR}\Plugins\Aero.dll"
 104 ReserveFile "${NSISDIR}\Plugins\Banner.dll"
 105 ReserveFile "${NSISDIR}\Plugins\CPUFeatures.dll"
 106 ReserveFile "${NSISDIR}\Plugins\InstallOptions.dll"
 107 ReserveFile "${NSISDIR}\Plugins\LangDLL.dll"
 108 ReserveFile "${NSISDIR}\Plugins\LockedList.dll"
 109 ReserveFile "${NSISDIR}\Plugins\LockedList64.dll"
 110 ReserveFile "${NSISDIR}\Plugins\nsDialogs.dll"
 111 ReserveFile "${NSISDIR}\Plugins\nsExec.dll"
 112 ReserveFile "${NSISDIR}\Plugins\StartMenu.dll"
 113 ReserveFile "${NSISDIR}\Plugins\StdUtils.dll"
 114 ReserveFile "${NSISDIR}\Plugins\System.dll"
 115 ReserveFile "${NSISDIR}\Plugins\UserInfo.dll"
 116 ReserveFile "Dialogs\Page_CPU.ini"
 117 ReserveFile "Resources\Splash.gif"
 118
 119
 120 ;--------------------------------------------------------------------------------
 121 ; INCLUDES
 122 ;--------------------------------------------------------------------------------
 123
 124 !include `MUI2.nsh`
 125 !include `InstallOptions.nsh`
 126 !include `WinVer.nsh`
 127 !include `x64.nsh`
 128 !include `StrFunc.nsh`
 129 !include `StdUtils.nsh`
 130 !include `CPUFeatures.nsh`
 131 !include `MPUI_Common.nsh`
 132
 133 ; Enable functions
 134 ${StrRep}
 135
 136
 137 ;--------------------------------------------------------------------------------
 138 ; GLOBAL VARIABLES
 139 ;--------------------------------------------------------------------------------
 140
 141 Var StartMenuFolder
 142 Var DetectedCPUType
 143 Var DetectedCPUCores
 144 Var SelectedCPUType
 145 Var SelectedTweaks
 146 Var NotUpdateInstall
 147
 148
 149 ;--------------------------------------------------------------------------------
 150 ; VERSION INFO
 151 ;--------------------------------------------------------------------------------
 152
 153 !searchreplace PRODUCT_VERSION_DATE "${MPLAYER_DATE}" "-" "."
 154 VIProductVersion "${PRODUCT_VERSION_DATE}.${MPLAYER_BUILDNO}"
 155
 156 VIAddVersionKey "Author" "LoRd_MuldeR <mulder2@gmx.de>"
 157 VIAddVersionKey "Comments" "This program is free software; you can redistribute it and/or modify it under the terms of the GNU General Public License as published by the Free Software Foundation; either version 2 of the License, or (at your option) any later version."
 158 VIAddVersionKey "CompanyName" "Free Software Foundation"
 159 VIAddVersionKey "FileDescription" "MPlayer for Windows (Build #${MPLAYER_BUILDNO})"
 160 VIAddVersionKey "FileVersion" "${PRODUCT_VERSION_DATE}.${MPLAYER_BUILDNO}"
 161 VIAddVersionKey "LegalCopyright" "Copyright 2000-2018 The MPlayer Project"
 162 VIAddVersionKey "LegalTrademarks" "GNU"
 163 VIAddVersionKey "OriginalFilename" "MPUI-Setup.exe"
 164 VIAddVersionKey "ProductName" "MPlayer for Windows"
 165 VIAddVersionKey "ProductVersion" "Build #${MPLAYER_BUILDNO} (${MPLAYER_DATE})"
 166 VIAddVersionKey "Website" "${MPlayerWebSite}"
 167
 168
 169 ;--------------------------------------------------------------------------------
 170 ; MUI2 INTERFACE SETTINGS
 171 ;--------------------------------------------------------------------------------
 172
 173 !define MUI_ABORTWARNING
 174 !define MUI_STARTMENUPAGE_REGISTRY_ROOT HKLM
 175 !define MUI_STARTMENUPAGE_REGISTRY_KEY "${MPlayerRegPath}"
 176 !define MUI_STARTMENUPAGE_REGISTRY_VALUENAME "StartmenuFolder"
 177 !define MUI_LANGDLL_REGISTRY_ROOT HKLM
 178 !define MUI_LANGDLL_REGISTRY_KEY "${MPlayerRegPath}"
 179 !define MUI_LANGDLL_REGISTRY_VALUENAME "SetupLanguage"
 180 !define MUI_STARTMENUPAGE_DEFAULTFOLDER "MPlayer for Windows"
 181 !define MUI_FINISHPAGE_NOAUTOCLOSE
 182 !define MUI_UNFINISHPAGE_NOAUTOCLOSE
 183 !define MUI_FINISHPAGE_RUN
 184 !define MUI_FINISHPAGE_RUN_FUNCTION RunAppFunction
 185 !define MUI_FINISHPAGE_SHOWREADME
 186 !define MUI_FINISHPAGE_SHOWREADME_FUNCTION ShowReadmeFunction
 187 !define MUI_FINISHPAGE_LINK ${MPlayerWebSite}
 188 !define MUI_FINISHPAGE_LINK_LOCATION ${MPlayerWebSite}
 189 !define MUI_ICON "${NSISDIR}\Contrib\Graphics\Icons\orange-install.ico"
 190 !define MUI_UNICON "${NSISDIR}\Contrib\Graphics\Icons\orange-uninstall.ico"
 191 !define MUI_WELCOMEFINISHPAGE_BITMAP "Artwork\wizard.bmp"
 192 !define MUI_UNWELCOMEFINISHPAGE_BITMAP "Artwork\wizard-un.bmp"
 193 !define MUI_HEADERIMAGE
 194 !define MUI_HEADERIMAGE_BITMAP "Artwork\header.bmp"
 195 !define MUI_HEADERIMAGE_UNBITMAP "Artwork\header-un.bmp"
 196 !define MUI_LANGDLL_ALLLANGUAGES
 197 !define MUI_CUSTOMFUNCTION_GUIINIT MyGuiInit
 198 !define MUI_CUSTOMFUNCTION_UNGUIINIT un.MyGuiInit
 199 !define MUI_LANGDLL_ALWAYSSHOW
 200 !define MUI_COMPONENTSPAGE_SMALLDESC
 201
 202
 203 ;--------------------------------------------------------------------------------
 204 ; MUI2 PAGE SETUP
 205 ;--------------------------------------------------------------------------------
 206
 207 ; Installer
 208 !define MUI_WELCOMEPAGE_TITLE_3LINES
 209 !define MUI_FINISHPAGE_TITLE_3LINES
 210 !insertmacro MUI_PAGE_WELCOME
 211 !insertmacro MUI_PAGE_LICENSE "Docs\License.txt"
 212 !define MUI_PAGE_CUSTOMFUNCTION_SHOW CheckForUpdate
 213 !insertmacro MUI_PAGE_DIRECTORY
 214 !insertmacro  MUI_PAGE_COMPONENTS
 215 !insertmacro MUI_PAGE_STARTMENU Application $StartMenuFolder
 216 Page Custom SelectCPUPage_Show SelectCPUPage_Validate
 217 Page Custom SetTweaksPage_Show
 218 Page Custom LockedListPage_Show
 219 !insertmacro MUI_PAGE_INSTFILES
 220 !insertmacro MUI_PAGE_FINISH
 221
 222 ; Un-Installer
 223 !define MUI_WELCOMEPAGE_TITLE_3LINES
 224 !define MUI_FINISHPAGE_TITLE_3LINES
 225 !insertmacro MUI_UNPAGE_WELCOME
 226 !insertmacro MUI_UNPAGE_CONFIRM
 227 UninstPage Custom un.LockedListPage_Show
 228 !insertmacro MUI_UNPAGE_INSTFILES
 229 !insertmacro MUI_UNPAGE_FINISH
 230
 231
 232 ;--------------------------------------------------------------------------------
 233 ; LANGUAGE
 234 ;--------------------------------------------------------------------------------
 235
 236 !insertmacro MUI_LANGUAGE "English"
 237 !insertmacro MUI_LANGUAGE "German"
 238
 239 ; Translation files
 240 !include "Language\MPUI_EN.nsh"
 241 !include "Language\MPUI_DE.nsh"
 242
 243
 244 ;--------------------------------------------------------------------------------
 245 ; INSTALL TYPES
 246 ;--------------------------------------------------------------------------------
 247
 248 InstType "$(MPLAYER_LANG_INSTTYPE_COMPLETE)"
 249 InstType "$(MPLAYER_LANG_INSTTYPE_MINIMAL)"
 250
 251
 252 ;--------------------------------------------------------------------------------
 253 ; INITIALIZATION
 254 ;--------------------------------------------------------------------------------
 255
 256 Function .onInit
 257         StrCpy $SelectedCPUType 0
 258         StrCpy $DetectedCPUType 0
 259         StrCpy $DetectedCPUCores 0
 260         StrCpy $SelectedTweaks 1
 261         StrCpy $NotUpdateInstall 1
 262
 263         InitPluginsDir
 264
 265         ; --------
 266
 267         System::Call 'kernel32::CreateMutexA(i 0, i 0, t "{B800490C-C100-4B12-9F09-1A54DF063049}") i .r1 ?e'
 268         Pop $0
 269         ${If} $0 <> 0
 270                 MessageBox MB_ICONSTOP|MB_TOPMOST "Oups, the installer is already running!"
 271                 Quit
 272         ${EndIf}
 273
 274         ; --------
 275
 276         # Running on Windows NT family?
 277         ${IfNot} ${IsNT}
 278                 MessageBox MB_TOPMOST|MB_ICONSTOP "Sorry, this application does *not* support Windows 9x or Windows ME!"
 279                 ExecShell "open" "http://windows.microsoft.com/"
 280                 Quit
 281         ${EndIf}
 282
 283         # Running on Windows XP or later?
 284         ${If} ${AtMostWin2000}
 285                 MessageBox MB_TOPMOST|MB_ICONSTOP "Sorry, but your operating system is *not* supported anymore.$\nInstallation will be aborted!$\n$\nThe minimum required platform is Windows XP."
 286                 ExecShell "open" "http://windows.microsoft.com/"
 287                 Quit
 288         ${EndIf}
 289
 290         ; --------
 291
 292         UserInfo::GetAccountType
 293         Pop $0
 294         ${If} $0 != "Admin"
 295                 MessageBox MB_ICONSTOP|MB_TOPMOST "Your system requires administrative permissions in order to install this software."
 296                 SetErrorLevel 740 ;ERROR_ELEVATION_REQUIRED
 297                 Quit
 298         ${EndIf}
 299
 300         ; --------
 301
 302         !insertmacro MUI_LANGDLL_DISPLAY
 303
 304         !insertmacro INSTALLOPTIONS_EXTRACT_AS "Dialogs\Page_CPU.ini"    "Page_CPU.ini"
 305         !insertmacro INSTALLOPTIONS_EXTRACT_AS "Dialogs\Page_Tweaks.ini" "Page_Tweaks.ini"
 306
 307         !ifdef PRE_RELEASE
 308                 ${IfCmd} MessageBox MB_TOPMOST|MB_ICONEXCLAMATION|MB_OKCANCEL|MB_DEFBUTTON2 "Note: This is an early pre-release version for test only!" IDCANCEL ${||} Quit ${|}
 309         !endif
 310
 311         ; --------
 312
 313         ${IfNot} ${Silent}
 314                 File "/oname=$PLUGINSDIR\Splash.gif" "Resources\Splash.gif"
 315                 newadvsplash::show 3000 1000 500 -1 /NOCANCEL "$PLUGINSDIR\Splash.gif"
 316                 Delete /REBOOTOK "$PLUGINSDIR\Splash.gif"
 317         ${EndIf}
 318 FunctionEnd
 319
 320 Function un.onInit
 321         InitPluginsDir
 322
 323         System::Call 'kernel32::CreateMutexA(i 0, i 0, t "{B800490C-C100-4B12-9F09-1A54DF063049}") i .r1 ?e'
 324         Pop $0
 325         ${If} $0 <> 0
 326                 MessageBox MB_ICONSTOP|MB_TOPMOST "Sorry, the un-installer is already running!"
 327                 Quit
 328         ${EndIf}
 329
 330         ; --------
 331
 332         UserInfo::GetAccountType
 333         Pop $0
 334         ${If} $0 != "Admin"
 335                 MessageBox MB_ICONSTOP|MB_TOPMOST "Your system requires administrative permissions in order to un-install this software."
 336                 SetErrorLevel 740 ;ERROR_ELEVATION_REQUIRED
 337                 Quit
 338         ${EndIf}
 339
 340         ; --------
 341
 342         !insertmacro MUI_LANGDLL_DISPLAY
 343 FunctionEnd
 344
 345
 346 ;--------------------------------------------------------------------------------
 347 ; GUI INITIALIZATION
 348 ;--------------------------------------------------------------------------------
 349
 350 Function MyGuiInit
 351         StrCpy $0 $HWNDPARENT
 352         System::Call "user32::SetWindowPos(i r0, i -1, i 0, i 0, i 0, i 0, i 3)"
 353         Aero::Apply
 354 FunctionEnd
 355
 356 Function un.MyGuiInit
 357         StrCpy $0 $HWNDPARENT
 358         System::Call "user32::SetWindowPos(i r0, i -1, i 0, i 0, i 0, i 0, i 3)"
 359         Aero::Apply
 360 FunctionEnd
 361
 362
 363 ;--------------------------------------------------------------------------------
 364 ; INSTALL SECTIONS
 365 ;--------------------------------------------------------------------------------
 366
 367 Section "-Check Current Version"
 368         ${StdUtils.TestParameter} $0 "Update"
 369         ${IfNot} "$0" == "true"
 370         ${AndIf} ${FileExists} "$INSTDIR\version.tag"
 371                 ReadINIStr $0 "$INSTDIR\version.tag" "mplayer_version" "build_no"
 372                 ${If} $0 > ${MPLAYER_BUILDNO}
 373                         MessageBox MB_OK|MB_ICONEXCLAMATION|MB_TOPMOST "$(MPLAYER_LANG_CAN_NOT_UPDATE)"
 374                         Quit
 375                 ${EndIf}
 376         ${EndIf}
 377 SectionEnd
 378
 379 Section "-Clean Up"
 380         ${PrintProgress} "$(MPLAYER_LANG_STATUS_INST_CLEAN)"
 381
 382         SetShellVarContext all
 383         SetOutPath "$INSTDIR"
 384
 385         ; Uninstall old version (aka "Setup v1")
 386         ClearErrors
 387         ReadRegStr $0 HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\{DB9E4EAB-2717-499F-8D56-4CC8A644AB60}" "InstallLocation"
 388         ${IfNot} ${Errors}
 389                 MessageBox MB_ICONINFORMATION|MB_OK "$(MPLAYER_LANG_UNINSTALL_OLDVER)"
 390                 File "/oname=$PLUGINSDIR\Uninstall-V1.exe" "Resources\Uninstall-V1.exe"
 391                 HideWindow
 392                 ExecWait '"$PLUGINSDIR\Uninstall-V1.exe" _?=$0'
 393                 Delete /REBOOTOK "$PLUGINSDIR\Uninstall-V1.exe"
 394                 BringToFront
 395         ${EndIf}
 396
 397         ; Clean registry
 398         DeleteRegKey HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\{DB9E4EAB-2717-499F-8D56-4CC8A644AB60}"
 399         DeleteRegKey HKCU "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\{DB9E4EAB-2717-499F-8D56-4CC8A644AB60}"
 400         DeleteRegValue HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Run" "MPlayerForWindows_UpdateReminder"
 401         DeleteRegValue HKCU "SOFTWARE\Microsoft\Windows\CurrentVersion\Run" "MPlayerForWindows_UpdateReminder"
 402
 403         ; Make sure MPlayer isn't running
 404         ${Do}
 405                 ClearErrors
 406                 Delete "$INSTDIR\MPlayer.exe"
 407                 Delete "$INSTDIR\SMPlayer.exe"
 408                 Delete "$INSTDIR\MPUI.exe"
 409                 ${If} ${Errors}
 410                         ${IfCmd} MessageBox MB_TOPMOST|MB_ICONEXCLAMATION|MB_OKCANCEL "$(MPLAYER_LANG_STILL_RUNNING)" IDCANCEL ${||} Abort ${|}
 411                 ${Else}
 412                         ${Break}
 413                 ${EndIf}
 414         ${Loop}
 415
 416         ; Clean the install folder
 417         Delete "$INSTDIR\*.exe"
 418         Delete "$INSTDIR\*.dll"
 419         Delete "$INSTDIR\*.ini"
 420         Delete "$INSTDIR\*.txt"
 421         Delete "$INSTDIR\*.html"
 422         Delete "$INSTDIR\*.htm"
 423         Delete "$INSTDIR\*.ass"
 424         Delete "$INSTDIR\*.m3u8"
 425         Delete "$INSTDIR\*.tag"
 426
 427         RMDir /r "$INSTDIR\codecs"
 428         RMDir /r "$INSTDIR\fonts"
 429         RMDir /r "$INSTDIR\imageformats"
 430         RMDir /r "$INSTDIR\legal_stuff"
 431         RMDir /r "$INSTDIR\locale"
 432         RMDir /r "$INSTDIR\mplayer"
 433         RMDir /r "$INSTDIR\platforms"
 434         RMDir /r "$INSTDIR\shortcuts"
 435         RMDir /r "$INSTDIR\themes"
 436         RMDir /r "$INSTDIR\translations"
 437
 438         ; Now deal with Virtual Store
 439         ${GetVirtualStorePath} $0 "$INSTDIR"
 440         ${If} ${FileExists} "$0\*.*"
 441                 RMDir /r "$0"
 442         ${EndIf}
 443 SectionEnd
 444
 445 Section "!MPlayer r${MPLAYER_REVISION}" SECID_MPLAYER
 446         SectionIn 1 2 RO
 447         ${PrintProgress} "$(MPLAYER_LANG_STATUS_INST_MPLAYER)"
 448         SetOutPath "$INSTDIR"
 449
 450         ; Detect
 451         ${If} ${Silent}
 452                 Call DetectCPUType
 453                 StrCpy $SelectedCPUType $DetectedCPUType
 454         ${EndIf}
 455
 456         ; MPlayer.exe
 457         ${Select} $SelectedCPUType
 458                 ${Case} "2"
 459                         DetailPrint "$(MPLAYER_LANG_SELECTED_TYPE): core2"
 460                         File "Builds\MPlayer-core2\MPlayer.exe"
 461                 ${Case} "3"
 462                         DetailPrint "$(MPLAYER_LANG_SELECTED_TYPE): corei7"
 463                         File "Builds\MPlayer-corei7\MPlayer.exe"
 464                 ${Case} "4"
 465                         DetailPrint "$(MPLAYER_LANG_SELECTED_TYPE): k8-sse3"
 466                         File "Builds\MPlayer-k8-sse3\MPlayer.exe"
 467                 ${Case} "5"
 468                         DetailPrint "$(MPLAYER_LANG_SELECTED_TYPE): generic"
 469                         File "Builds\MPlayer-generic\MPlayer.exe"
 470                 ${CaseElse}
 471                         MessageBox MB_TOPMOST|MB_ICONEXCLAMATION|MB_OK "Internal error: Invalid CPU type selection detected!"
 472                         Abort
 473         ${EndSelect}
 474
 475         ; Utilities
 476         File ".Compile\Updater.exe"
 477         File "Resources\AppRegGUI.exe"
 478
 479         ; Other MPlayer-related files
 480         File "Builds\MPlayer-generic\*.dll"
 481         ${ExtractSubDir} "Builds\MPlayer-generic" "mplayer"
 482         ${ExtractSubDir} "Builds\MPlayer-generic" "fonts"
 483
 484         ; Documents
 485         SetOutPath "$INSTDIR"
 486         File "GPL.txt"
 487         File "/oname=Manual.html" "Builds\MPlayer-generic\MPlayer.man.html"
 488         File "Docs\Readme.html"
 489         SetOutPath "$INSTDIR\legal_stuff"
 490         File "Docs\legal_stuff\*.txt"
 491
 492         ; Write version tag
 493         ${Do}
 494                 ClearErrors
 495                 Delete "$INSTDIR\version.tag"
 496                 ${If} ${Errors}
 497                         ${IfCmd} MessageBox MB_TOPMOST|MB_ICONEXCLAMATION|MB_OKCANCEL "$(MPLAYER_LANG_TAG_WRITE)" IDCANCEL ${||} Abort ${|}
 498                 ${Else}
 499                         ${Break}
 500                 ${EndIf}
 501         ${Loop}
 502         WriteINIStr "$INSTDIR\version.tag" "mplayer_version" "build_no" "${MPLAYER_BUILDNO}"
 503         WriteINIStr "$INSTDIR\version.tag" "mplayer_version" "pkg_date" "${MPLAYER_DATE}"
 504         SetFileAttributes "$INSTDIR\version.tag" FILE_ATTRIBUTE_READONLY
 505
 506         ; Set file access rights
 507         ${MakePathPublic} "$INSTDIR"
 508         ${MakeFilePublic} "$INSTDIR\mplayer\config"
 509         ${MakeFilePublic} "$INSTDIR\fonts\fonts.conf"
 510 SectionEnd
 511
 512 Section "!MPUI $(MPLAYER_LANG_FRONT_END) v${MPUI_VERSION}" SECID_MPUI
 513         SectionIn 1 2
 514         ${PrintProgress} "$(MPLAYER_LANG_STATUS_INST_MPUI)"
 515
 516         ; Extract files
 517         SetOutPath "$INSTDIR"
 518         File "MPUI\MPUI.exe"
 519
 520         ; Extract locales
 521         SetOutPath "$INSTDIR\locale"
 522         File "MPUI\locale\*.txt"
 523
 524         ; Set file access rights
 525         ${MakeFilePublic} "$INSTDIR\MPUI.ini"
 526
 527         ; Setup initial config
 528         ClearErrors
 529         WriteINIStr "$INSTDIR\MPUI.ini" "MPUI" "Params" "-vo direct3d -lavdopts threads=$DetectedCPUCores"
 530         WriteINIStr "$INSTDIR\MPUI.ini" "MPUI" "Locale" "$(MPLAYER_LANG_MPUI_DEFAULT_LANGUAGE)"
 531         ${If} ${Errors}
 532                 ${IfCmd} MessageBox MB_TOPMOST|MB_ICONSTOP|MB_DEFBUTTON2|MB_OKCANCEL "$(MPLAYER_LANG_CONFIG_MPUI)" IDCANCEL ${||} Abort ${|}
 533         ${EndIf}
 534 SectionEnd
 535
 536 Section "!SMPlayer $(MPLAYER_LANG_FRONT_END) v${SMPLAYER_VERSION}" SECID_SMPLAYER
 537         SectionIn 1
 538         ${PrintProgress} "$(MPLAYER_LANG_STATUS_INST_SMPLAYER)"
 539
 540         ; SMPlayer program files
 541         SetOutPath "$INSTDIR"
 542         File "SMPlayer\*.exe"
 543         File "SMPlayer\*.dll"
 544
 545         ; Additional SMPlayer files
 546         ${ExtractSubDir} "SMPlayer" "imageformats"
 547         ${ExtractSubDir} "SMPlayer" "platforms"
 548         ${ExtractSubDir} "SMPlayer" "shortcuts"
 549         ${ExtractSubDir} "SMPlayer" "themes"
 550         ${ExtractSubDir} "SMPlayer" "translations"
 551
 552         ; Set file access rights
 553         ${MakeFilePublic} "$INSTDIR\SMPlayer.ini"
 554         ${MakeFilePublic} "$INSTDIR\SMPlayer_files.ini"
 555         ${MakeFilePublic} "$INSTDIR\player_info.ini"
 556         ${MakeFilePublic} "$INSTDIR\playlist.ini"
 557         ${MakeFilePublic} "$INSTDIR\favorites.m3u8"
 558         ${MakeFilePublic} "$INSTDIR\radio.m3u8"
 559         ${MakeFilePublic} "$INSTDIR\tv.m3u8"
 560         ${MakeFilePublic} "$INSTDIR\styles.ass"
 561         ${MakeFilePublic} "$INSTDIR\shortcuts\default.keys"
 562
 563         ; Setup initial config
 564         ${StrRep} $0 "$INSTDIR\MPlayer.exe" "\" "/"
 565         ClearErrors
 566         WriteINIStr "$INSTDIR\SMPlayer.ini" "%General"       "autosync"                      "true"
 567         WriteINIStr "$INSTDIR\SMPlayer.ini" "%General"       "autosync_factor"               "30"
 568         WriteINIStr "$INSTDIR\SMPlayer.ini" "%General"       "config_version"                "5"
 569         WriteINIStr "$INSTDIR\SMPlayer.ini" "%General"       "driver\vo"                     "direct3d"
 570         WriteINIStr "$INSTDIR\SMPlayer.ini" "%General"       "file_settings_method"          "normal"
 571         WriteINIStr "$INSTDIR\SMPlayer.ini" "%General"       "mplayer_bin"                   "$0"
 572         WriteINIStr "$INSTDIR\SMPlayer.ini" "%General"       "osd"                           "1"
 573         WriteINIStr "$INSTDIR\SMPlayer.ini" "%General"       "use_audio_equalizer"           "false"
 574         WriteINIStr "$INSTDIR\SMPlayer.ini" "%General"       "use_scaletempo"                "0"
 575         WriteINIStr "$INSTDIR\SMPlayer.ini" "advanced"       "mplayer_additional_options"    ""
 576         WriteINIStr "$INSTDIR\SMPlayer.ini" "gui"            "gui"                           "DefaultGUI"
 577         WriteINIStr "$INSTDIR\SMPlayer.ini" "gui"            "iconset"                       "Numix-remix"
 578         WriteINIStr "$INSTDIR\SMPlayer.ini" "gui"            "qt_style"                      "WindowsVista"
 579         WriteINIStr "$INSTDIR\SMPlayer.ini" "mplayer_info"   "is_mplayer2"                   "false"
 580         WriteINIStr "$INSTDIR\SMPlayer.ini" "mplayer_info"   "mplayer_detected_version"      "${MPLAYER_REVISION}"
 581         WriteINIStr "$INSTDIR\SMPlayer.ini" "mplayer_info"   "mplayer_user_supplied_version" "-1"
 582         WriteINIStr "$INSTDIR\SMPlayer.ini" "performance"    "frame_drop"                    "true"
 583         WriteINIStr "$INSTDIR\SMPlayer.ini" "performance"    "priority"                      "1"
 584         WriteINIStr "$INSTDIR\SMPlayer.ini" "performance"    "threads"                       "$DetectedCPUCores"
 585         WriteINIStr "$INSTDIR\SMPlayer.ini" "smplayer"       "check_for_new_version"         "false"
 586         WriteINIStr "$INSTDIR\SMPlayer.ini" "smplayer"       "check_if_upgraded"             "false"
 587         WriteINIStr "$INSTDIR\SMPlayer.ini" "update_checker" "enabled"                       "false"
 588
 589         ${If} ${Errors}
 590                 ${IfCmd} MessageBox MB_TOPMOST|MB_ICONSTOP|MB_DEFBUTTON2|MB_OKCANCEL "$(MPLAYER_LANG_CONFIG_SMPLAYER)" IDCANCEL ${||} Abort ${|}
 591         ${EndIf}
 592 SectionEnd
 593
 594 Section "!$(MPLAYER_LANG_BIN_CODECS) (${CODECS_DATE})"
 595         SectionIn 1
 596         ${PrintProgress} "$(MPLAYER_LANG_STATUS_INST_CODECS)"
 597
 598         SetOutPath "$INSTDIR\codecs"
 599
 600         File "Codecs\*.0"
 601         File "Codecs\*.acm"
 602         File "Codecs\*.ax"
 603         File "Codecs\*.dll"
 604         File "Codecs\*.qtx"
 605         File "Codecs\*.so"
 606         File "Codecs\*.vwp"
 607         File "Codecs\*.xa"
 608 SectionEnd
 609
 610 Section "-Write Uninstaller"
 611         ${PrintProgress} "$(MPLAYER_LANG_STATUS_MAKEUNINST)"
 612         WriteUninstaller "$INSTDIR\Uninstall.exe"
 613 SectionEnd
 614
 615 Section "-Create Shortcuts"
 616         !insertmacro MUI_STARTMENU_WRITE_BEGIN Application
 617                 ${PrintProgress} "$(MPLAYER_LANG_STATUS_SHORTCUTS)"
 618                 CreateDirectory "$SMPROGRAMS\$StartMenuFolder"
 619
 620                 SetShellVarContext current
 621                 Delete "$SMPROGRAMS\$StartMenuFolder\*.lnk"
 622                 Delete "$SMPROGRAMS\$StartMenuFolder\*.pif"
 623                 Delete "$SMPROGRAMS\$StartMenuFolder\*.url"
 624
 625                 SetShellVarContext all
 626                 Delete "$SMPROGRAMS\$StartMenuFolder\*.lnk"
 627                 Delete "$SMPROGRAMS\$StartMenuFolder\*.pif"
 628                 Delete "$SMPROGRAMS\$StartMenuFolder\*.url"
 629
 630                 ${If} ${FileExists} "$INSTDIR\MPUI.exe"
 631                         CreateShortCut "$SMPROGRAMS\$StartMenuFolder\MPUI.lnk" "$INSTDIR\MPUI.exe"
 632                         CreateShortCut "$DESKTOP\MPUI.lnk" "$INSTDIR\MPUI.exe"
 633                 ${EndIf}
 634                 ${If} ${FileExists} "$INSTDIR\SMPlayer.exe"
 635                         CreateShortCut "$SMPROGRAMS\$StartMenuFolder\SMPlayer.lnk" "$INSTDIR\SMPlayer.exe"
 636                         CreateShortCut "$DESKTOP\SMPlayer.lnk" "$INSTDIR\SMPlayer.exe"
 637                 ${EndIf}
 638
 639                 CreateShortCut "$SMPROGRAMS\$StartMenuFolder\$(MPLAYER_LANG_SHORTCUT_UPDATE).lnk" "$INSTDIR\Updater.exe" "/L=$LANGUAGE"
 640                 CreateShortCut "$SMPROGRAMS\$StartMenuFolder\$(MPLAYER_LANG_SHORTCUT_README).lnk" "$INSTDIR\Readme.html"
 641                 CreateShortCut "$SMPROGRAMS\$StartMenuFolder\$(MPLAYER_LANG_SHORTCUT_MANUAL).lnk" "$INSTDIR\Manual.html"
 642
 643                 ${If} ${AtLeastWinVista}
 644                         CreateShortCut "$SMPROGRAMS\$StartMenuFolder\$(MPLAYER_LANG_SHORTCUT_APPREG).lnk" "$INSTDIR\AppRegGUI.exe"
 645                 ${EndIf}
 646
 647                 ${CreateWebLink} "$SMPROGRAMS\$StartMenuFolder\$(MPLAYER_LANG_SHORTCUT_SITE_MULDERS).url" "http://muldersoft.com/"
 648                 ${CreateWebLink} "$SMPROGRAMS\$StartMenuFolder\$(MPLAYER_LANG_SHORTCUT_SITE_MPWIN32).url" "http://oss.netfarm.it/mplayer-win32.php"
 649                 ${CreateWebLink} "$SMPROGRAMS\$StartMenuFolder\$(MPLAYER_LANG_SHORTCUT_SITE_MPLAYER).url" "http://www.mplayerhq.hu/"
 650
 651                 ${If} ${FileExists} "$SMPROGRAMS\$StartMenuFolder\SMPlayer.lnk"
 652                         ${StdUtils.InvokeShellVerb} $R1 "$SMPROGRAMS\$StartMenuFolder" "SMPlayer.lnk" ${StdUtils.Const.ShellVerb.PinToTaskbar}
 653                         DetailPrint 'Pin: "$SMPROGRAMS\$StartMenuFolder\SMPlayer.lnk" -> $R1'
 654                 ${EndIf}
 655         !insertmacro MUI_STARTMENU_WRITE_END
 656 SectionEnd
 657
 658 Section "-ApplyTweaks"
 659         ${PrintProgress} "$(MPLAYER_LANG_STATUS_TWEAKS)"
 660         DetailPrint "$(MPLAYER_LANG_APPLYING_TWEAKS)"
 661
 662         IntOp $0 $SelectedTweaks & 1
 663         ${If} $0 != 0
 664                 ${If} ${FileExists} "$INSTDIR\SMPlayer.ini"
 665                         WriteINIStr "$INSTDIR\SMPlayer.ini" "gui" "gui"      "SkinGUI"
 666                         WriteINIStr "$INSTDIR\SMPlayer.ini" "gui" "qt_style" "Fusion"
 667                         WriteINIStr "$INSTDIR\SMPlayer.ini" "gui" "iconset"  "Modern"
 668                 ${EndIf}
 669         ${EndIf}
 670
 671         IntOp $0 $SelectedTweaks & 2
 672         ${If} $0 != 0
 673                 ${If} ${FileExists} "$INSTDIR\MPUI.ini"
 674                         WriteINIStr "$INSTDIR\MPUI.ini" "MPUI" "Params" "-vo gl:yuv=3 -lavdopts threads=$DetectedCPUCores"
 675                 ${EndIf}
 676                 ${If} ${FileExists} "$INSTDIR\SMPlayer.ini"
 677                         WriteINIStr "$INSTDIR\SMPlayer.ini" "%General" "driver\vo" "gl:yuv=3"
 678                 ${EndIf}
 679         ${EndIf}
 680
 681         IntOp $0 $SelectedTweaks & 4
 682         ${If} $0 != 0
 683                 ${If} ${FileExists} "$INSTDIR\MPUI.ini"
 684                         ReadINIStr $1 "$INSTDIR\MPUI.ini" "MPUI" "Params"
 685                         WriteINIStr "$INSTDIR\MPUI.ini" "MPUI" "Params" "$1 -af volnorm=2"
 686                 ${EndIf}
 687                 ${If} ${FileExists} "$INSTDIR\SMPlayer.ini"
 688                         WriteINIStr "$INSTDIR\SMPlayer.ini" "defaults" "initial_volnorm" "true"
 689                 ${EndIf}
 690         ${EndIf}
 691 SectionEnd
 692
 693 Section "$(MPLAYER_LANG_COMPRESS_FILES)"
 694         SectionIn 1 2
 695         ${PrintProgress} "$(MPLAYER_LANG_STATUS_INST_COMPRESS)"
 696
 697         File "/oname=$PLUGINSDIR\UPX.exe" "${UPX_PATH}\UPX.exe"
 698
 699         ${PackAll} "$INSTDIR" "*.exe"
 700         ${PackAll} "$INSTDIR" "*.dll"
 701         ${PackAll} "$INSTDIR\codecs" "*.acm"
 702         ${PackAll} "$INSTDIR\codecs" "*.ax"
 703         ${PackAll} "$INSTDIR\codecs" "*.dll"
 704         ${PackAll} "$INSTDIR\codecs" "*.qtx"
 705
 706         Delete "$PLUGINSDIR\UPX.exe"
 707 SectionEnd
 708
 709 Section "-Update Font Cache"
 710         ${PrintProgress} "$(MPLAYER_LANG_STATUS_INST_FONTCACHE)"
 711
 712         SetShellVarContext current
 713         Delete "$APPDATA\fontconfig\cache\*.*"
 714         Delete "$LOCALAPPDATA\fontconfig\cache\*.*"
 715
 716         SetShellVarContext all
 717         Delete "$APPDATA\fontconfig\cache\*.*"
 718         Delete "$LOCALAPPDATA\fontconfig\cache\*.*"
 719
 720         File "/oname=$PLUGINSDIR\Sample.avi" "Resources\Sample.avi"
 721         DetailPrint "$(MPLAYER_LANG_UPDATING_FONTCACHE)"
 722         NsExec::Exec '"$INSTDIR\MPlayer.exe" -fontconfig -ass -vo null -ao null "$PLUGINSDIR\Sample.avi"'
 723         Delete "Resources\Sample.avi"
 724 SectionEnd
 725
 726 Section "-Update Registry"
 727         ${PrintProgress} "$(MPLAYER_LANG_STATUS_REGISTRY)"
 728         DetailPrint "$(MPLAYER_LANG_WRITING_REGISTRY)"
 729
 730         ; Clean up
 731         DeleteRegKey HKLM "${MPlayerRegPath}"
 732         DeleteRegKey HKCU "${MPlayerRegPath}"
 733         DeleteRegValue HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Run" "MPlayerForWindows_AutoUpdateV2"
 734         DeleteRegValue HKCU "SOFTWARE\Microsoft\Windows\CurrentVersion\Run" "MPlayerForWindows_AutoUpdateV2"
 735
 736         ; Uninstaller
 737         WriteRegStr HKLM "${MPlayerRegPath}" "InstallLocation" "$INSTDIR"
 738         WriteRegStr HKLM "${MPlayerRegPath}" "UninstallString" '"$INSTDIR\Uninstall.exe"'
 739         WriteRegStr HKLM "${MPlayerRegPath}" "DisplayName" "$(MPLAYER_LANG_MPLAYER_WIN32)"
 740         WriteRegStr HKLM "${MPlayerRegPath}" "DisplayIcon" "$INSTDIR\MPlayer.exe,0"
 741         WriteRegStr HKLM "${MPlayerRegPath}" "DisplayVersion" "${MPLAYER_DATE}"
 742         WriteRegStr HKLM "${MPlayerRegPath}" "URLInfoAbout" "http://muldersoft.com/"
 743         WriteRegStr HKLM "${MPlayerRegPath}" "URLUpdateInfo" "http://muldersoft.com/"
 744         WriteRegStr HKLM "${MPlayerRegPath}" "Publisher" "The MPlayer Team"
 745         WriteRegDWORD HKLM "${MPlayerRegPath}" "NoModify" 1
 746         WriteRegDWORD HKLM "${MPlayerRegPath}" "NoRepair" 1
 747
 748         ; Shell
 749         DeleteRegKey HKCR "MPlayerForWindowsV2.File"
 750         DeleteRegKey HKLM "SOFTWARE\Classes\MPlayerForWindowsV2.File"
 751         DeleteRegKey HKCU "SOFTWARE\Classes\MPlayerForWindowsV2.File"
 752         ${If} ${FileExists} "$INSTDIR\MPUI.exe"
 753                 WriteRegStr HKLM "SOFTWARE\Classes\MPlayerForWindowsV2.File\shell\open\command" "" '"$INSTDIR\MPUI.exe" "%1"'
 754                 WriteRegStr HKLM "SOFTWARE\Classes\MPlayerForWindowsV2.File\DefaultIcon" "" "$INSTDIR\MPUI.exe,0"
 755         ${EndIf}
 756         ${If} ${FileExists} "$INSTDIR\SMPlayer.exe"
 757                 WriteRegStr HKLM "SOFTWARE\Classes\MPlayerForWindowsV2.File\shell\open\command" "" '"$INSTDIR\SMPlayer.exe" "%1"'
 758                 WriteRegStr HKLM "SOFTWARE\Classes\MPlayerForWindowsV2.File\DefaultIcon" "" "$INSTDIR\SMPlayer.exe,1"
 759         ${EndIf}
 760
 761         ; Register App
 762         DeleteRegValue HKCU "SOFTWARE\RegisteredApplications" "MPlayerForWindowsV2"
 763         WriteRegStr HKLM "SOFTWARE\RegisteredApplications" "MPlayerForWindowsV2" "${MPlayerRegPath}\Capabilities"
 764
 765         ; Capabilities
 766         WriteRegStr HKLM "${MPlayerRegPath}\Capabilities" "ApplicationName" "$(MPLAYER_LANG_MPLAYER_WIN32)"
 767         WriteRegStr HKLM "${MPlayerRegPath}\Capabilities" "ApplicationDescription" "$(MPLAYER_LANG_MPLAYER_WIN32)"
 768         WriteRegStr HKLM "${MPlayerRegPath}\Capabilities" "ApplicationDescription" "$(MPLAYER_LANG_MPLAYER_WIN32)"
 769
 770         ; File Associations
 771         ${RegisterFileExtCapability} "256"
 772         ${RegisterFileExtCapability} "3GP"
 773         ${RegisterFileExtCapability} "AAC"
 774         ${RegisterFileExtCapability} "ASF"
 775         ${RegisterFileExtCapability} "AVI"
 776         ${RegisterFileExtCapability} "BIN"
 777         ${RegisterFileExtCapability} "DAT"
 778         ${RegisterFileExtCapability} "DIVX"
 779         ${RegisterFileExtCapability} "EVO"
 780         ${RegisterFileExtCapability} "FLV"
 781         ${RegisterFileExtCapability} "M2V"
 782         ${RegisterFileExtCapability} "M2TS"
 783         ${RegisterFileExtCapability} "M4A"
 784         ${RegisterFileExtCapability} "MKA"
 785         ${RegisterFileExtCapability} "MKV"
 786         ${RegisterFileExtCapability} "MOV"
 787         ${RegisterFileExtCapability} "MP2"
 788         ${RegisterFileExtCapability} "MP3"
 789         ${RegisterFileExtCapability} "MP4"
 790         ${RegisterFileExtCapability} "MPEG"
 791         ${RegisterFileExtCapability} "MPG"
 792         ${RegisterFileExtCapability} "MPV"
 793         ${RegisterFileExtCapability} "NSV"
 794         ${RegisterFileExtCapability} "OGG"
 795         ${RegisterFileExtCapability} "OGM"
 796         ${RegisterFileExtCapability} "RM"
 797         ${RegisterFileExtCapability} "RMVB"
 798         ${RegisterFileExtCapability} "TS"
 799         ${RegisterFileExtCapability} "VOB"
 800         ${RegisterFileExtCapability} "WAV"
 801         ${RegisterFileExtCapability} "WEBM"
 802         ${RegisterFileExtCapability} "WMV"
 803
 804         ; Reset auto update interval
 805         DeleteRegValue HKLM "${MPlayerRegPath}" "LastUpdateCheck"
 806         DeleteRegValue HKCU "${MPlayerRegPath}" "LastUpdateCheck"
 807 SectionEnd
 808
 809 Section "$(MPLAYER_LANG_INST_AUTOUPDATE)" SECID_AUTOUPDATE
 810         SectionIn 1 2
 811         DetailPrint "$(MPLAYER_LANG_SCHEDULE_UPDATE)"
 812         WriteRegStr HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Run" "MPlayerForWindows_AutoUpdateV2" '"$INSTDIR\Updater.exe" /L=$LANGUAGE /AutoCheck'
 813 SectionEnd
 814
 815 Section "-Protect Files"
 816         SetFileAttributes "$INSTDIR\AppRegGUI.exe"       FILE_ATTRIBUTE_READONLY
 817         SetFileAttributes "$INSTDIR\mplayer.exe"         FILE_ATTRIBUTE_READONLY
 818         SetFileAttributes "$INSTDIR\MPUI.exe"            FILE_ATTRIBUTE_READONLY
 819         SetFileAttributes "$INSTDIR\smplayer.exe"        FILE_ATTRIBUTE_READONLY
 820         SetFileAttributes "$INSTDIR\Updater.exe"         FILE_ATTRIBUTE_READONLY
 821
 822         SetFileAttributes "$INSTDIR\dsnative.dll"        FILE_ATTRIBUTE_READONLY
 823         SetFileAttributes "$INSTDIR\libeay32.dll"        FILE_ATTRIBUTE_READONLY
 824         SetFileAttributes "$INSTDIR\libgcc_s_dw2-1.dll"  FILE_ATTRIBUTE_READONLY
 825         SetFileAttributes "$INSTDIR\libstdc++-6.dll"     FILE_ATTRIBUTE_READONLY
 826         SetFileAttributes "$INSTDIR\libwinpthread-1.dll" FILE_ATTRIBUTE_READONLY
 827         SetFileAttributes "$INSTDIR\Qt5Core.dll"         FILE_ATTRIBUTE_READONLY
 828         SetFileAttributes "$INSTDIR\Qt5Gui.dll"          FILE_ATTRIBUTE_READONLY
 829         SetFileAttributes "$INSTDIR\Qt5Network.dll"      FILE_ATTRIBUTE_READONLY
 830         SetFileAttributes "$INSTDIR\Qt5Script.dll"       FILE_ATTRIBUTE_READONLY
 831         SetFileAttributes "$INSTDIR\Qt5Widgets.dll"      FILE_ATTRIBUTE_READONLY
 832         SetFileAttributes "$INSTDIR\Qt5Xml.dll"          FILE_ATTRIBUTE_READONLY
 833         SetFileAttributes "$INSTDIR\ssleay32.dll"        FILE_ATTRIBUTE_READONLY
 834         SetFileAttributes "$INSTDIR\zlib1.dll"           FILE_ATTRIBUTE_READONLY
 835 SectionEnd
 836
 837 Section "-Finished"
 838         ${PrintStatus} "$(MUI_TEXT_FINISH_TITLE)"
 839 SectionEnd
 840
 841
 842 ;--------------------------------------------------------------------------------
 843 ; UN-INSTALL SECTIONS
 844 ;--------------------------------------------------------------------------------
 845
 846 Section "Uninstall"
 847         SetOutPath "$TEMP"
 848         ${PrintProgress} "$(MPLAYER_LANG_STATUS_UNINSTALL)"
 849
 850         ; Validate uninstall path
 851         ${IfThen} "$INSTDIR" == "" ${|} Abort ${|}
 852         StrCpy $0 "$INSTDIR" "" -2
 853         ${IfThen} $0 == ":\" ${|} Abort ${|}
 854
 855         ; Startmenu
 856         !insertmacro MUI_STARTMENU_GETFOLDER Application $StartMenuFolder
 857         ${IfNot} "$StartMenuFolder" == ""
 858                 SetShellVarContext current
 859                 ${If} ${FileExists} "$SMPROGRAMS\$StartMenuFolder\SMPlayer.lnk"
 860                         ${StdUtils.InvokeShellVerb} $R1 "$SMPROGRAMS\$StartMenuFolder" "SMPlayer.lnk" ${StdUtils.Const.ShellVerb.UnpinFromTaskbar}
 861                         DetailPrint 'Unpin: "$SMPROGRAMS\$StartMenuFolder\SMPlayer.lnk" -> $R1'
 862                 ${EndIf}
 863                 ${If} ${FileExists} "$SMPROGRAMS\$StartMenuFolder\*.*"
 864                         Delete /REBOOTOK "$SMPROGRAMS\$StartMenuFolder\*.lnk"
 865                         Delete /REBOOTOK "$SMPROGRAMS\$StartMenuFolder\*.url"
 866                         Delete /REBOOTOK "$SMPROGRAMS\$StartMenuFolder\*.pif"
 867                         RMDir "$SMPROGRAMS\$StartMenuFolder"
 868                 ${EndIf}
 869                 SetShellVarContext all
 870                 ${If} ${FileExists} "$SMPROGRAMS\$StartMenuFolder\SMPlayer.lnk"
 871                         ${StdUtils.InvokeShellVerb} $R1 "$SMPROGRAMS\$StartMenuFolder" "SMPlayer.lnk" ${StdUtils.Const.ShellVerb.UnpinFromTaskbar}
 872                         DetailPrint 'Unpin: "$SMPROGRAMS\$StartMenuFolder\SMPlayer.lnk" -> $R1'
 873                 ${EndIf}
 874                 ${If} ${FileExists} "$SMPROGRAMS\$StartMenuFolder\*.*"
 875                         Delete /REBOOTOK "$SMPROGRAMS\$StartMenuFolder\*.lnk"
 876                         Delete /REBOOTOK "$SMPROGRAMS\$StartMenuFolder\*.url"
 877                         Delete /REBOOTOK "$SMPROGRAMS\$StartMenuFolder\*.pif"
 878                         RMDir "$SMPROGRAMS\$StartMenuFolder"
 879                 ${EndIf}
 880         ${EndIf}
 881
 882         ; Desktop icons
 883         Delete /REBOOTOK "$DESKTOP\MPUI.lnk"
 884         Delete /REBOOTOK "$DESKTOP\SMPlayer.lnk"
 885
 886         ; Files
 887         RMDir /r "$INSTDIR"
 888
 889         ; Virtual Store
 890         ${GetVirtualStorePath} $0 "$INSTDIR"
 891         ${If} ${FileExists} "$0\*.*"
 892                 RMDir /r "$0"
 893         ${EndIf}
 894
 895         ; Registry Keys
 896         DeleteRegKey HKLM "${MPlayerRegPath}"
 897         DeleteRegKey HKCU "${MPlayerRegPath}"
 898         DeleteRegValue HKLM "SOFTWARE\RegisteredApplications" "MPlayerForWindowsV2"
 899         DeleteRegValue HKCU "SOFTWARE\RegisteredApplications" "MPlayerForWindowsV2"
 900
 901         ; Auto Update
 902         DeleteRegValue HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Run" "MPlayerForWindows_AutoUpdateV2"
 903         DeleteRegValue HKCU "SOFTWARE\Microsoft\Windows\CurrentVersion\Run" "MPlayerForWindows_AutoUpdateV2"
 904
 905         ; Shell
 906         DeleteRegKey HKCR "MPlayerForWindowsV2.File"
 907         DeleteRegKey HKLM "SOFTWARE\Classes\MPlayerForWindowsV2.File"
 908         DeleteRegKey HKCU "SOFTWARE\Classes\MPlayerForWindowsV2.File"
 909
 910         ${PrintStatus} "$(MUI_UNTEXT_FINISH_TITLE)"
 911 SectionEnd
 912
 913
 914 ;--------------------------------------------------------------------------------
 915 ; SECTION SELECTION CHANGED
 916 ;--------------------------------------------------------------------------------
 917
 918 Function .onSelChange
 919         ${IfNot} ${SectionIsSelected} ${SECID_MPUI}
 920         ${AndIfNot} ${SectionIsSelected} ${SECID_SMPLAYER}
 921                 MessageBox MB_TOPMOST|MB_ICONEXCLAMATION "$(MPLAYER_LANG_SELCHANGE)"
 922                 SectionGetFlags ${SECID_MPUI} $0
 923                 IntOp $0 $0 | ${SF_SELECTED}
 924                 SectionSetFlags ${SECID_MPUI} $0
 925         ${EndIf}
 926
 927         ${IfNot} ${SectionIsSelected} ${SECID_AUTOUPDATE}
 928                 StrCpy $0 "nope"
 929                 ${IfCmd} MessageBox MB_TOPMOST|MB_ICONEXCLAMATION|MB_YESNO|MB_DEFBUTTON2 "$(MPLAYER_LANG_SEL_AUTOUPDATE)" IDNO ${||} StrCpy $0 "ok" ${|}
 930                 ${If} "$0" == "ok"
 931                         SectionGetFlags ${SECID_AUTOUPDATE} $0
 932                         IntOp $0 $0 | ${SF_SELECTED}
 933                         SectionSetFlags ${SECID_AUTOUPDATE} $0
 934                 ${EndIf}
 935         ${EndIf}
 936 FunctionEnd
 937
 938
 939 ;--------------------------------------------------------------------------------
 940 ; LOCKED-LIST PLUGIN
 941 ;--------------------------------------------------------------------------------
 942
 943 !macro LockedListPage_Function
 944         !insertmacro MUI_HEADER_TEXT "$(MPLAYER_LANG_LOCKEDLIST_HEADER)" "$(MPLAYER_LANG_LOCKEDLIST_TEXT)"
 945
 946         InitPluginsDir
 947         File /oname=$PLUGINSDIR\LockedList64.dll `${NSISDIR}\Plugins\LockedList64.dll`
 948
 949         LockedList::AddModule "\MPlayer.exe"
 950         LockedList::AddModule "\SMPlayer.exe"
 951         LockedList::AddModule "\MPUI.exe"
 952         LockedList::AddModule "${NSISDIR}\Qt5Core.dll"
 953
 954         LockedList::Dialog /autonext /ignore "$(MPLAYER_LANG_IGNORE)" /heading "$(MPLAYER_LANG_LOCKEDLIST_HEADING)" /noprograms "$(MPLAYER_LANG_LOCKEDLIST_NOPROG)" /searching  "$(MPLAYER_LANG_LOCKEDLIST_SEARCH)" /colheadings "$(MPLAYER_LANG_LOCKEDLIST_COLHDR1)" "$(MPLAYER_LANG_LOCKEDLIST_COLHDR2)"
 955         Pop $R0
 956 !macroend
 957
 958 Function LockedListPage_Show
 959         !insertmacro LockedListPage_Function
 960 FunctionEnd
 961
 962 Function un.LockedListPage_Show
 963         !insertmacro LockedListPage_Function
 964 FunctionEnd
 965
 966
 967 ;--------------------------------------------------------------------------------
 968 ; CUSTOME PAGE: CPU SELECTOR
 969 ;--------------------------------------------------------------------------------
 970
 971 Function SelectCPUPage_Show
 972         ; Detect CPU type, if not detected yet
 973         ${If} $DetectedCPUType < 2
 974         ${OrIf} $DetectedCPUType > 5
 975                 Call DetectCPUType
 976                 !insertmacro INSTALLOPTIONS_READ $0 "Page_CPU.ini" "Field $DetectedCPUType" "Text"
 977                 !insertmacro INSTALLOPTIONS_WRITE "Page_CPU.ini" "Field $DetectedCPUType" "Text" "$0  <---"
 978         ${EndIf}
 979
 980         ; Make sure the current selection is valid
 981         ${IfThen} $SelectedCPUType < 2 ${|} StrCpy $SelectedCPUType $DetectedCPUType ${|}
 982         ${IfThen} $SelectedCPUType > 5 ${|} StrCpy $SelectedCPUType $DetectedCPUType ${|}
 983
 984         ; Translate
 985         !insertmacro INSTALLOPTIONS_WRITE "Page_CPU.ini" "Field 1" "Text" "$(MPLAYER_LANG_SELECT_CPU_TYPE)"
 986         !insertmacro INSTALLOPTIONS_WRITE "Page_CPU.ini" "Field 6" "Text" "$(MPLAYER_LANG_SELECT_CPU_HINT)"
 987
 988         ; Apply current selection to dialog
 989         ${For} $0 2 5
 990                 ${If} $0 == $SelectedCPUType
 991                         !insertmacro INSTALLOPTIONS_WRITE "Page_CPU.ini" "Field $0" "State" "1"
 992                 ${Else}
 993                         !insertmacro INSTALLOPTIONS_WRITE "Page_CPU.ini" "Field $0" "State" "0"
 994                 ${EndIf}
 995         ${Next}
 996
 997         ; Display dialog
 998         !insertmacro MUI_HEADER_TEXT "$(MPLAYER_LANG_SELECT_CPU_HEAD)" "$(MPLAYER_LANG_SELECT_CPU_TEXT)"
 999         !insertmacro INSTALLOPTIONS_DISPLAY "Page_CPU.ini"
1000
1001         ; Read new selection from dialog
1002         StrCpy $SelectedCPUType 0
1003         ${For} $0 2 5
1004                 !insertmacro INSTALLOPTIONS_READ $1 "Page_CPU.ini" "Field $0" "State"
1005                 ${IfThen} $1 == 1 ${|} StrCpy $SelectedCPUType $0 ${|}
1006         ${Next}
1007 FunctionEnd
1008
1009 Function SelectCPUPage_Validate
1010         ; Read new selection from dialog
1011         StrCpy $2 0
1012         ${For} $0 2 5
1013                 !insertmacro INSTALLOPTIONS_READ $1 "Page_CPU.ini" "Field $0" "State"
1014                 ${IfThen} $1 == 1 ${|} StrCpy $2 $0 ${|}
1015         ${Next}
1016
1017         ; Validate selection
1018         ${If} $2 < 2
1019         ${OrIf} $2 > 5
1020                 MessageBox MB_ICONSTOP "Oups, invalid selection detected!"
1021                 Abort
1022         ${EndIf}
1023 FunctionEnd
1024
1025 Function DetectCPUType
1026         StrCpy $DetectedCPUType 5 ;generic
1027         StrCpy $DetectedCPUCores 2
1028
1029         ${IfNot} ${Silent}
1030                 Banner::show /NOUNLOAD "$(MPLAYER_LANG_DETECTING)"
1031         ${EndIf}
1032
1033         ${CPUFeatures.GetCount} $0
1034         ${IfNot} $0 == "error"
1035                 StrCpy $DetectedCPUCores $0
1036         ${EndIf}
1037
1038         ; Debug Code
1039         !ifdef CPU_DETECT_DEBUG
1040                 ${CPUFeatures.GetVendor} $0
1041                 ${CPUFeatures.CheckFeature} "MMX1"   $1
1042                 ${CPUFeatures.CheckFeature} "3DNOW"  $2
1043                 ${CPUFeatures.CheckFeature} "SSE3"   $3
1044                 ${CPUFeatures.CheckFeature} "SSSE3"  $4
1045                 ${CPUFeatures.CheckFeature} "SSE4.2" $5
1046                 ${CPUFeatures.CheckFeature} "AVX1"   $6
1047                 ${CPUFeatures.CheckFeature} "FMA4"   $7
1048                 StrCpy $9 `Vendor = $0`
1049                 StrCpy $9 `$9$\n"MMX1" = $1`
1050                 StrCpy $9 `$9$\n"3DNOW" = $2`
1051                 StrCpy $9 `$9$\n"SSE3" = $3`
1052                 StrCpy $9 `$9$\n"SSSE3" = $4`
1053                 StrCpy $9 `$9$\n"SSE4.2" = $5`
1054                 StrCpy $9 `$9$\n"AVX1" = $6`
1055                 StrCpy $9 `$9$\n"FMA4" = $7`
1056                 MessageBox MB_TOPMOST `$9`
1057         !endif
1058
1059         ; Make sure we have at least MMX
1060         ${IfNot} ${CPUSupports} "MMX1"
1061                 Banner::destroy
1062                 Return
1063         ${EndIf}
1064
1065         ; Select the "best" model for Intel's
1066         ${If} ${CPUIsIntel}
1067                 ; Core2 (SSE3 + SSSE3)
1068                 ${If} ${CPUSupportsAll} "SSE3,SSSE3"
1069                         StrCpy $DetectedCPUType 2 ;
1070                 ${EndIf}
1071                 ; Nehalem (SSE3 + SSSE3 + SSE4.2)
1072                 ${If} ${CPUSupportsAll} "SSE3,SSSE3,SSE4.2"
1073                         StrCpy $DetectedCPUType 3
1074                 ${EndIf}
1075         ${EndIf}
1076
1077         ; Select the "best" model for AMD's
1078         ${If} ${CPUIsAMD}
1079                 ; K8+SSE3 (3DNow! + SSE3)
1080                 ${If} ${CPUSupportsAll} "3DNOW,SSE3"
1081                         StrCpy $DetectedCPUType 4
1082                 ${EndIf}
1083                 ; Bulldozer (SSE3 + SSSE3 + SSE4.2 + AVX + FMA4)
1084                 ;${If} ${CPUSupportsAll} "SSE3,SSSE3,SSE4.2,AVX1,FMA4"
1085                 ;       StrCpy $DetectedCPUType 5       #5 is now generic, as 'bdver1' build got dropped
1086                 ;${EndIf}
1087         ${EndIf}
1088
1089         Banner::destroy
1090 FunctionEnd
1091
1092
1093 ;--------------------------------------------------------------------------------
1094 ; CUSTOME PAGE: TWEAKS
1095 ;--------------------------------------------------------------------------------
1096
1097 Function SetTweaksPage_Show
1098         ; Apply current selection to dialog
1099         StrCpy $0 1
1100         ${For} $1 2 4
1101                 IntOp $2 $0 & $SelectedTweaks
1102                 ${If} $2 != 0
1103                         !insertmacro INSTALLOPTIONS_WRITE "Page_Tweaks.ini" "Field $1" "State" "1"
1104                 ${Else}
1105                         !insertmacro INSTALLOPTIONS_WRITE "Page_Tweaks.ini" "Field $1" "State" "0"
1106                 ${EndIf}
1107                 IntOp $0 $0 << 1
1108         ${Next}
1109
1110         ; Translate
1111         !insertmacro INSTALLOPTIONS_WRITE "Page_Tweaks.ini" "Field 1" "Text" "$(MPLAYER_LANG_TWEAKS_HINT)"
1112         !insertmacro INSTALLOPTIONS_WRITE "Page_Tweaks.ini" "Field 2" "Text" "$(MPLAYER_LANG_TWEAKS_SKINNEDUI)"
1113         !insertmacro INSTALLOPTIONS_WRITE "Page_Tweaks.ini" "Field 3" "Text" "$(MPLAYER_LANG_TWEAKS_OPENGL)"
1114         !insertmacro INSTALLOPTIONS_WRITE "Page_Tweaks.ini" "Field 4" "Text" "$(MPLAYER_LANG_TWEAKS_VOLNORM)"
1115
1116         ; Display dialog
1117         !insertmacro MUI_HEADER_TEXT "$(MPLAYER_LANG_TWEAKS_HEAD)" "$(MPLAYER_LANG_TWEAKS_TEXT)"
1118         !insertmacro INSTALLOPTIONS_DISPLAY "Page_Tweaks.ini"
1119
1120         ; Read new selection from dialog
1121         StrCpy $0 1
1122         ${For} $1 2 4
1123                 !insertmacro INSTALLOPTIONS_READ $2 "Page_Tweaks.ini" "Field $1" "State"
1124                 ${IfThen} $2 == 1 ${|} IntOp $SelectedTweaks $SelectedTweaks | $0 ${|}
1125                 IntOp $0 $0 << 1
1126         ${Next}
1127 FunctionEnd
1128
1129
1130 ;--------------------------------------------------------------------------------
1131 ; CHECK FOR UPDATE MODE
1132 ;--------------------------------------------------------------------------------
1133
1134 !macro SetControlEnabled item_id enable
1135         FindWindow $0 "#32770" "" $HWNDPARENT
1136         ${IfNot} $0 == 0
1137                 GetDlgItem $1 $0 ${item_id}
1138                 EnableWindow $1 ${enable}
1139         ${EndIf}
1140 !macroend
1141
1142 !macro SkipToNextPage
1143         GetDlgItem $0 $HWNDPARENT 1
1144         System::Call "User32::PostMessage(i $HWNDPARENT, i ${WM_COMMAND}, i 1, i $R0)"
1145 !macroend
1146
1147 !macro EnablePathEditable flag show_msg
1148         !insertmacro SetControlEnabled 1019 ${flag}
1149         !insertmacro SetControlEnabled 1001 ${flag}
1150         ${IfNot} $NotUpdateInstall = ${flag}
1151                 !if ${show_msg} == 1
1152                         MessageBox MB_OK|MB_ICONINFORMATION "$(MPLAYER_LANG_FORCE_UPDATE)" /SD IDOK
1153                 !endif
1154                 StrCpy $NotUpdateInstall ${flag}
1155                 !insertmacro SkipToNextPage
1156         ${EndIf}
1157 !macroend
1158
1159 Function CheckForUpdate
1160         ${StdUtils.TestParameter} $0 "Update"
1161         ${If} "$0" == "true"
1162                 !insertmacro EnablePathEditable 0 0
1163                 Return
1164         ${EndIf}
1165
1166         ${If} ${FileExists} "$INSTDIR\MPlayer.exe"
1167                 ${If} $NotUpdateInstall = 1
1168                 ${AndIf} ${FileExists} "$INSTDIR\version.tag"
1169                         ReadINIStr $0 "$INSTDIR\version.tag" "mplayer_version" "build_no"
1170                         ${If} $0 > ${MPLAYER_BUILDNO}
1171                                 MessageBox MB_OK|MB_ICONEXCLAMATION "$(MPLAYER_LANG_CAN_NOT_UPDATE)"
1172                                 Quit
1173                         ${EndIf}
1174                         ${If} $0 = ${MPLAYER_BUILDNO}
1175                                 ${IfCmd} MessageBox MB_YESNO|MB_ICONEXCLAMATION "$(MPLAYER_LANG_CONFIRM_UPDATE)" /SD IDYES IDNO ${||} Quit ${|}
1176                         ${EndIf}
1177                 ${EndIf}
1178                 !insertmacro EnablePathEditable 0 1
1179                 Return
1180         ${EndIf}
1181
1182         !insertmacro EnablePathEditable 1 0
1183 FunctionEnd
1184
1185
1186 ;--------------------------------------------------------------------------------
1187 ; FINISHED
1188 ;--------------------------------------------------------------------------------
1189
1190 Function RunAppFunction
1191         !insertmacro DisableNextButton $R0
1192         ${If} ${FileExists} "$INSTDIR\SMPlayer.exe"
1193                 ${StdUtils.ExecShellAsUser} $R0 "$INSTDIR\SMPlayer.exe" "open" "http://lounge-office.rautemusik.fm/"
1194         ${Else}
1195                 ${StdUtils.ExecShellAsUser} $R0 "$INSTDIR\MPUI.exe" "open" "http://lounge-office.rautemusik.fm/"
1196         ${EndIf}
1197 FunctionEnd
1198
1199 Function ShowReadmeFunction
1200         !insertmacro DisableNextButton $R0
1201         ${StdUtils.ExecShellAsUser} $R0 "$INSTDIR\Readme.html" "open" ""
1202 FunctionEnd
1203
1204 Function .onInstSuccess
1205         ${StdUtils.ExecShellAsUser} $R0 "$SMPROGRAMS\$StartMenuFolder" "explore" ""
1206 FunctionEnd
1207
1208
1209 ### EOF ###