lib/perl5/5.6.1/msys/DynaLoader.pm

   1
   2 # Generated from DynaLoader.pm.PL
   3
   4 package DynaLoader;
   5
   6 #   And Gandalf said: 'Many folk like to know beforehand what is to
   7 #   be set on the table; but those who have laboured to prepare the
   8 #   feast like to keep their secret; for wonder makes the words of
   9 #   praise louder.'
  10
  11 #   (Quote from Tolkien suggested by Anno Siegel.)
  12 #
  13 # See pod text at end of file for documentation.
  14 # See also ext/DynaLoader/README in source tree for other information.
  15 #
  16 # Tim.Bunce@ig.co.uk, August 1994
  17
  18 use vars qw($VERSION *AUTOLOAD);
  19
  20 $VERSION = 1.04;        # avoid typo warning
  21
  22 require AutoLoader;
  23 *AUTOLOAD = \&AutoLoader::AUTOLOAD;
  24
  25 use Config;
  26
  27 # The following require can't be removed during maintenance
  28 # releases, sadly, because of the risk of buggy code that does
  29 # require Carp; Carp::croak "..."; without brackets dying
  30 # if Carp hasn't been loaded in earlier compile time. :-(
  31 # We'll let those bugs get found on the development track.
  32 require Carp if $] < 5.00450;
  33
  34 # enable debug/trace messages from DynaLoader perl code
  35 $dl_debug = $ENV{PERL_DL_DEBUG} || 0 unless defined $dl_debug;
  36
  37 #
  38 # Flags to alter dl_load_file behaviour.  Assigned bits:
  39 #   0x01  make symbols available for linking later dl_load_file's.
  40 #         (only known to work on Solaris 2 using dlopen(RTLD_GLOBAL))
  41 #         (ignored under VMS; effect is built-in to image linking)
  42 #
  43 # This is called as a class method $module->dl_load_flags.  The
  44 # definition here will be inherited and result on "default" loading
  45 # behaviour unless a sub-class of DynaLoader defines its own version.
  46 #
  47
  48 sub dl_load_flags { 0x00 }
  49
  50 # ($dl_dlext, $dlsrc)
  51 #         = @Config::Config{'dlext', 'dlsrc'};
  52   ($dl_dlext, $dlsrc) = ('dll','dl_dlopen.xs')
  53 ;
  54 # Some systems need special handling to expand file specifications
  55 # (VMS support by Charles Bailey <bailey@HMIVAX.HUMGEN.UPENN.EDU>)
  56 # See dl_expandspec() for more details. Should be harmless but
  57 # inefficient to define on systems that don't need it.
  58 $Is_VMS    = $^O eq 'VMS';
  59 $do_expand = $Is_VMS;
  60 $Is_MacOS  = $^O eq 'MacOS';
  61
  62 @dl_require_symbols = ();       # names of symbols we need
  63 @dl_resolve_using   = ();       # names of files to link with
  64 @dl_library_path    = ();       # path to look for files
  65 @dl_librefs         = ();       # things we have loaded
  66 @dl_modules         = ();       # Modules we have loaded
  67
  68 # This is a fix to support DLD's unfortunate desire to relink -lc
  69 @dl_resolve_using = dl_findfile('-lc') if $dlsrc eq "dl_dld.xs";
  70
  71 # Initialise @dl_library_path with the 'standard' library path
  72 # for this platform as determined by Configure.
  73
  74 push(@dl_library_path, split(' ', $Config::Config{libpth}));
  75
  76
  77 my $ldlibpthname         = $Config::Config{ldlibpthname};
  78 my $ldlibpthname_defined = defined $Config::Config{ldlibpthname};
  79 my $pthsep               = $Config::Config{path_sep};
  80
  81 # Add to @dl_library_path any extra directories we can gather from environment
  82 # during runtime.
  83
  84 if ($ldlibpthname_defined &&
  85     exists $ENV{$ldlibpthname}) {
  86     push(@dl_library_path, split(/$pthsep/, $ENV{$ldlibpthname}));
  87 }
  88
  89 # E.g. HP-UX supports both its native SHLIB_PATH *and* LD_LIBRARY_PATH.
  90
  91 if ($ldlibpthname_defined &&
  92     $ldlibpthname ne 'LD_LIBRARY_PATH' &&
  93     exists $ENV{LD_LIBRARY_PATH}) {
  94     push(@dl_library_path, split(/$pthsep/, $ENV{LD_LIBRARY_PATH}));
  95 }
  96
  97
  98 # No prizes for guessing why we don't say 'bootstrap DynaLoader;' here.
  99 # NOTE: All dl_*.xs (including dl_none.xs) define a dl_error() XSUB
 100 boot_DynaLoader('DynaLoader') if defined(&boot_DynaLoader) &&
 101                                 !defined(&dl_error);
 102
 103 if ($dl_debug) {
 104     print STDERR "DynaLoader.pm loaded (@INC, @dl_library_path)\n";
 105     print STDERR "DynaLoader not linked into this perl\n"
 106             unless defined(&boot_DynaLoader);
 107 }
 108
 109 1; # End of main code
 110
 111
 112 sub croak   { require Carp; Carp::croak(@_)   }
 113
 114 sub bootstrap_inherit {
 115     my $module = $_[0];
 116     local *isa = *{"$module\::ISA"};
 117     local @isa = (@isa, 'DynaLoader');
 118     # Cannot goto due to delocalization.  Will report errors on a wrong line?
 119     bootstrap(@_);
 120 }
 121
 122 # The bootstrap function cannot be autoloaded (without complications)
 123 # so we define it here:
 124
 125 sub bootstrap {
 126     # use local vars to enable $module.bs script to edit values
 127     local(@args) = @_;
 128     local($module) = $args[0];
 129     local(@dirs, $file);
 130
 131     unless ($module) {
 132         require Carp;
 133         Carp::confess("Usage: DynaLoader::bootstrap(module)");
 134     }
 135
 136     # A common error on platforms which don't support dynamic loading.
 137     # Since it's fatal and potentially confusing we give a detailed message.
 138     croak("Can't load module $module, dynamic loading not available in this perl.\n".
 139         "  (You may need to build a new perl executable which either supports\n".
 140         "  dynamic loading or has the $module module statically linked into it.)\n")
 141         unless defined(&dl_load_file);
 142
 143     my @modparts = split(/::/,$module);
 144     my $modfname = $modparts[-1];
 145
 146     # Some systems have restrictions on files names for DLL's etc.
 147     # mod2fname returns appropriate file base name (typically truncated)
 148     # It may also edit @modparts if required.
 149     $modfname = &mod2fname(\@modparts) if defined &mod2fname;
 150
 151     my $modpname = join(($Is_MacOS ? ':' : '/'),@modparts);
 152
 153     print STDERR "DynaLoader::bootstrap for $module ",
 154                 ($Is_MacOS
 155                        ? "(:auto:$modpname:$modfname.$dl_dlext)\n" :
 156                        "(auto/$modpname/$modfname.$dl_dlext)\n")
 157         if $dl_debug;
 158
 159     foreach (@INC) {
 160         chop($_ = VMS::Filespec::unixpath($_)) if $Is_VMS;
 161         my $dir;
 162         if ($Is_MacOS) {
 163             chop $_  if /:$/;
 164             $dir = "$_:auto:$modpname";
 165         } else {
 166             $dir = "$_/auto/$modpname";
 167         }
 168         next unless -d $dir; # skip over uninteresting directories
 169
 170         # check for common cases to avoid autoload of dl_findfile
 171         my $try = $Is_MacOS ? "$dir:$modfname.$dl_dlext" : "$dir/$modfname.$dl_dlext";
 172         last if $file = ($do_expand) ? dl_expandspec($try) : (-f $try && $try);
 173
 174         # no luck here, save dir for possible later dl_findfile search
 175         push @dirs, $dir;
 176     }
 177     # last resort, let dl_findfile have a go in all known locations
 178     $file = dl_findfile(map("-L$_",@dirs,@INC), $modfname) unless $file;
 179
 180     croak("Can't locate loadable object for module $module in \@INC (\@INC contains: @INC)")
 181         unless $file;   # wording similar to error from 'require'
 182
 183     $file = uc($file) if $Is_VMS && $Config::Config{d_vms_case_sensitive_symbols};
 184     my $bootname = "boot_$module";
 185     $bootname =~ s/\W/_/g;
 186     @dl_require_symbols = ($bootname);
 187
 188     # Execute optional '.bootstrap' perl script for this module.
 189     # The .bs file can be used to configure @dl_resolve_using etc to
 190     # match the needs of the individual module on this architecture.
 191     my $bs = $file;
 192     $bs =~ s/(\.\w+)?(;\d*)?$/\.bs/; # look for .bs 'beside' the library
 193     if (-s $bs) { # only read file if it's not empty
 194         print STDERR "BS: $bs ($^O, $dlsrc)\n" if $dl_debug;
 195         eval { do $bs; };
 196         warn "$bs: $@\n" if $@;
 197     }
 198
 199     # Many dynamic extension loading problems will appear to come from
 200     # this section of code: XYZ failed at line 123 of DynaLoader.pm.
 201     # Often these errors are actually occurring in the initialisation
 202     # C code of the extension XS file. Perl reports the error as being
 203     # in this perl code simply because this was the last perl code
 204     # it executed.
 205
 206     my $libref = dl_load_file($file, $module->dl_load_flags) or
 207         croak("Can't load '$file' for module $module: ".dl_error());
 208
 209     push(@dl_librefs,$libref);  # record loaded object
 210
 211     my @unresolved = dl_undef_symbols();
 212     if (@unresolved) {
 213         require Carp;
 214         Carp::carp("Undefined symbols present after loading $file: @unresolved\n");
 215     }
 216
 217     my $boot_symbol_ref = dl_find_symbol($libref, $bootname) or
 218          croak("Can't find '$bootname' symbol in $file\n");
 219
 220     my $xs = dl_install_xsub("${module}::bootstrap", $boot_symbol_ref, $file);
 221
 222     push(@dl_modules, $module); # record loaded module
 223
 224     # See comment block above
 225     &$xs(@args);
 226 }
 227
 228
 229 #sub _check_file {   # private utility to handle dl_expandspec vs -f tests
 230 #    my($file) = @_;
 231 #    return $file if (!$do_expand && -f $file); # the common case
 232 #    return $file if ( $do_expand && ($file=dl_expandspec($file)));
 233 #    return undef;
 234 #}
 235
 236
 237 # Let autosplit and the autoloader deal with these functions:
 238 __END__
 239
 240
 241 sub dl_findfile {
 242     # Read ext/DynaLoader/DynaLoader.doc for detailed information.
 243     # This function does not automatically consider the architecture
 244     # or the perl library auto directories.
 245     my (@args) = @_;
 246     my (@dirs,  $dir);   # which directories to search
 247     my (@found);         # full paths to real files we have found
 248     my $dl_ext= 'dll'; # $Config::Config{'dlext'} suffix for perl extensions
 249     my $dl_so = 'dll'; # $Config::Config{'so'} suffix for shared libraries
 250
 251     print STDERR "dl_findfile(@args)\n" if $dl_debug;
 252
 253     # accumulate directories but process files as they appear
 254     arg: foreach(@args) {
 255         #  Special fast case: full filepath requires no search
 256         if ($Is_VMS && m%[:>/\]]% && -f $_) {
 257             push(@found,dl_expandspec(VMS::Filespec::vmsify($_)));
 258             last arg unless wantarray;
 259             next;
 260         }
 261         elsif ($Is_MacOS) {
 262             if (m/:/ && -f $_) {
 263                 push(@found,$_);
 264                 last arg unless wantarray;
 265             }
 266         }
 267         elsif (m:/: && -f $_ && !$do_expand) {
 268             push(@found,$_);
 269             last arg unless wantarray;
 270             next;
 271         }
 272
 273         # Deal with directories first:
 274         #  Using a -L prefix is the preferred option (faster and more robust)
 275         if (m:^-L:) { s/^-L//; push(@dirs, $_); next; }
 276
 277         if ($Is_MacOS) {
 278             #  Otherwise we try to try to spot directories by a heuristic
 279             #  (this is a more complicated issue than it first appears)
 280             if (m/:/ && -d $_) {   push(@dirs, $_); next; }
 281             #  Only files should get this far...
 282             my(@names, $name);    # what filenames to look for
 283             s/^-l//;
 284             push(@names, $_);
 285             foreach $dir (@dirs, @dl_library_path) {
 286                 next unless -d $dir;
 287                 $dir =~ s/^([^:]+)$/:$1/;
 288                 $dir =~ s/:$//;
 289                 foreach $name (@names) {
 290                     my($file) = "$dir:$name";
 291                     print STDERR " checking in $dir for $name\n" if $dl_debug;
 292                     if (-f $file) {
 293                         push(@found, $file);
 294                         next arg; # no need to look any further
 295                     }
 296                 }
 297             }
 298             next;
 299         }
 300
 301         #  Otherwise we try to try to spot directories by a heuristic
 302         #  (this is a more complicated issue than it first appears)
 303         if (m:/: && -d $_) {   push(@dirs, $_); next; }
 304
 305         # VMS: we may be using native VMS directory syntax instead of
 306         # Unix emulation, so check this as well
 307         if ($Is_VMS && /[:>\]]/ && -d $_) {   push(@dirs, $_); next; }
 308
 309         #  Only files should get this far...
 310         my(@names, $name);    # what filenames to look for
 311         if (m:-l: ) {          # convert -lname to appropriate library name
 312             s/-l//;
 313             push(@names,"lib$_.$dl_so");
 314             push(@names,"lib$_.a");
 315         } else {                # Umm, a bare name. Try various alternatives:
 316             # these should be ordered with the most likely first
 317             push(@names,"$_.$dl_ext")    unless m/\.$dl_ext$/o;
 318             push(@names,"$_.$dl_so")     unless m/\.$dl_so$/o;
 319             push(@names,"lib$_.$dl_so")  unless m:/:;
 320             push(@names,"$_.a")          if !m/\.a$/ and $dlsrc eq "dl_dld.xs";
 321             push(@names, $_);
 322         }
 323         foreach $dir (@dirs, @dl_library_path) {
 324             next unless -d $dir;
 325             chop($dir = VMS::Filespec::unixpath($dir)) if $Is_VMS;
 326             foreach $name (@names) {
 327                 my($file) = "$dir/$name";
 328                 print STDERR " checking in $dir for $name\n" if $dl_debug;
 329                 $file = ($do_expand) ? dl_expandspec($file) : (-f $file && $file);
 330                 #$file = _check_file($file);
 331                 if ($file) {
 332                     push(@found, $file);
 333                     next arg; # no need to look any further
 334                 }
 335             }
 336         }
 337     }
 338     if ($dl_debug) {
 339         foreach(@dirs) {
 340             print STDERR " dl_findfile ignored non-existent directory: $_\n" unless -d $_;
 341         }
 342         print STDERR "dl_findfile found: @found\n";
 343     }
 344     return $found[0] unless wantarray;
 345     @found;
 346 }
 347
 348
 349 sub dl_expandspec {
 350     my($spec) = @_;
 351     # Optional function invoked if DynaLoader.pm sets $do_expand.
 352     # Most systems do not require or use this function.
 353     # Some systems may implement it in the dl_*.xs file in which case
 354     # this autoload version will not be called but is harmless.
 355
 356     # This function is designed to deal with systems which treat some
 357     # 'filenames' in a special way. For example VMS 'Logical Names'
 358     # (something like unix environment variables - but different).
 359     # This function should recognise such names and expand them into
 360     # full file paths.
 361     # Must return undef if $spec is invalid or file does not exist.
 362
 363     my $file = $spec; # default output to input
 364
 365     if ($Is_VMS) { # dl_expandspec should be defined in dl_vms.xs
 366         require Carp;
 367         Carp::croak("dl_expandspec: should be defined in XS file!\n");
 368     } else {
 369         return undef unless -f $file;
 370     }
 371     print STDERR "dl_expandspec($spec) => $file\n" if $dl_debug;
 372     $file;
 373 }
 374
 375 sub dl_find_symbol_anywhere
 376 {
 377     my $sym = shift;
 378     my $libref;
 379     foreach $libref (@dl_librefs) {
 380         my $symref = dl_find_symbol($libref,$sym);
 381         return $symref if $symref;
 382     }
 383     return undef;
 384 }
 385
 386 =head1 NAME
 387
 388 DynaLoader - Dynamically load C libraries into Perl code
 389
 390 dl_error(), dl_findfile(), dl_expandspec(), dl_load_file(), dl_unload_file(), dl_find_symbol(), dl_find_symbol_anywhere(), dl_undef_symbols(), dl_install_xsub(), dl_load_flags(), bootstrap() - routines used by DynaLoader modules
 391
 392 =head1 SYNOPSIS
 393
 394     package YourPackage;
 395     require DynaLoader;
 396     @ISA = qw(... DynaLoader ...);
 397     bootstrap YourPackage;
 398
 399     # optional method for 'global' loading
 400     sub dl_load_flags { 0x01 }
 401
 402
 403 =head1 DESCRIPTION
 404
 405 This document defines a standard generic interface to the dynamic
 406 linking mechanisms available on many platforms.  Its primary purpose is
 407 to implement automatic dynamic loading of Perl modules.
 408
 409 This document serves as both a specification for anyone wishing to
 410 implement the DynaLoader for a new platform and as a guide for
 411 anyone wishing to use the DynaLoader directly in an application.
 412
 413 The DynaLoader is designed to be a very simple high-level
 414 interface that is sufficiently general to cover the requirements
 415 of SunOS, HP-UX, NeXT, Linux, VMS and other platforms.
 416
 417 It is also hoped that the interface will cover the needs of OS/2, NT
 418 etc and also allow pseudo-dynamic linking (using C<ld -A> at runtime).
 419
 420 It must be stressed that the DynaLoader, by itself, is practically
 421 useless for accessing non-Perl libraries because it provides almost no
 422 Perl-to-C 'glue'.  There is, for example, no mechanism for calling a C
 423 library function or supplying arguments.  A C::DynaLib module
 424 is available from CPAN sites which performs that function for some
 425 common system types.
 426
 427 DynaLoader Interface Summary
 428
 429   @dl_library_path
 430   @dl_resolve_using
 431   @dl_require_symbols
 432   $dl_debug
 433   @dl_librefs
 434   @dl_modules
 435                                                   Implemented in:
 436   bootstrap($modulename)                               Perl
 437   @filepaths = dl_findfile(@names)                     Perl
 438   $flags = $modulename->dl_load_flags                  Perl
 439   $symref  = dl_find_symbol_anywhere($symbol)          Perl
 440
 441   $libref  = dl_load_file($filename, $flags)           C
 442   $status  = dl_unload_file($libref)                   C
 443   $symref  = dl_find_symbol($libref, $symbol)          C
 444   @symbols = dl_undef_symbols()                        C
 445   dl_install_xsub($name, $symref [, $filename])        C
 446   $message = dl_error                                  C
 447
 448 =over 4
 449
 450 =item @dl_library_path
 451
 452 The standard/default list of directories in which dl_findfile() will
 453 search for libraries etc.  Directories are searched in order:
 454 $dl_library_path[0], [1], ... etc
 455
 456 @dl_library_path is initialised to hold the list of 'normal' directories
 457 (F</usr/lib>, etc) determined by B<Configure> (C<$Config{'libpth'}>).  This should
 458 ensure portability across a wide range of platforms.
 459
 460 @dl_library_path should also be initialised with any other directories
 461 that can be determined from the environment at runtime (such as
 462 LD_LIBRARY_PATH for SunOS).
 463
 464 After initialisation @dl_library_path can be manipulated by an
 465 application using push and unshift before calling dl_findfile().
 466 Unshift can be used to add directories to the front of the search order
 467 either to save search time or to override libraries with the same name
 468 in the 'normal' directories.
 469
 470 The load function that dl_load_file() calls may require an absolute
 471 pathname.  The dl_findfile() function and @dl_library_path can be
 472 used to search for and return the absolute pathname for the
 473 library/object that you wish to load.
 474
 475 =item @dl_resolve_using
 476
 477 A list of additional libraries or other shared objects which can be
 478 used to resolve any undefined symbols that might be generated by a
 479 later call to load_file().
 480
 481 This is only required on some platforms which do not handle dependent
 482 libraries automatically.  For example the Socket Perl extension
 483 library (F<auto/Socket/Socket.so>) contains references to many socket
 484 functions which need to be resolved when it's loaded.  Most platforms
 485 will automatically know where to find the 'dependent' library (e.g.,
 486 F</usr/lib/libsocket.so>).  A few platforms need to be told the
 487 location of the dependent library explicitly.  Use @dl_resolve_using
 488 for this.
 489
 490 Example usage:
 491
 492     @dl_resolve_using = dl_findfile('-lsocket');
 493
 494 =item @dl_require_symbols
 495
 496 A list of one or more symbol names that are in the library/object file
 497 to be dynamically loaded.  This is only required on some platforms.
 498
 499 =item @dl_librefs
 500
 501 An array of the handles returned by successful calls to dl_load_file(),
 502 made by bootstrap, in the order in which they were loaded.
 503 Can be used with dl_find_symbol() to look for a symbol in any of
 504 the loaded files.
 505
 506 =item @dl_modules
 507
 508 An array of module (package) names that have been bootstrap'ed.
 509
 510 =item dl_error()
 511
 512 Syntax:
 513
 514     $message = dl_error();
 515
 516 Error message text from the last failed DynaLoader function.  Note
 517 that, similar to errno in unix, a successful function call does not
 518 reset this message.
 519
 520 Implementations should detect the error as soon as it occurs in any of
 521 the other functions and save the corresponding message for later
 522 retrieval.  This will avoid problems on some platforms (such as SunOS)
 523 where the error message is very temporary (e.g., dlerror()).
 524
 525 =item $dl_debug
 526
 527 Internal debugging messages are enabled when $dl_debug is set true.
 528 Currently setting $dl_debug only affects the Perl side of the
 529 DynaLoader.  These messages should help an application developer to
 530 resolve any DynaLoader usage problems.
 531
 532 $dl_debug is set to C<$ENV{'PERL_DL_DEBUG'}> if defined.
 533
 534 For the DynaLoader developer/porter there is a similar debugging
 535 variable added to the C code (see dlutils.c) and enabled if Perl was
 536 built with the B<-DDEBUGGING> flag.  This can also be set via the
 537 PERL_DL_DEBUG environment variable.  Set to 1 for minimal information or
 538 higher for more.
 539
 540 =item dl_findfile()
 541
 542 Syntax:
 543
 544     @filepaths = dl_findfile(@names)
 545
 546 Determine the full paths (including file suffix) of one or more
 547 loadable files given their generic names and optionally one or more
 548 directories.  Searches directories in @dl_library_path by default and
 549 returns an empty list if no files were found.
 550
 551 Names can be specified in a variety of platform independent forms.  Any
 552 names in the form B<-lname> are converted into F<libname.*>, where F<.*> is
 553 an appropriate suffix for the platform.
 554
 555 If a name does not already have a suitable prefix and/or suffix then
 556 the corresponding file will be searched for by trying combinations of
 557 prefix and suffix appropriate to the platform: "$name.o", "lib$name.*"
 558 and "$name".
 559
 560 If any directories are included in @names they are searched before
 561 @dl_library_path.  Directories may be specified as B<-Ldir>.  Any other
 562 names are treated as filenames to be searched for.
 563
 564 Using arguments of the form C<-Ldir> and C<-lname> is recommended.
 565
 566 Example:
 567
 568     @dl_resolve_using = dl_findfile(qw(-L/usr/5lib -lposix));
 569
 570
 571 =item dl_expandspec()
 572
 573 Syntax:
 574
 575     $filepath = dl_expandspec($spec)
 576
 577 Some unusual systems, such as VMS, require special filename handling in
 578 order to deal with symbolic names for files (i.e., VMS's Logical Names).
 579
 580 To support these systems a dl_expandspec() function can be implemented
 581 either in the F<dl_*.xs> file or code can be added to the autoloadable
 582 dl_expandspec() function in F<DynaLoader.pm>.  See F<DynaLoader.pm> for
 583 more information.
 584
 585 =item dl_load_file()
 586
 587 Syntax:
 588
 589     $libref = dl_load_file($filename, $flags)
 590
 591 Dynamically load $filename, which must be the path to a shared object
 592 or library.  An opaque 'library reference' is returned as a handle for
 593 the loaded object.  Returns undef on error.
 594
 595 The $flags argument to alters dl_load_file behaviour.
 596 Assigned bits:
 597
 598  0x01  make symbols available for linking later dl_load_file's.
 599        (only known to work on Solaris 2 using dlopen(RTLD_GLOBAL))
 600        (ignored under VMS; this is a normal part of image linking)
 601
 602 (On systems that provide a handle for the loaded object such as SunOS
 603 and HPUX, $libref will be that handle.  On other systems $libref will
 604 typically be $filename or a pointer to a buffer containing $filename.
 605 The application should not examine or alter $libref in any way.)
 606
 607 This is the function that does the real work.  It should use the
 608 current values of @dl_require_symbols and @dl_resolve_using if required.
 609
 610     SunOS: dlopen($filename)
 611     HP-UX: shl_load($filename)
 612     Linux: dld_create_reference(@dl_require_symbols); dld_link($filename)
 613     NeXT:  rld_load($filename, @dl_resolve_using)
 614     VMS:   lib$find_image_symbol($filename,$dl_require_symbols[0])
 615
 616 (The dlopen() function is also used by Solaris and some versions of
 617 Linux, and is a common choice when providing a "wrapper" on other
 618 mechanisms as is done in the OS/2 port.)
 619
 620 =item dl_unload_file()
 621
 622 Syntax:
 623
 624     $status = dl_unload_file($libref)
 625
 626 Dynamically unload $libref, which must be an opaque 'library reference' as
 627 returned from dl_load_file.  Returns one on success and zero on failure.
 628
 629 This function is optional and may not necessarily be provided on all platforms.
 630 If it is defined, it is called automatically when the interpreter exits for
 631 every shared object or library loaded by DynaLoader::bootstrap.  All such
 632 library references are stored in @dl_librefs by DynaLoader::Bootstrap as it
 633 loads the libraries.  The files are unloaded in last-in, first-out order.
 634
 635 This unloading is usually necessary when embedding a shared-object perl (e.g.
 636 one configured with -Duseshrplib) within a larger application, and the perl
 637 interpreter is created and destroyed several times within the lifetime of the
 638 application.  In this case it is possible that the system dynamic linker will
 639 unload and then subsequently reload the shared libperl without relocating any
 640 references to it from any files DynaLoaded by the previous incarnation of the
 641 interpreter.  As a result, any shared objects opened by DynaLoader may point to
 642 a now invalid 'ghost' of the libperl shared object, causing apparently random
 643 memory corruption and crashes.  This behaviour is most commonly seen when using
 644 Apache and mod_perl built with the APXS mechanism.
 645
 646     SunOS: dlclose($libref)
 647     HP-UX: ???
 648     Linux: ???
 649     NeXT:  ???
 650     VMS:   ???
 651
 652 (The dlclose() function is also used by Solaris and some versions of
 653 Linux, and is a common choice when providing a "wrapper" on other
 654 mechanisms as is done in the OS/2 port.)
 655
 656 =item dl_loadflags()
 657
 658 Syntax:
 659
 660     $flags = dl_loadflags $modulename;
 661
 662 Designed to be a method call, and to be overridden by a derived class
 663 (i.e. a class which has DynaLoader in its @ISA).  The definition in
 664 DynaLoader itself returns 0, which produces standard behavior from
 665 dl_load_file().
 666
 667 =item dl_find_symbol()
 668
 669 Syntax:
 670
 671     $symref = dl_find_symbol($libref, $symbol)
 672
 673 Return the address of the symbol $symbol or C<undef> if not found.  If the
 674 target system has separate functions to search for symbols of different
 675 types then dl_find_symbol() should search for function symbols first and
 676 then other types.
 677
 678 The exact manner in which the address is returned in $symref is not
 679 currently defined.  The only initial requirement is that $symref can
 680 be passed to, and understood by, dl_install_xsub().
 681
 682     SunOS: dlsym($libref, $symbol)
 683     HP-UX: shl_findsym($libref, $symbol)
 684     Linux: dld_get_func($symbol) and/or dld_get_symbol($symbol)
 685     NeXT:  rld_lookup("_$symbol")
 686     VMS:   lib$find_image_symbol($libref,$symbol)
 687
 688
 689 =item dl_find_symbol_anywhere()
 690
 691 Syntax:
 692
 693     $symref = dl_find_symbol_anywhere($symbol)
 694
 695 Applies dl_find_symbol() to the members of @dl_librefs and returns
 696 the first match found.
 697
 698 =item dl_undef_symbols()
 699
 700 Example
 701
 702     @symbols = dl_undef_symbols()
 703
 704 Return a list of symbol names which remain undefined after load_file().
 705 Returns C<()> if not known.  Don't worry if your platform does not provide
 706 a mechanism for this.  Most do not need it and hence do not provide it,
 707 they just return an empty list.
 708
 709
 710 =item dl_install_xsub()
 711
 712 Syntax:
 713
 714     dl_install_xsub($perl_name, $symref [, $filename])
 715
 716 Create a new Perl external subroutine named $perl_name using $symref as
 717 a pointer to the function which implements the routine.  This is simply
 718 a direct call to newXSUB().  Returns a reference to the installed
 719 function.
 720
 721 The $filename parameter is used by Perl to identify the source file for
 722 the function if required by die(), caller() or the debugger.  If
 723 $filename is not defined then "DynaLoader" will be used.
 724
 725
 726 =item bootstrap()
 727
 728 Syntax:
 729
 730 bootstrap($module)
 731
 732 This is the normal entry point for automatic dynamic loading in Perl.
 733
 734 It performs the following actions:
 735
 736 =over 8
 737
 738 =item *
 739
 740 locates an auto/$module directory by searching @INC
 741
 742 =item *
 743
 744 uses dl_findfile() to determine the filename to load
 745
 746 =item *
 747
 748 sets @dl_require_symbols to C<("boot_$module")>
 749
 750 =item *
 751
 752 executes an F<auto/$module/$module.bs> file if it exists
 753 (typically used to add to @dl_resolve_using any files which
 754 are required to load the module on the current platform)
 755
 756 =item *
 757
 758 calls dl_load_flags() to determine how to load the file.
 759
 760 =item *
 761
 762 calls dl_load_file() to load the file
 763
 764 =item *
 765
 766 calls dl_undef_symbols() and warns if any symbols are undefined
 767
 768 =item *
 769
 770 calls dl_find_symbol() for "boot_$module"
 771
 772 =item *
 773
 774 calls dl_install_xsub() to install it as "${module}::bootstrap"
 775
 776 =item *
 777
 778 calls &{"${module}::bootstrap"} to bootstrap the module (actually
 779 it uses the function reference returned by dl_install_xsub for speed)
 780
 781 =back
 782
 783 =back
 784
 785
 786 =head1 AUTHOR
 787
 788 Tim Bunce, 11 August 1994.
 789
 790 This interface is based on the work and comments of (in no particular
 791 order): Larry Wall, Robert Sanders, Dean Roehrich, Jeff Okamoto, Anno
 792 Siegel, Thomas Neumann, Paul Marquess, Charles Bailey, myself and others.
 793
 794 Larry Wall designed the elegant inherited bootstrap mechanism and
 795 implemented the first Perl 5 dynamic loader using it.
 796
 797 Solaris global loading added by Nick Ing-Simmons with design/coding
 798 assistance from Tim Bunce, January 1996.
 799
 800 =cut