lib/perl5/5.6.1/AutoLoader.pm

   1 package AutoLoader;
   2
   3 use 5.6.0;
   4 our(@EXPORT, @EXPORT_OK, $VERSION);
   5
   6 my $is_dosish;
   7 my $is_epoc;
   8 my $is_vms;
   9 my $is_macos;
  10
  11 BEGIN {
  12     require Exporter;
  13     @EXPORT = @EXPORT = ();
  14     @EXPORT_OK = @EXPORT_OK = qw(AUTOLOAD);
  15     $is_dosish = $^O eq 'dos' || $^O eq 'os2' || $^O eq 'MSWin32';
  16     $is_epoc = $^O eq 'epoc';
  17     $is_vms = $^O eq 'VMS';
  18     $is_macos = $^O eq 'MacOS';
  19     $VERSION = '5.58';
  20 }
  21
  22 AUTOLOAD {
  23     my $sub = $AUTOLOAD;
  24     my $filename;
  25     # Braces used to preserve $1 et al.
  26     {
  27         # Try to find the autoloaded file from the package-qualified
  28         # name of the sub. e.g., if the sub needed is
  29         # Getopt::Long::GetOptions(), then $INC{Getopt/Long.pm} is
  30         # something like '/usr/lib/perl5/Getopt/Long.pm', and the
  31         # autoload file is '/usr/lib/perl5/auto/Getopt/Long/GetOptions.al'.
  32         #
  33         # However, if @INC is a relative path, this might not work.  If,
  34         # for example, @INC = ('lib'), then $INC{Getopt/Long.pm} is
  35         # 'lib/Getopt/Long.pm', and we want to require
  36         # 'auto/Getopt/Long/GetOptions.al' (without the leading 'lib').
  37         # In this case, we simple prepend the 'auto/' and let the
  38         # C<require> take care of the searching for us.
  39
  40         my ($pkg,$func) = ($sub =~ /(.*)::([^:]+)$/);
  41         $pkg =~ s#::#/#g;
  42         if (defined($filename = $INC{"$pkg.pm"})) {
  43             if ($is_macos) {
  44                 $pkg =~ tr#/#:#;
  45                 $filename =~ s#^(.*)$pkg\.pm\z#$1auto:$pkg:$func.al#s;
  46             } else {
  47                 $filename =~ s#^(.*)$pkg\.pm\z#$1auto/$pkg/$func.al#s;
  48             }
  49
  50             # if the file exists, then make sure that it is a
  51             # a fully anchored path (i.e either '/usr/lib/auto/foo/bar.al',
  52             # or './lib/auto/foo/bar.al'.  This avoids C<require> searching
  53             # (and failing) to find the 'lib/auto/foo/bar.al' because it
  54             # looked for 'lib/lib/auto/foo/bar.al', given @INC = ('lib').
  55
  56             if (-r $filename) {
  57                 unless ($filename =~ m|^/|s) {
  58                     if ($is_dosish) {
  59                         unless ($filename =~ m{^([a-z]:)?[\\/]}is) {
  60                              $filename = "./$filename";
  61                         }
  62                     }
  63                     elsif ($is_epoc) {
  64                         unless ($filename =~ m{^([a-z?]:)?[\\/]}is) {
  65                              $filename = "./$filename";
  66                         }
  67                     }
  68                     elsif ($is_vms) {
  69                         # XXX todo by VMSmiths
  70                         $filename = "./$filename";
  71                     }
  72                     elsif (!$is_macos) {
  73                         $filename = "./$filename";
  74                     }
  75                 }
  76             }
  77             else {
  78                 $filename = undef;
  79             }
  80         }
  81         unless (defined $filename) {
  82             # let C<require> do the searching
  83             $filename = "auto/$sub.al";
  84             $filename =~ s#::#/#g;
  85         }
  86     }
  87     my $save = $@;
  88     eval { local $SIG{__DIE__}; require $filename };
  89     if ($@) {
  90         if (substr($sub,-9) eq '::DESTROY') {
  91             *$sub = sub {};
  92         } else {
  93             # The load might just have failed because the filename was too
  94             # long for some old SVR3 systems which treat long names as errors.
  95             # If we can succesfully truncate a long name then it's worth a go.
  96             # There is a slight risk that we could pick up the wrong file here
  97             # but autosplit should have warned about that when splitting.
  98             if ($filename =~ s/(\w{12,})\.al$/substr($1,0,11).".al"/e){
  99                 eval { local $SIG{__DIE__}; require $filename };
 100             }
 101             if ($@){
 102                 $@ =~ s/ at .*\n//;
 103                 my $error = $@;
 104                 require Carp;
 105                 Carp::croak($error);
 106             }
 107         }
 108     }
 109     $@ = $save;
 110     goto &$sub;
 111 }
 112
 113 sub import {
 114     my $pkg = shift;
 115     my $callpkg = caller;
 116
 117     #
 118     # Export symbols, but not by accident of inheritance.
 119     #
 120
 121     if ($pkg eq 'AutoLoader') {
 122       local $Exporter::ExportLevel = 1;
 123       Exporter::import $pkg, @_;
 124     }
 125
 126     #
 127     # Try to find the autosplit index file.  Eg., if the call package
 128     # is POSIX, then $INC{POSIX.pm} is something like
 129     # '/usr/local/lib/perl5/POSIX.pm', and the autosplit index file is in
 130     # '/usr/local/lib/perl5/auto/POSIX/autosplit.ix', so we require that.
 131     #
 132     # However, if @INC is a relative path, this might not work.  If,
 133     # for example, @INC = ('lib'), then
 134     # $INC{POSIX.pm} is 'lib/POSIX.pm', and we want to require
 135     # 'auto/POSIX/autosplit.ix' (without the leading 'lib').
 136     #
 137
 138     (my $calldir = $callpkg) =~ s#::#/#g;
 139     my $path = $INC{$calldir . '.pm'};
 140     if (defined($path)) {
 141         # Try absolute path name.
 142         if ($is_macos) {
 143             (my $malldir = $calldir) =~ tr#/#:#;
 144             $path =~ s#^(.*)$malldir\.pm\z#$1auto:$malldir:autosplit.ix#s;
 145         } else {
 146             $path =~ s#^(.*)$calldir\.pm\z#$1auto/$calldir/autosplit.ix#;
 147         }
 148
 149         eval { require $path; };
 150         # If that failed, try relative path with normal @INC searching.
 151         if ($@) {
 152             $path ="auto/$calldir/autosplit.ix";
 153             eval { require $path; };
 154         }
 155         if ($@) {
 156             my $error = $@;
 157             require Carp;
 158             Carp::carp($error);
 159         }
 160     }
 161 }
 162
 163 sub unimport {
 164   my $callpkg = caller;
 165   eval "package $callpkg; sub AUTOLOAD;";
 166 }
 167
 168 1;
 169
 170 __END__
 171
 172 =head1 NAME
 173
 174 AutoLoader - load subroutines only on demand
 175
 176 =head1 SYNOPSIS
 177
 178     package Foo;
 179     use AutoLoader 'AUTOLOAD';   # import the default AUTOLOAD subroutine
 180
 181     package Bar;
 182     use AutoLoader;              # don't import AUTOLOAD, define our own
 183     sub AUTOLOAD {
 184         ...
 185         $AutoLoader::AUTOLOAD = "...";
 186         goto &AutoLoader::AUTOLOAD;
 187     }
 188
 189 =head1 DESCRIPTION
 190
 191 The B<AutoLoader> module works with the B<AutoSplit> module and the
 192 C<__END__> token to defer the loading of some subroutines until they are
 193 used rather than loading them all at once.
 194
 195 To use B<AutoLoader>, the author of a module has to place the
 196 definitions of subroutines to be autoloaded after an C<__END__> token.
 197 (See L<perldata>.)  The B<AutoSplit> module can then be run manually to
 198 extract the definitions into individual files F<auto/funcname.al>.
 199
 200 B<AutoLoader> implements an AUTOLOAD subroutine.  When an undefined
 201 subroutine in is called in a client module of B<AutoLoader>,
 202 B<AutoLoader>'s AUTOLOAD subroutine attempts to locate the subroutine in a
 203 file with a name related to the location of the file from which the
 204 client module was read.  As an example, if F<POSIX.pm> is located in
 205 F</usr/local/lib/perl5/POSIX.pm>, B<AutoLoader> will look for perl
 206 subroutines B<POSIX> in F</usr/local/lib/perl5/auto/POSIX/*.al>, where
 207 the C<.al> file has the same name as the subroutine, sans package.  If
 208 such a file exists, AUTOLOAD will read and evaluate it,
 209 thus (presumably) defining the needed subroutine.  AUTOLOAD will then
 210 C<goto> the newly defined subroutine.
 211
 212 Once this process completes for a given function, it is defined, so
 213 future calls to the subroutine will bypass the AUTOLOAD mechanism.
 214
 215 =head2 Subroutine Stubs
 216
 217 In order for object method lookup and/or prototype checking to operate
 218 correctly even when methods have not yet been defined it is necessary to
 219 "forward declare" each subroutine (as in C<sub NAME;>).  See
 220 L<perlsub/"SYNOPSIS">.  Such forward declaration creates "subroutine
 221 stubs", which are place holders with no code.
 222
 223 The AutoSplit and B<AutoLoader> modules automate the creation of forward
 224 declarations.  The AutoSplit module creates an 'index' file containing
 225 forward declarations of all the AutoSplit subroutines.  When the
 226 AutoLoader module is 'use'd it loads these declarations into its callers
 227 package.
 228
 229 Because of this mechanism it is important that B<AutoLoader> is always
 230 C<use>d and not C<require>d.
 231
 232 =head2 Using B<AutoLoader>'s AUTOLOAD Subroutine
 233
 234 In order to use B<AutoLoader>'s AUTOLOAD subroutine you I<must>
 235 explicitly import it:
 236
 237     use AutoLoader 'AUTOLOAD';
 238
 239 =head2 Overriding B<AutoLoader>'s AUTOLOAD Subroutine
 240
 241 Some modules, mainly extensions, provide their own AUTOLOAD subroutines.
 242 They typically need to check for some special cases (such as constants)
 243 and then fallback to B<AutoLoader>'s AUTOLOAD for the rest.
 244
 245 Such modules should I<not> import B<AutoLoader>'s AUTOLOAD subroutine.
 246 Instead, they should define their own AUTOLOAD subroutines along these
 247 lines:
 248
 249     use AutoLoader;
 250     use Carp;
 251
 252     sub AUTOLOAD {
 253         my $sub = $AUTOLOAD;
 254         (my $constname = $sub) =~ s/.*:://;
 255         my $val = constant($constname, @_ ? $_[0] : 0);
 256         if ($! != 0) {
 257             if ($! =~ /Invalid/ || $!{EINVAL}) {
 258                 $AutoLoader::AUTOLOAD = $sub;
 259                 goto &AutoLoader::AUTOLOAD;
 260             }
 261             else {
 262                 croak "Your vendor has not defined constant $constname";
 263             }
 264         }
 265         *$sub = sub { $val }; # same as: eval "sub $sub { $val }";
 266         goto &$sub;
 267     }
 268
 269 If any module's own AUTOLOAD subroutine has no need to fallback to the
 270 AutoLoader's AUTOLOAD subroutine (because it doesn't have any AutoSplit
 271 subroutines), then that module should not use B<AutoLoader> at all.
 272
 273 =head2 Package Lexicals
 274
 275 Package lexicals declared with C<my> in the main block of a package
 276 using B<AutoLoader> will not be visible to auto-loaded subroutines, due to
 277 the fact that the given scope ends at the C<__END__> marker.  A module
 278 using such variables as package globals will not work properly under the
 279 B<AutoLoader>.
 280
 281 The C<vars> pragma (see L<perlmod/"vars">) may be used in such
 282 situations as an alternative to explicitly qualifying all globals with
 283 the package namespace.  Variables pre-declared with this pragma will be
 284 visible to any autoloaded routines (but will not be invisible outside
 285 the package, unfortunately).
 286
 287 =head2 Not Using AutoLoader
 288
 289 You can stop using AutoLoader by simply
 290
 291         no AutoLoader;
 292
 293 =head2 B<AutoLoader> vs. B<SelfLoader>
 294
 295 The B<AutoLoader> is similar in purpose to B<SelfLoader>: both delay the
 296 loading of subroutines.
 297
 298 B<SelfLoader> uses the C<__DATA__> marker rather than C<__END__>.
 299 While this avoids the use of a hierarchy of disk files and the
 300 associated open/close for each routine loaded, B<SelfLoader> suffers a
 301 startup speed disadvantage in the one-time parsing of the lines after
 302 C<__DATA__>, after which routines are cached.  B<SelfLoader> can also
 303 handle multiple packages in a file.
 304
 305 B<AutoLoader> only reads code as it is requested, and in many cases
 306 should be faster, but requires a mechanism like B<AutoSplit> be used to
 307 create the individual files.  L<ExtUtils::MakeMaker> will invoke
 308 B<AutoSplit> automatically if B<AutoLoader> is used in a module source
 309 file.
 310
 311 =head1 CAVEATS
 312
 313 AutoLoaders prior to Perl 5.002 had a slightly different interface.  Any
 314 old modules which use B<AutoLoader> should be changed to the new calling
 315 style.  Typically this just means changing a require to a use, adding
 316 the explicit C<'AUTOLOAD'> import if needed, and removing B<AutoLoader>
 317 from C<@ISA>.
 318
 319 On systems with restrictions on file name length, the file corresponding
 320 to a subroutine may have a shorter name that the routine itself.  This
 321 can lead to conflicting file names.  The I<AutoSplit> package warns of
 322 these potential conflicts when used to split a module.
 323
 324 AutoLoader may fail to find the autosplit files (or even find the wrong
 325 ones) in cases where C<@INC> contains relative paths, B<and> the program
 326 does C<chdir>.
 327
 328 =head1 SEE ALSO
 329
 330 L<SelfLoader> - an autoloader that doesn't use external files.
 331
 332 =cut