git/git-cvsexportcommit.perl

   1 #!/usr/bin/perl -w
   2
   3 # Known limitations:
   4 # - does not propagate permissions
   5 # - error handling has not been extensively tested
   6 #
   7
   8 use strict;
   9 use Getopt::Std;
  10 use File::Temp qw(tempdir);
  11 use Data::Dumper;
  12 use File::Basename qw(basename dirname);
  13
  14 unless ($ENV{GIT_DIR} && -r $ENV{GIT_DIR}){
  15     die "GIT_DIR is not defined or is unreadable";
  16 }
  17
  18 our ($opt_h, $opt_P, $opt_p, $opt_v, $opt_c, $opt_f, $opt_a, $opt_m, $opt_d, $opt_u);
  19
  20 getopts('uhPpvcfam:d:');
  21
  22 $opt_h && usage();
  23
  24 die "Need at least one commit identifier!" unless @ARGV;
  25
  26 my @cvs;
  27 if ($opt_d) {
  28         @cvs = ('cvs', '-d', $opt_d);
  29 } else {
  30         @cvs = ('cvs');
  31 }
  32
  33 # setup a tempdir
  34 our ($tmpdir, $tmpdirname) = tempdir('git-cvsapplycommit-XXXXXX',
  35                                      TMPDIR => 1,
  36                                      CLEANUP => 1);
  37
  38 # resolve target commit
  39 my $commit;
  40 $commit = pop @ARGV;
  41 $commit = safe_pipe_capture('git-rev-parse', '--verify', "$commit^0");
  42 chomp $commit;
  43 if ($?) {
  44     die "The commit reference $commit did not resolve!";
  45 }
  46
  47 # resolve what parent we want
  48 my $parent;
  49 if (@ARGV) {
  50     $parent = pop @ARGV;
  51     $parent =  safe_pipe_capture('git-rev-parse', '--verify', "$parent^0");
  52     chomp $parent;
  53     if ($?) {
  54         die "The parent reference did not resolve!";
  55     }
  56 }
  57
  58 # find parents from the commit itself
  59 my @commit  = safe_pipe_capture('git-cat-file', 'commit', $commit);
  60 my @parents;
  61 my $committer;
  62 my $author;
  63 my $stage = 'headers'; # headers, msg
  64 my $title;
  65 my $msg = '';
  66
  67 foreach my $line (@commit) {
  68     chomp $line;
  69     if ($stage eq 'headers' && $line eq '') {
  70         $stage = 'msg';
  71         next;
  72     }
  73
  74     if ($stage eq 'headers') {
  75         if ($line =~ m/^parent (\w{40})$/) { # found a parent
  76             push @parents, $1;
  77         } elsif ($line =~ m/^author (.+) \d+ [-+]\d+$/) {
  78             $author = $1;
  79         } elsif ($line =~ m/^committer (.+) \d+ [-+]\d+$/) {
  80             $committer = $1;
  81         }
  82     } else {
  83         $msg .= $line . "\n";
  84         unless ($title) {
  85             $title = $line;
  86         }
  87     }
  88 }
  89
  90 if ($parent) {
  91     my $found;
  92     # double check that it's a valid parent
  93     foreach my $p (@parents) {
  94         if ($p eq $parent) {
  95             $found = 1;
  96             last;
  97         }; # found it
  98     }
  99     die "Did not find $parent in the parents for this commit!" if !$found and !$opt_P;
 100 } else { # we don't have a parent from the cmdline...
 101     if (@parents == 1) { # it's safe to get it from the commit
 102         $parent = $parents[0];
 103     } else { # or perhaps not!
 104         die "This commit has more than one parent -- please name the parent you want to use explicitly";
 105     }
 106 }
 107
 108 $opt_v && print "Applying to CVS commit $commit from parent $parent\n";
 109
 110 # grab the commit message
 111 open(MSG, ">.msg") or die "Cannot open .msg for writing";
 112 if ($opt_m) {
 113     print MSG $opt_m;
 114 }
 115 print MSG $msg;
 116 if ($opt_a) {
 117     print MSG "\n\nAuthor: $author\n";
 118     if ($author ne $committer) {
 119         print MSG "Committer: $committer\n";
 120     }
 121 }
 122 close MSG;
 123
 124 `git-diff-tree --binary -p $parent $commit >.cvsexportcommit.diff`;# || die "Cannot diff";
 125
 126 ## apply non-binary changes
 127
 128 # In pedantic mode require all lines of context to match.  In normal
 129 # mode, be compatible with diff/patch: assume 3 lines of context and
 130 # require at least one line match, i.e. ignore at most 2 lines of
 131 # context, like diff/patch do by default.
 132 my $context = $opt_p ? '' : '-C1';
 133
 134 print "Checking if patch will apply\n";
 135
 136 my @stat;
 137 open APPLY, "GIT_DIR= git-apply $context --binary --summary --numstat<.cvsexportcommit.diff|" || die "cannot patch";
 138 @stat=<APPLY>;
 139 close APPLY || die "Cannot patch";
 140 my (@bfiles,@files,@afiles,@dfiles);
 141 chomp @stat;
 142 foreach (@stat) {
 143         push (@bfiles,$1) if m/^-\t-\t(.*)$/;
 144         push (@files, $1) if m/^-\t-\t(.*)$/;
 145         push (@files, $1) if m/^\d+\t\d+\t(.*)$/;
 146         push (@afiles,$1) if m/^ create mode [0-7]+ (.*)$/;
 147         push (@dfiles,$1) if m/^ delete mode [0-7]+ (.*)$/;
 148 }
 149 map { s/^"(.*)"$/$1/g } @bfiles,@files;
 150 map { s/\\([0-7]{3})/sprintf('%c',oct $1)/eg } @bfiles,@files;
 151
 152 # check that the files are clean and up to date according to cvs
 153 my $dirty;
 154 my @dirs;
 155 foreach my $p (@afiles) {
 156     my $path = dirname $p;
 157     while (!-d $path and ! grep { $_ eq $path } @dirs) {
 158         unshift @dirs, $path;
 159         $path = dirname $path;
 160     }
 161 }
 162
 163 # ... check dirs,
 164 foreach my $d (@dirs) {
 165     if (-e $d) {
 166         $dirty = 1;
 167         warn "$d exists and is not a directory!\n";
 168     }
 169 }
 170
 171 # ... query status of all files that we have a directory for and parse output of 'cvs status' to %cvsstat.
 172 my @canstatusfiles;
 173 foreach my $f (@files) {
 174     my $path = dirname $f;
 175     next if (grep { $_ eq $path } @dirs);
 176     push @canstatusfiles, $f;
 177 }
 178
 179 my %cvsstat;
 180 if (@canstatusfiles) {
 181     if ($opt_u) {
 182       my @updated = safe_pipe_capture(@cvs, 'update', @canstatusfiles);
 183       print @updated;
 184     }
 185     my @cvsoutput;
 186     @cvsoutput= safe_pipe_capture(@cvs, 'status', @canstatusfiles);
 187     my $matchcount = 0;
 188     foreach my $l (@cvsoutput) {
 189         chomp $l;
 190         if ( $l =~ /^File:/ and  $l =~ /Status: (.*)$/ ) {
 191             $cvsstat{$canstatusfiles[$matchcount]} = $1;
 192             $matchcount++;
 193         }
 194     }
 195 }
 196
 197 # ... validate new files,
 198 foreach my $f (@afiles) {
 199     if (defined ($cvsstat{$f}) and $cvsstat{$f} ne "Unknown") {
 200         $dirty = 1;
 201         warn "File $f is already known in your CVS checkout -- perhaps it has been added by another user. Or this may indicate that it exists on a different branch. If this is the case, use -f to force the merge.\n";
 202         warn "Status was: $cvsstat{$f}\n";
 203     }
 204 }
 205 # ... validate known files.
 206 foreach my $f (@files) {
 207     next if grep { $_ eq $f } @afiles;
 208     # TODO:we need to handle removed in cvs
 209     unless (defined ($cvsstat{$f}) and $cvsstat{$f} eq "Up-to-date") {
 210         $dirty = 1;
 211         warn "File $f not up to date but has status '$cvsstat{$f}' in your CVS checkout!\n";
 212     }
 213 }
 214 if ($dirty) {
 215     if ($opt_f) {       warn "The tree is not clean -- forced merge\n";
 216         $dirty = 0;
 217     } else {
 218         die "Exiting: your CVS tree is not clean for this merge.";
 219     }
 220 }
 221
 222 print "Applying\n";
 223 `GIT_DIR= git-apply $context --binary --summary --numstat --apply <.cvsexportcommit.diff` || die "cannot patch";
 224
 225 print "Patch applied successfully. Adding new files and directories to CVS\n";
 226 my $dirtypatch = 0;
 227 foreach my $d (@dirs) {
 228     if (system(@cvs,'add',$d)) {
 229         $dirtypatch = 1;
 230         warn "Failed to cvs add directory $d -- you may need to do it manually";
 231     }
 232 }
 233
 234 foreach my $f (@afiles) {
 235     if (grep { $_ eq $f } @bfiles) {
 236       system(@cvs, 'add','-kb',$f);
 237     } else {
 238       system(@cvs, 'add', $f);
 239     }
 240     if ($?) {
 241         $dirtypatch = 1;
 242         warn "Failed to cvs add $f -- you may need to do it manually";
 243     }
 244 }
 245
 246 foreach my $f (@dfiles) {
 247     system(@cvs, 'rm', '-f', $f);
 248     if ($?) {
 249         $dirtypatch = 1;
 250         warn "Failed to cvs rm -f $f -- you may need to do it manually";
 251     }
 252 }
 253
 254 print "Commit to CVS\n";
 255 print "Patch title (first comment line): $title\n";
 256 my @commitfiles = map { unless (m/\s/) { '\''.$_.'\''; } else { $_; }; } (@files);
 257 my $cmd = join(' ', @cvs)." commit -F .msg @commitfiles";
 258
 259 if ($dirtypatch) {
 260     print "NOTE: One or more hunks failed to apply cleanly.\n";
 261     print "You'll need to apply the patch in .cvsexportcommit.diff manually\n";
 262     print "using a patch program. After applying the patch and resolving the\n";
 263     print "problems you may commit using:";
 264     print "\n    $cmd\n\n";
 265     exit(1);
 266 }
 267
 268 if ($opt_c) {
 269     print "Autocommit\n  $cmd\n";
 270     print safe_pipe_capture(@cvs, 'commit', '-F', '.msg', @files);
 271     if ($?) {
 272         die "Exiting: The commit did not succeed";
 273     }
 274     print "Committed successfully to CVS\n";
 275     # clean up
 276     unlink(".msg");
 277 } else {
 278     print "Ready for you to commit, just run:\n\n   $cmd\n";
 279 }
 280
 281 # clean up
 282 unlink(".cvsexportcommit.diff");
 283
 284 sub usage {
 285         print STDERR <<END;
 286 Usage: GIT_DIR=/path/to/.git ${\basename $0} [-h] [-p] [-v] [-c] [-f] [-m msgprefix] [ parent ] commit
 287 END
 288         exit(1);
 289 }
 290
 291 # An alternative to `command` that allows input to be passed as an array
 292 # to work around shell problems with weird characters in arguments
 293 # if the exec returns non-zero we die
 294 sub safe_pipe_capture {
 295     my @output;
 296     if (my $pid = open my $child, '-|') {
 297         @output = (<$child>);
 298         close $child or die join(' ',@_).": $! $?";
 299     } else {
 300         exec(@_) or die "$! $?"; # exec() can fail the executable can't be found
 301     }
 302     return wantarray ? @output : join('',@output);
 303 }
 304
 305 sub safe_pipe_capture_blob {
 306     my $output;
 307     if (my $pid = open my $child, '-|') {
 308         local $/;
 309         undef $/;
 310         $output = (<$child>);
 311         close $child or die join(' ',@_).": $! $?";
 312     } else {
 313         exec(@_) or die "$! $?"; # exec() can fail the executable can't be found
 314     }
 315     return $output;
 316 }