mpsl.l

   1 %{
   2 /*
   3
   4     MPSL - Minimum Profit Scripting Language
   5     Copyright (C) 2003/2007 Angel Ortega <angel@triptico.com>
   6
   7     mpsl.l - Minimum Profit Scripting Language [F]lexer
   8
   9     This program is free software; you can redistribute it and/or
  10     modify it under the terms of the GNU General Public License
  11     as published by the Free Software Foundation; either version 2
  12     of the License, or (at your option) any later version.
  13
  14     This program is distributed in the hope that it will be useful,
  15     but WITHOUT ANY WARRANTY; without even the implied warranty of
  16     MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17     GNU General Public License for more details.
  18
  19     You should have received a copy of the GNU General Public License
  20     along with this program; if not, write to the Free Software
  21     Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111-1307, USA.
  22
  23     http://www.triptico.com
  24
  25 */
  26
  27 #include <stdio.h>
  28 #include <wchar.h>
  29 #include "mpdm.h"
  30
  31 #include <stdlib.h>
  32 #include "y.tab.h"
  33
  34 void yyerror(char * s);
  35 int yy_input_for_flex(char * buf, int max);
  36
  37 /* redefinition of input function for GNU Flex */
  38 #undef YY_INPUT
  39 #define YY_INPUT(b,r,m) (r = yy_input_for_flex(b,m))
  40
  41 /* internal pointer to next character in code */
  42 wchar_t *mpsl_next_char = NULL;
  43
  44 /* file stream for compiling from file */
  45 FILE *mpsl_file = NULL;
  46
  47 /* line number */
  48 int mpsl_line = 0;
  49
  50 /* cached value MPSL.LC */
  51 mpdm_t mpsl_lc = NULL;
  52
  53 /* dynamic string manipulation macros */
  54 #ifndef ds_init
  55 struct ds { wchar_t * d; int p; int s; };
  56 #define ds_init(x) do { x.d = (wchar_t *)0; x.p = x.s = 0; } while(0)
  57 #define ds_rewind(x) x.p = 0;
  58 #define ds_free(x) do { if(x.d) free(x.d); ds_init(x); } while(0)
  59 #define ds_redim(x) do { if(x.p >= x.s) x.d = realloc(x.d, ++x.s * sizeof(wchar_t)); } while(0)
  60 #define ds_poke(x,c) do { ds_redim(x); x.d[x.p++] = c; } while(0)
  61 #define ds_pokes(x,t) do { wchar_t *p = t; while(*p) ds_poke(x, *p++); } while(0)
  62 #endif /* ds_init */
  63
  64 /* a dynamic string */
  65 struct ds ds_v;
  66
  67 static wchar_t *s_mbstowcs(char *str)
  68 /* converts from mbs to wcs, using a static buffer */
  69 {
  70         static wchar_t * wc = NULL;
  71         static int wc_s = 0;
  72         int n;
  73
  74         /* allocs wchar_t space, if needed */
  75         if ((n = mbstowcs(NULL, str, 0)) > wc_s) {
  76                 wc_s = n;
  77                 wc = realloc(wc, (wc_s + 1) * sizeof(wchar_t));
  78         }
  79
  80         /* really converts */
  81         mbstowcs(wc, str, n);
  82         wc[n] = L'\0';
  83
  84         return wc;
  85 }
  86
  87
  88 static mpdm_t literal_cache(char *ptr, wchar_t *wptr)
  89 /* the cache of literal values */
  90 {
  91         mpdm_t v;
  92
  93         /* convert to wchar_t */
  94         if (ptr != NULL)
  95                 wptr = s_mbstowcs(ptr);
  96
  97         /* search in cache */
  98         if ((v = mpdm_hget_s(mpsl_lc, wptr)) == NULL) {
  99                 v = MPDM_S(wptr);
 100                 mpdm_hset(mpsl_lc, v, v);
 101         }
 102
 103         return v;
 104 }
 105
 106
 107 %}
 108
 109 DIGIT           [0-9]
 110 LETTER          [a-zA-Z_]
 111 WSPACE          [ \t\r]+
 112 OCTDIGIT        [0-7]
 113 HEXDIGIT        [0-9a-fA-F]
 114 HEXQUAD         {HEXDIGIT}{1,4}
 115
 116 DECINTEGER      {DIGIT}+
 117 OCTINTEGER      0{OCTDIGIT}+
 118 HEXINTEGER      0[xX]{HEXDIGIT}+
 119
 120 REAL            {DIGIT}*[\.]?{DIGIT}+
 121 SCIENT          {DIGIT}+(\.{DIGIT}+)?[eE][-+]?{DIGIT}+
 122 SYMBOL          {LETTER}({LETTER}|{DIGIT})*
 123 INTEGER         ({DECINTEGER}|{OCTINTEGER}|{HEXINTEGER})
 124
 125 %x REM
 126 %x STR
 127
 128 %%
 129
 130 {INTEGER}       {
 131                         /* integers */
 132                         yylval.v = literal_cache(yytext, NULL);
 133                         return INTEGER;
 134                 }
 135
 136 ({REAL}|{SCIENT})       {
 137                         /* real numbers */
 138                         yylval.v = literal_cache(yytext, NULL);
 139                         return REAL;
 140                 }
 141
 142 \'[^']*\'       {
 143                         /* single quoted string; return as is */
 144                         yytext[yyleng - 1] = '\0';
 145                         yylval.v = literal_cache(yytext + 1, NULL);
 146                         return STRING;
 147                 }
 148
 149 "NULL"          return NULLV;
 150 "while"         return WHILE;
 151 "if"            return IF;
 152 "else"          return ELSE;
 153 "sub"           return SUB;
 154 "foreach"       return FOREACH;
 155 "local"         return LOCAL;
 156 "break"         return BREAK;
 157 "return"        return RETURN;
 158
 159 "=="            return NUMEQ;
 160 "!="            return NUMNE;
 161 ">="            return NUMGE;
 162 "<="            return NUMLE;
 163 "&&"            return BOOLAND;
 164 "||"            return BOOLOR;
 165 "=>"            return HASHPAIR;
 166 ".."            return RANGE;
 167 "&"             return BITAND;
 168 "|"             return BITOR;
 169 "^"             return BITXOR;
 170
 171 "eq"            return STREQ;
 172 "ne"            return STRNE;
 173 "~"             return STRCAT;
 174
 175 "++"            return INC;
 176 "--"            return DEC;
 177 "+="            return IADD;
 178 "-="            return ISUB;
 179 "*="            return IMUL;
 180 "/="            return IDIV;
 181 "%"             return MOD;
 182 "%="            return IMOD;
 183
 184 {SYMBOL}        {
 185                         /* symbol name */
 186                         yylval.v = literal_cache(yytext, NULL);
 187                         return SYMBOL;
 188                 }
 189
 190 {WSPACE}        ;       /* ignore spaces */
 191
 192 \n              { mpsl_line++; }
 193
 194 \/\*            { BEGIN REM; /* C-like comments */ }
 195 <REM>\*\/       { BEGIN 0; }
 196 <REM>\n         { mpsl_line++; }
 197 <REM>.          ;
 198
 199 \"              { BEGIN STR; ds_rewind(ds_v); }
 200 <STR>\n         { ds_poke(ds_v, L'\n'); mpsl_line++; }
 201 <STR>\\n        { ds_poke(ds_v, L'\n'); }
 202 <STR>\\t        { ds_poke(ds_v, L'\t'); }
 203 <STR>\\r        { ds_poke(ds_v, L'\r'); }
 204 <STR>\\e        { ds_poke(ds_v, 27); }
 205 <STR>\\\"       { ds_poke(ds_v, L'\"'); }
 206 <STR>\\\\       { ds_poke(ds_v, L'\\'); }
 207 <STR>\"\\\n[ \t]+\"     ;
 208 <STR>\"         {
 209                         ds_poke(ds_v, L'\0');
 210                         yylval.v = literal_cache(NULL, ds_v.d);
 211                         BEGIN 0;
 212                         return STRING;
 213                 }
 214 <STR>\\x\{{HEXQUAD}\} {
 215                         int c;
 216
 217                         sscanf(yytext, "\\x{%x}", &c);
 218                         ds_poke(ds_v, (wchar_t) c);
 219                 }
 220 <STR>.          { wchar_t wc; if (mbtowc(&wc, yytext, 1) > 0) ds_poke(ds_v, wc); }
 221
 222 .               { return *yytext; }
 223
 224 %%
 225
 226 int yywrap(void) { return 1; }
 227
 228 int yy_input_for_flex(char *buf, int max)
 229 {
 230         int n = 0;
 231
 232         if (mpsl_file != NULL) {
 233                 while (n < max) {
 234                         int c;
 235
 236                         if ((c = fgetc(mpsl_file)) == EOF) {
 237                                 mpsl_file = NULL;
 238                                 break;
 239                         }
 240
 241                         buf[n++] = c;
 242                 }
 243         }
 244         else
 245         if (mpsl_next_char != NULL) {
 246                 for (;;) {
 247                         char tmp[64];   /* really MB_CUR_MAX + 1 */
 248                         int c, i;
 249
 250                         if (*mpsl_next_char == L'\0' ||
 251                            (c = wctomb(tmp, *mpsl_next_char)) < 0) {
 252                                 mpsl_next_char = NULL;
 253                                 break;
 254                         }
 255
 256                         /* no room? try next time */
 257                         if (n + c >= max)
 258                                 break;
 259
 260                         mpsl_next_char++;
 261
 262                         /* transfer */
 263                         for (i = 0; i < c; i++)
 264                                 buf[n++] = tmp[i];
 265                 }
 266         }
 267
 268         return n;
 269 }