mpsl.l

   1 %{
   2 /*
   3
   4     MPSL - Minimum Profit Scripting Language
   5     Copyright (C) 2003/2010 Angel Ortega <angel@triptico.com>
   6
   7     mpsl.l - Minimum Profit Scripting Language [F]lexer
   8
   9     This program is free software; you can redistribute it and/or
  10     modify it under the terms of the GNU General Public License
  11     as published by the Free Software Foundation; either version 2
  12     of the License, or (at your option) any later version.
  13
  14     This program is distributed in the hope that it will be useful,
  15     but WITHOUT ANY WARRANTY; without even the implied warranty of
  16     MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17     GNU General Public License for more details.
  18
  19     You should have received a copy of the GNU General Public License
  20     along with this program; if not, write to the Free Software
  21     Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111-1307, USA.
  22
  23     http://www.triptico.com
  24
  25 */
  26
  27 #include <stdio.h>
  28 #include <wchar.h>
  29 #include "mpdm.h"
  30
  31 #include <stdlib.h>
  32 #include "y.tab.h"
  33
  34 void yyerror(char *s);
  35 int yy_input_for_flex(char *buf, int max);
  36
  37 /* redefinition of input function for GNU Flex */
  38 #undef YY_INPUT
  39 #define YY_INPUT(b,r,m) (r = yy_input_for_flex(b,m))
  40
  41 /* internal pointer to next character in code */
  42 wchar_t *mpsl_next_char = NULL;
  43
  44 /* file stream for compiling from file */
  45 FILE *mpsl_file = NULL;
  46
  47 /* line number */
  48 int mpsl_line = 0;
  49
  50 /* cached value MPSL.LC */
  51 mpdm_t mpsl_lc = NULL;
  52
  53 /* dynamic string manipulation macros */
  54 #ifndef ds_init
  55 struct ds {
  56     wchar_t *d;
  57     int p;
  58     int s;
  59 };
  60 #define ds_init(x) do { x.d = (wchar_t *)0; x.p = x.s = 0; } while(0)
  61 #define ds_rewind(x) x.p = 0;
  62 #define ds_free(x) do { if(x.d) free(x.d); ds_init(x); } while(0)
  63 #define ds_redim(x) do { if(x.p >= x.s) x.d = realloc(x.d, ++x.s * sizeof(wchar_t)); } while(0)
  64 #define ds_poke(x,c) do { ds_redim(x); x.d[x.p++] = c; } while(0)
  65 #define ds_pokes(x,t) do { wchar_t *p = t; while(*p) ds_poke(x, *p++); } while(0)
  66 #endif                          /* ds_init */
  67
  68 /* a dynamic string */
  69 struct ds ds_v;
  70
  71 static wchar_t *s_mbstowcs(char *str)
  72 /* converts from mbs to wcs, using a static buffer */
  73 {
  74     static wchar_t *wc = NULL;
  75     static int wc_s = 0;
  76     int n;
  77
  78     /* allocs wchar_t space, if needed */
  79     if ((n = mbstowcs(NULL, str, 0)) > wc_s) {
  80         wc_s = n;
  81         wc = realloc(wc, (wc_s + 1) * sizeof(wchar_t));
  82     }
  83
  84     /* really converts */
  85     mbstowcs(wc, str, n);
  86     wc[n] = L'\0';
  87
  88     return wc;
  89 }
  90
  91
  92 static mpdm_t literal_cache(char *ptr, wchar_t * wptr)
  93 /* the cache of literal values */
  94 {
  95     mpdm_t v;
  96
  97     /* convert to wchar_t */
  98     if (ptr != NULL)
  99         wptr = s_mbstowcs(ptr);
 100
 101     /* search in cache */
 102     if ((v = mpdm_hget_s(mpsl_lc, wptr)) == NULL) {
 103         v = MPDM_S(wptr);
 104         mpdm_hset(mpsl_lc, v, v);
 105     }
 106
 107     return v;
 108 }
 109
 110
 111 %}
 112
 113 DIGIT           [0-9]
 114 LETTER          [a-zA-Z_]
 115 WSPACE          [ \t\r]+
 116 OCTDIGIT        [0-7]
 117 HEXDIGIT        [0-9a-fA-F]
 118 BINDIGIT        [0-1]
 119 HEXQUAD         {HEXDIGIT}{1,4}
 120
 121 DECINTEGER      {DIGIT}+
 122 OCTINTEGER      0{OCTDIGIT}+
 123 HEXINTEGER      0[xX]{HEXDIGIT}+
 124 BININTEGER      0[bB]{BINDIGIT}+
 125
 126 REAL            {DIGIT}*[\.]?{DIGIT}+
 127 SCIENT          {DIGIT}+(\.{DIGIT}+)?[eE][-+]?{DIGIT}+
 128 SYMBOL          {LETTER}({LETTER}|{DIGIT})*
 129 INTEGER         ({DECINTEGER}|{OCTINTEGER}|{HEXINTEGER}|{BININTEGER})
 130
 131 %x REM
 132 %x STR
 133
 134 %%
 135
 136 {INTEGER}       {
 137                         /* integers */
 138                         yylval.v = literal_cache(yytext, NULL);
 139                         return INTEGER;
 140                 }
 141
 142 ({REAL}|{SCIENT})       {
 143                         /* real numbers */
 144                         yylval.v = literal_cache(yytext, NULL);
 145                         return REAL;
 146                 }
 147
 148 \'[^']*\'       {
 149                         /* single quoted string; return as is */
 150                         yytext[yyleng - 1] = '\0';
 151                         yylval.v = literal_cache(yytext + 1, NULL);
 152                         return STRING;
 153                 }
 154
 155 "NULL"          return NULLV;
 156 "while"         return WHILE;
 157 "if"            return IF;
 158 "else"          return ELSE;
 159 "sub"           return SUB;
 160 "foreach"       return FOREACH;
 161 "local"         return LOCAL;
 162 "break"         return BREAK;
 163 "return"        return RETURN;
 164
 165 "=="            return NUMEQ;
 166 "!="            return NUMNE;
 167 ">="            return NUMGE;
 168 "<="            return NUMLE;
 169 "&&"            return BOOLAND;
 170 "||"            return BOOLOR;
 171 "=>"            return HASHPAIR;
 172 ".."            return RANGE;
 173 "&"             return AMPERSAND;
 174 "|"             return BITOR;
 175 "^"             return BITXOR;
 176 "<<"    return SHL;
 177 ">>"    return SHR;
 178 "->"            return INVCALL;
 179
 180 "eq"            return STREQ;
 181 "ne"            return STRNE;
 182 "~"             return STRCAT;
 183
 184 "++"            return INC;
 185 "--"            return DEC;
 186 "+="            return IADD;
 187 "-="            return ISUB;
 188 "*="            return IMUL;
 189 "/="            return IDIV;
 190 "%"             return MOD;
 191 "%="            return IMOD;
 192 "&="            return IBITAND;
 193 "|="            return IBITOR;
 194 "^="            return IBITXOR;
 195 "<<="           return ISHL;
 196 ">>="           return ISHR;
 197 "**"            return POW;
 198
 199 {SYMBOL}        {
 200                         /* symbol name */
 201                         yylval.v = literal_cache(yytext, NULL);
 202                         return SYMBOL;
 203                 }
 204
 205 {WSPACE}        ;       /* ignore spaces */
 206
 207 \n              { mpsl_line++; }
 208
 209 \/\*            { BEGIN REM; /* C-like comments */ }
 210 <REM>\*\/       { BEGIN 0; }
 211 <REM>\n         { mpsl_line++; }
 212 <REM>.          ;
 213
 214 \"              { BEGIN STR; ds_rewind(ds_v); }
 215 <STR>\n         { ds_poke(ds_v, L'\n'); mpsl_line++; }
 216 <STR>\\n        { ds_poke(ds_v, L'\n'); }
 217 <STR>\\t        { ds_poke(ds_v, L'\t'); }
 218 <STR>\\r        { ds_poke(ds_v, L'\r'); }
 219 <STR>\\e        { ds_poke(ds_v, 27); }
 220 <STR>\\\"       { ds_poke(ds_v, L'\"'); }
 221 <STR>\\\\       { ds_poke(ds_v, L'\\'); }
 222 <STR>\"\\\n[ \t]+\"     ;
 223 <STR>\"         {
 224                         ds_poke(ds_v, L'\0');
 225                         yylval.v = literal_cache(NULL, ds_v.d);
 226                         BEGIN 0;
 227                         return STRING;
 228                 }
 229 <STR>\\x\{{HEXQUAD}\} {
 230                         int c;
 231
 232                         sscanf(yytext, "\\x{%x}", &c);
 233                         ds_poke(ds_v, (wchar_t) c);
 234                 }
 235 <STR>.          { wchar_t wc; if (mbtowc(&wc, yytext, 1) > 0) ds_poke(ds_v, wc); }
 236
 237 .               { return *yytext; }
 238
 239 %%
 240
 241 int yywrap(void)
 242 {
 243     return 1;
 244 }
 245
 246 int yy_input_for_flex(char *buf, int max)
 247 {
 248     int n = 0;
 249
 250     if (mpsl_file != NULL) {
 251         while (n < max) {
 252             int c;
 253
 254             if ((c = fgetc(mpsl_file)) == EOF) {
 255                 mpsl_file = NULL;
 256                 break;
 257             }
 258
 259             buf[n++] = c;
 260         }
 261     }
 262     else if (mpsl_next_char != NULL) {
 263         for (;;) {
 264             char tmp[64];       /* really MB_CUR_MAX + 1 */
 265             int c, i;
 266
 267             if (*mpsl_next_char == L'\0' ||
 268                 (c = wctomb(tmp, *mpsl_next_char)) < 0) {
 269                 mpsl_next_char = NULL;
 270                 break;
 271             }
 272
 273             /* no room? try next time */
 274             if (n + c >= max)
 275                 break;
 276
 277             mpsl_next_char++;
 278
 279             /* transfer */
 280             for (i = 0; i < c; i++)
 281                 buf[n++] = tmp[i];
 282         }
 283     }
 284
 285     return n;
 286 }