ld/ldlex.l

   1 %{
   2
   3 /* Copyright 1991, 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999,
   4    2000, 2001, 2002, 2003, 2004, 2005, 2007
   5    Free Software Foundation, Inc.
   6    Written by Steve Chamberlain of Cygnus Support.
   7
   8    This file is part of the GNU Binutils.
   9
  10    This program is free software; you can redistribute it and/or modify
  11    it under the terms of the GNU General Public License as published by
  12    the Free Software Foundation; either version 3 of the License, or
  13    (at your option) any later version.
  14
  15    This program is distributed in the hope that it will be useful,
  16    but WITHOUT ANY WARRANTY; without even the implied warranty of
  17    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18    GNU General Public License for more details.
  19
  20    You should have received a copy of the GNU General Public License
  21    along with this program; if not, write to the Free Software
  22    Foundation, Inc., 51 Franklin Street - Fifth Floor, Boston,
  23    MA 02110-1301, USA.  */
  24
  25 #include "sysdep.h"
  26 #include "bfd.h"
  27 #include "safe-ctype.h"
  28 #include "bfdlink.h"
  29 #include "ld.h"
  30 #include "ldmisc.h"
  31 #include "ldexp.h"
  32 #include "ldlang.h"
  33 #include <ldgram.h>
  34 #include "ldfile.h"
  35 #include "ldlex.h"
  36 #include "ldmain.h"
  37 #include "libiberty.h"
  38
  39 /* The type of top-level parser input.
  40    yylex and yyparse (indirectly) both check this.  */
  41 input_type parser_input;
  42
  43 /* Line number in the current input file.
  44    (FIXME Actually, it doesn't appear to get reset for each file?)  */
  45 unsigned int lineno = 1;
  46
  47 /* The string we are currently lexing, or NULL if we are reading a
  48    file.  */
  49 const char *lex_string = NULL;
  50
  51 /* Support for flex reading from more than one input file (stream).
  52    `include_stack' is flex's input state for each open file;
  53    `file_name_stack' is the file names.  `lineno_stack' is the current
  54    line numbers.
  55
  56    If `include_stack_ptr' is 0, we haven't started reading anything yet.
  57    Otherwise, stack elements 0 through `include_stack_ptr - 1' are valid.  */
  58
  59 #undef YY_INPUT
  60 #define YY_INPUT(buf,result,max_size) yy_input (buf, &result, max_size)
  61
  62 #define YY_NO_UNPUT
  63
  64 #define MAX_INCLUDE_DEPTH 10
  65 static YY_BUFFER_STATE include_stack[MAX_INCLUDE_DEPTH];
  66 static const char *file_name_stack[MAX_INCLUDE_DEPTH];
  67 static unsigned int lineno_stack[MAX_INCLUDE_DEPTH];
  68 static unsigned int include_stack_ptr = 0;
  69 static int vers_node_nesting = 0;
  70
  71 static void yy_input (char *, int *, int);
  72 static void comment (void);
  73 static void lex_warn_invalid (char *where, char *what);
  74
  75 /* STATES
  76         EXPRESSION      definitely in an expression
  77         SCRIPT          definitely in a script
  78         BOTH            either EXPRESSION or SCRIPT
  79         DEFSYMEXP       in an argument to -defsym
  80         MRI             in an MRI script
  81         VERS_START      starting a Sun style mapfile
  82         VERS_SCRIPT     a Sun style mapfile
  83         VERS_NODE       a node within a Sun style mapfile
  84 */
  85 #define RTOKEN(x)  {  yylval.token = x; return x; }
  86
  87 /* Some versions of flex want this.  */
  88 #ifndef yywrap
  89 int yywrap (void) { return 1; }
  90 #endif
  91 %}
  92
  93 %a 4000
  94 %o 5000
  95
  96 CMDFILENAMECHAR   [_a-zA-Z0-9\/\.\\_\+\$\:\[\]\\\,\=\&\!\<\>\-\~]
  97 CMDFILENAMECHAR1  [_a-zA-Z0-9\/\.\\_\+\$\:\[\]\\\,\=\&\!\<\>\~]
  98 FILENAMECHAR1   [_a-zA-Z\/\.\\\$\_\~]
  99 SYMBOLCHARN     [_a-zA-Z\/\.\\\$\_\~0-9]
 100 FILENAMECHAR    [_a-zA-Z0-9\/\.\-\_\+\=\$\:\[\]\\\,\~]
 101 WILDCHAR        [_a-zA-Z0-9\/\.\-\_\+\=\$\:\[\]\\\,\~\?\*]
 102 WHITE           [ \t\n\r]+
 103
 104 NOCFILENAMECHAR [_a-zA-Z0-9\/\.\-\_\+\$\:\[\]\\\~]
 105
 106 V_TAG [.$_a-zA-Z][._a-zA-Z0-9]*
 107 V_IDENTIFIER [*?.$_a-zA-Z\[\]\-\!\^\\]([*?.$_a-zA-Z0-9\[\]\-\!\^\\]|::)*
 108
 109 %s SCRIPT
 110 %s EXPRESSION
 111 %s BOTH
 112 %s DEFSYMEXP
 113 %s MRI
 114 %s VERS_START
 115 %s VERS_SCRIPT
 116 %s VERS_NODE
 117 %%
 118
 119   if (parser_input != input_selected)
 120     {
 121       /* The first token of the input determines the initial parser state.  */
 122       input_type t = parser_input;
 123       parser_input = input_selected;
 124       switch (t)
 125         {
 126         case input_script: return INPUT_SCRIPT; break;
 127         case input_mri_script: return INPUT_MRI_SCRIPT; break;
 128         case input_version_script: return INPUT_VERSION_SCRIPT; break;
 129         case input_dynamic_list: return INPUT_DYNAMIC_LIST; break;
 130         case input_defsym: return INPUT_DEFSYM; break;
 131         default: abort ();
 132         }
 133     }
 134
 135 <BOTH,SCRIPT,EXPRESSION,VERS_START,VERS_NODE,VERS_SCRIPT>"/*"   { comment (); }
 136
 137
 138 <DEFSYMEXP>"-"                  { RTOKEN('-');}
 139 <DEFSYMEXP>"+"                  { RTOKEN('+');}
 140 <DEFSYMEXP>{FILENAMECHAR1}{SYMBOLCHARN}*   { yylval.name = xstrdup (yytext); return NAME; }
 141 <DEFSYMEXP>"="                  { RTOKEN('='); }
 142
 143 <MRI,EXPRESSION>"$"([0-9A-Fa-f])+ {
 144                                 yylval.integer = bfd_scan_vma (yytext + 1, 0, 16);
 145                                 yylval.bigint.str = NULL;
 146                                 return INT;
 147                         }
 148
 149 <MRI,EXPRESSION>([0-9A-Fa-f])+(H|h|X|x|B|b|O|o|D|d) {
 150                                    int ibase ;
 151                                    switch (yytext[yyleng - 1]) {
 152                                     case 'X':
 153                                     case 'x':
 154                                     case 'H':
 155                                     case 'h':
 156                                      ibase = 16;
 157                                      break;
 158                                     case 'O':
 159                                     case 'o':
 160                                      ibase = 8;
 161                                      break;
 162                                     case 'B':
 163                                     case 'b':
 164                                      ibase = 2;
 165                                      break;
 166                                     default:
 167                                      ibase = 10;
 168                                    }
 169                                    yylval.integer = bfd_scan_vma (yytext, 0,
 170                                                                   ibase);
 171                                    yylval.bigint.str = NULL;
 172                                    return INT;
 173                                  }
 174 <SCRIPT,DEFSYMEXP,MRI,BOTH,EXPRESSION>((("$"|0[xX])([0-9A-Fa-f])+)|(([0-9])+))(M|K|m|k)? {
 175                                   char *s = yytext;
 176                                   int ibase = 0;
 177
 178                                   if (*s == '$')
 179                                     {
 180                                       ++s;
 181                                       ibase = 16;
 182                                     }
 183                                   yylval.integer = bfd_scan_vma (s, 0, ibase);
 184                                   yylval.bigint.str = NULL;
 185                                   if (yytext[yyleng - 1] == 'M'
 186                                       || yytext[yyleng - 1] == 'm')
 187                                     {
 188                                       yylval.integer *= 1024 * 1024;
 189                                     }
 190                                   else if (yytext[yyleng - 1] == 'K'
 191                                       || yytext[yyleng - 1]=='k')
 192                                     {
 193                                       yylval.integer *= 1024;
 194                                     }
 195                                   else if (yytext[0] == '0'
 196                                            && (yytext[1] == 'x'
 197                                                || yytext[1] == 'X'))
 198                                     {
 199                                       yylval.bigint.str = xstrdup (yytext + 2);
 200                                     }
 201                                   return INT;
 202                                 }
 203 <BOTH,SCRIPT,EXPRESSION,MRI>"]"         { RTOKEN(']');}
 204 <BOTH,SCRIPT,EXPRESSION,MRI>"["         { RTOKEN('[');}
 205 <BOTH,SCRIPT,EXPRESSION,MRI>"<<="       { RTOKEN(LSHIFTEQ);}
 206 <BOTH,SCRIPT,EXPRESSION,MRI>">>="       { RTOKEN(RSHIFTEQ);}
 207 <BOTH,SCRIPT,EXPRESSION,MRI>"||"        { RTOKEN(OROR);}
 208 <BOTH,SCRIPT,EXPRESSION,MRI>"=="        { RTOKEN(EQ);}
 209 <BOTH,SCRIPT,EXPRESSION,MRI>"!="        { RTOKEN(NE);}
 210 <BOTH,SCRIPT,EXPRESSION,MRI>">="        { RTOKEN(GE);}
 211 <BOTH,SCRIPT,EXPRESSION,MRI>"<="        { RTOKEN(LE);}
 212 <BOTH,SCRIPT,EXPRESSION,MRI>"<<"        { RTOKEN(LSHIFT);}
 213 <BOTH,SCRIPT,EXPRESSION,MRI>">>"        { RTOKEN(RSHIFT);}
 214 <BOTH,SCRIPT,EXPRESSION,MRI>"+="        { RTOKEN(PLUSEQ);}
 215 <BOTH,SCRIPT,EXPRESSION,MRI>"-="        { RTOKEN(MINUSEQ);}
 216 <BOTH,SCRIPT,EXPRESSION,MRI>"*="        { RTOKEN(MULTEQ);}
 217 <BOTH,SCRIPT,EXPRESSION,MRI>"/="        { RTOKEN(DIVEQ);}
 218 <BOTH,SCRIPT,EXPRESSION,MRI>"&="        { RTOKEN(ANDEQ);}
 219 <BOTH,SCRIPT,EXPRESSION,MRI>"|="        { RTOKEN(OREQ);}
 220 <BOTH,SCRIPT,EXPRESSION,MRI>"&&"        { RTOKEN(ANDAND);}
 221 <BOTH,SCRIPT,EXPRESSION,MRI>">"         { RTOKEN('>');}
 222 <BOTH,SCRIPT,EXPRESSION,MRI>","         { RTOKEN(',');}
 223 <BOTH,SCRIPT,EXPRESSION,MRI>"&"         { RTOKEN('&');}
 224 <BOTH,SCRIPT,EXPRESSION,MRI>"|"         { RTOKEN('|');}
 225 <BOTH,SCRIPT,EXPRESSION,MRI>"~"         { RTOKEN('~');}
 226 <BOTH,SCRIPT,EXPRESSION,MRI>"!"         { RTOKEN('!');}
 227 <BOTH,SCRIPT,EXPRESSION,MRI>"?"         { RTOKEN('?');}
 228 <BOTH,SCRIPT,EXPRESSION,MRI>"*"         { RTOKEN('*');}
 229 <BOTH,SCRIPT,EXPRESSION,MRI>"+"         { RTOKEN('+');}
 230 <BOTH,SCRIPT,EXPRESSION,MRI>"-"         { RTOKEN('-');}
 231 <BOTH,SCRIPT,EXPRESSION,MRI>"/"         { RTOKEN('/');}
 232 <BOTH,SCRIPT,EXPRESSION,MRI>"%"         { RTOKEN('%');}
 233 <BOTH,SCRIPT,EXPRESSION,MRI>"<"         { RTOKEN('<');}
 234 <BOTH,SCRIPT,EXPRESSION,MRI>"="         { RTOKEN('=');}
 235 <BOTH,SCRIPT,EXPRESSION,MRI>"}"         { RTOKEN('}') ; }
 236 <BOTH,SCRIPT,EXPRESSION,MRI>"{"         { RTOKEN('{'); }
 237 <BOTH,SCRIPT,EXPRESSION,MRI>")"         { RTOKEN(')');}
 238 <BOTH,SCRIPT,EXPRESSION,MRI>"("         { RTOKEN('(');}
 239 <BOTH,SCRIPT,EXPRESSION,MRI>":"         { RTOKEN(':'); }
 240 <BOTH,SCRIPT,EXPRESSION,MRI>";"         { RTOKEN(';');}
 241 <BOTH,SCRIPT>"MEMORY"                   { RTOKEN(MEMORY);}
 242 <BOTH,SCRIPT,EXPRESSION>"ORIGIN"        { RTOKEN(ORIGIN);}
 243 <BOTH,SCRIPT>"VERSION"                  { RTOKEN(VERSIONK);}
 244 <EXPRESSION,BOTH,SCRIPT>"BLOCK"         { RTOKEN(BLOCK);}
 245 <EXPRESSION,BOTH,SCRIPT>"BIND"          { RTOKEN(BIND);}
 246 <BOTH,SCRIPT,EXPRESSION>"LENGTH"        { RTOKEN(LENGTH);}
 247 <EXPRESSION,BOTH,SCRIPT>"ALIGN"         { RTOKEN(ALIGN_K);}
 248 <EXPRESSION,BOTH,SCRIPT>"DATA_SEGMENT_ALIGN"    { RTOKEN(DATA_SEGMENT_ALIGN);}
 249 <EXPRESSION,BOTH,SCRIPT>"DATA_SEGMENT_RELRO_END"        { RTOKEN(DATA_SEGMENT_RELRO_END);}
 250 <EXPRESSION,BOTH,SCRIPT>"DATA_SEGMENT_END"      { RTOKEN(DATA_SEGMENT_END);}
 251 <EXPRESSION,BOTH,SCRIPT>"ADDR"          { RTOKEN(ADDR);}
 252 <EXPRESSION,BOTH,SCRIPT>"LOADADDR"      { RTOKEN(LOADADDR);}
 253 <EXPRESSION,BOTH,SCRIPT>"ALIGNOF"       { RTOKEN(ALIGNOF); }
 254 <EXPRESSION,BOTH>"MAX"                  { RTOKEN(MAX_K); }
 255 <EXPRESSION,BOTH>"MIN"                  { RTOKEN(MIN_K); }
 256 <EXPRESSION,BOTH>"CEILP2"                       { RTOKEN(CEILP2); }
 257 <EXPRESSION,BOTH>"NACL_MASK"    { RTOKEN(NACL_MASK);}
 258 <EXPRESSION,BOTH,SCRIPT>"ASSERT"        { RTOKEN(ASSERT_K); }
 259 <BOTH,SCRIPT>"ENTRY"                    { RTOKEN(ENTRY);}
 260 <BOTH,SCRIPT,MRI>"EXTERN"               { RTOKEN(EXTERN);}
 261 <EXPRESSION,BOTH,SCRIPT>"NEXT"          { RTOKEN(NEXT);}
 262 <EXPRESSION,BOTH,SCRIPT>"sizeof_headers"        { RTOKEN(SIZEOF_HEADERS);}
 263 <EXPRESSION,BOTH,SCRIPT>"SIZEOF_HEADERS"        { RTOKEN(SIZEOF_HEADERS);}
 264 <EXPRESSION,BOTH,SCRIPT>"SEGMENT_START" { RTOKEN(SEGMENT_START);}
 265 <BOTH,SCRIPT>"MAP"                      { RTOKEN(MAP);}
 266 <EXPRESSION,BOTH,SCRIPT>"SIZEOF"        { RTOKEN(SIZEOF);}
 267 <BOTH,SCRIPT>"TARGET"                   { RTOKEN(TARGET_K);}
 268 <BOTH,SCRIPT>"SEARCH_DIR"               { RTOKEN(SEARCH_DIR);}
 269 <BOTH,SCRIPT>"OUTPUT"                   { RTOKEN(OUTPUT);}
 270 <BOTH,SCRIPT>"INPUT"                    { RTOKEN(INPUT);}
 271 <EXPRESSION,BOTH,SCRIPT>"GROUP"         { RTOKEN(GROUP);}
 272 <EXPRESSION,BOTH,SCRIPT>"AS_NEEDED"     { RTOKEN(AS_NEEDED);}
 273 <EXPRESSION,BOTH,SCRIPT>"DEFINED"       { RTOKEN(DEFINED);}
 274 <BOTH,SCRIPT>"CREATE_OBJECT_SYMBOLS"    { RTOKEN(CREATE_OBJECT_SYMBOLS);}
 275 <BOTH,SCRIPT>"CONSTRUCTORS"             { RTOKEN( CONSTRUCTORS);}
 276 <BOTH,SCRIPT>"FORCE_COMMON_ALLOCATION"  { RTOKEN(FORCE_COMMON_ALLOCATION);}
 277 <BOTH,SCRIPT>"INHIBIT_COMMON_ALLOCATION" { RTOKEN(INHIBIT_COMMON_ALLOCATION);}
 278 <BOTH,SCRIPT>"SECTIONS"                 { RTOKEN(SECTIONS);}
 279 <BOTH,SCRIPT>"FILL"                     { RTOKEN(FILL);}
 280 <BOTH,SCRIPT>"STARTUP"                  { RTOKEN(STARTUP);}
 281 <BOTH,SCRIPT>"OUTPUT_FORMAT"            { RTOKEN(OUTPUT_FORMAT);}
 282 <BOTH,SCRIPT>"OUTPUT_ARCH"              { RTOKEN( OUTPUT_ARCH);}
 283 <BOTH,SCRIPT>"HLL"                      { RTOKEN(HLL);}
 284 <BOTH,SCRIPT>"SYSLIB"                   { RTOKEN(SYSLIB);}
 285 <BOTH,SCRIPT>"FLOAT"                    { RTOKEN(FLOAT);}
 286 <BOTH,SCRIPT>"QUAD"                     { RTOKEN( QUAD);}
 287 <BOTH,SCRIPT>"SQUAD"                    { RTOKEN( SQUAD);}
 288 <BOTH,SCRIPT>"LONG"                     { RTOKEN( LONG);}
 289 <BOTH,SCRIPT>"SHORT"                    { RTOKEN( SHORT);}
 290 <BOTH,SCRIPT>"BYTE"                     { RTOKEN( BYTE);}
 291 <BOTH,SCRIPT>"NOFLOAT"                  { RTOKEN(NOFLOAT);}
 292 <EXPRESSION,BOTH,SCRIPT>"NOCROSSREFS"   { RTOKEN(NOCROSSREFS);}
 293 <BOTH,SCRIPT>"OVERLAY"                  { RTOKEN(OVERLAY); }
 294 <BOTH,SCRIPT>"SORT_BY_NAME"             { RTOKEN(SORT_BY_NAME); }
 295 <BOTH,SCRIPT>"SORT_BY_ALIGNMENT"        { RTOKEN(SORT_BY_ALIGNMENT); }
 296 <BOTH,SCRIPT>"SORT"                     { RTOKEN(SORT_BY_NAME); }
 297 <EXPRESSION,BOTH,SCRIPT>"NOLOAD"        { RTOKEN(NOLOAD);}
 298 <EXPRESSION,BOTH,SCRIPT>"DSECT"         { RTOKEN(DSECT);}
 299 <EXPRESSION,BOTH,SCRIPT>"COPY"          { RTOKEN(COPY);}
 300 <EXPRESSION,BOTH,SCRIPT>"INFO"          { RTOKEN(INFO);}
 301 <EXPRESSION,BOTH,SCRIPT>"OVERLAY"       { RTOKEN(OVERLAY);}
 302 <EXPRESSION,BOTH,SCRIPT>"ONLY_IF_RO"    { RTOKEN(ONLY_IF_RO); }
 303 <EXPRESSION,BOTH,SCRIPT>"ONLY_IF_RW"    { RTOKEN(ONLY_IF_RW); }
 304 <EXPRESSION,BOTH,SCRIPT>"SPECIAL"       { RTOKEN(SPECIAL); }
 305 <BOTH,SCRIPT>"o"                        { RTOKEN(ORIGIN);}
 306 <BOTH,SCRIPT>"org"                      { RTOKEN(ORIGIN);}
 307 <BOTH,SCRIPT>"l"                        { RTOKEN( LENGTH);}
 308 <BOTH,SCRIPT>"len"                      { RTOKEN( LENGTH);}
 309 <BOTH,SCRIPT>"INCLUDE"                  { RTOKEN(INCLUDE);}
 310 <BOTH,SCRIPT>"PHDRS"                    { RTOKEN (PHDRS); }
 311 <EXPRESSION,BOTH,SCRIPT>"AT"            { RTOKEN(AT);}
 312 <EXPRESSION,BOTH,SCRIPT>"SUBALIGN"      { RTOKEN(SUBALIGN);}
 313 <EXPRESSION,BOTH,SCRIPT>"PROVIDE"       { RTOKEN(PROVIDE); }
 314 <EXPRESSION,BOTH,SCRIPT>"PROVIDE_HIDDEN" { RTOKEN(PROVIDE_HIDDEN); }
 315 <EXPRESSION,BOTH,SCRIPT>"KEEP"          { RTOKEN(KEEP); }
 316 <EXPRESSION,BOTH,SCRIPT>"EXCLUDE_FILE"  { RTOKEN(EXCLUDE_FILE); }
 317 <EXPRESSION,BOTH,SCRIPT>"CONSTANT"      { RTOKEN(CONSTANT);}
 318 <MRI>"#".*\n?                   { ++ lineno; }
 319 <MRI>"\n"                       { ++ lineno;  RTOKEN(NEWLINE); }
 320 <MRI>"*".*                      { /* Mri comment line */ }
 321 <MRI>";".*                      { /* Mri comment line */ }
 322 <MRI>"END"                      { RTOKEN(ENDWORD); }
 323 <MRI>"ALIGNMOD"                 { RTOKEN(ALIGNMOD);}
 324 <MRI>"ALIGN"                    { RTOKEN(ALIGN_K);}
 325 <MRI>"CHIP"                     { RTOKEN(CHIP); }
 326 <MRI>"BASE"                     { RTOKEN(BASE); }
 327 <MRI>"ALIAS"                    { RTOKEN(ALIAS); }
 328 <MRI>"TRUNCATE"                 { RTOKEN(TRUNCATE); }
 329 <MRI>"LOAD"                     { RTOKEN(LOAD); }
 330 <MRI>"PUBLIC"                   { RTOKEN(PUBLIC); }
 331 <MRI>"ORDER"                    { RTOKEN(ORDER); }
 332 <MRI>"NAME"                     { RTOKEN(NAMEWORD); }
 333 <MRI>"FORMAT"                   { RTOKEN(FORMAT); }
 334 <MRI>"CASE"                     { RTOKEN(CASE); }
 335 <MRI>"START"                    { RTOKEN(START); }
 336 <MRI>"LIST".*                   { RTOKEN(LIST); /* LIST and ignore to end of line */ }
 337 <MRI>"SECT"                     { RTOKEN(SECT); }
 338 <EXPRESSION,BOTH,SCRIPT,MRI>"ABSOLUTE"                  { RTOKEN(ABSOLUTE); }
 339 <MRI>"end"                      { RTOKEN(ENDWORD); }
 340 <MRI>"alignmod"                 { RTOKEN(ALIGNMOD);}
 341 <MRI>"align"                    { RTOKEN(ALIGN_K);}
 342 <MRI>"chip"                     { RTOKEN(CHIP); }
 343 <MRI>"base"                     { RTOKEN(BASE); }
 344 <MRI>"alias"                    { RTOKEN(ALIAS); }
 345 <MRI>"truncate"                 { RTOKEN(TRUNCATE); }
 346 <MRI>"load"                     { RTOKEN(LOAD); }
 347 <MRI>"public"                   { RTOKEN(PUBLIC); }
 348 <MRI>"order"                    { RTOKEN(ORDER); }
 349 <MRI>"name"                     { RTOKEN(NAMEWORD); }
 350 <MRI>"format"                   { RTOKEN(FORMAT); }
 351 <MRI>"case"                     { RTOKEN(CASE); }
 352 <MRI>"extern"                   { RTOKEN(EXTERN); }
 353 <MRI>"start"                    { RTOKEN(START); }
 354 <MRI>"list".*                   { RTOKEN(LIST); /* LIST and ignore to end of line */ }
 355 <MRI>"sect"                     { RTOKEN(SECT); }
 356 <EXPRESSION,BOTH,SCRIPT,MRI>"absolute"                  { RTOKEN(ABSOLUTE); }
 357
 358 <MRI>{FILENAMECHAR1}{NOCFILENAMECHAR}*  {
 359 /* Filename without commas, needed to parse mri stuff */
 360                                  yylval.name = xstrdup (yytext);
 361                                   return NAME;
 362                                 }
 363
 364
 365 <BOTH>{FILENAMECHAR1}{FILENAMECHAR}*    {
 366                                  yylval.name = xstrdup (yytext);
 367                                   return NAME;
 368                                 }
 369 <BOTH>"-l"{FILENAMECHAR}+ {
 370                                   yylval.name = xstrdup (yytext + 2);
 371                                   return LNAME;
 372                                 }
 373 <EXPRESSION>{FILENAMECHAR1}{NOCFILENAMECHAR}*   {
 374                                  yylval.name = xstrdup (yytext);
 375                                   return NAME;
 376                                 }
 377 <EXPRESSION>"-l"{NOCFILENAMECHAR}+ {
 378                                   yylval.name = xstrdup (yytext + 2);
 379                                   return LNAME;
 380                                 }
 381 <SCRIPT>{WILDCHAR}* {
 382                 /* Annoyingly, this pattern can match comments, and we have
 383                    longest match issues to consider.  So if the first two
 384                    characters are a comment opening, put the input back and
 385                    try again.  */
 386                 if (yytext[0] == '/' && yytext[1] == '*')
 387                   {
 388                     yyless (2);
 389                     comment ();
 390                   }
 391                 else
 392                   {
 393                     yylval.name = xstrdup (yytext);
 394                     return NAME;
 395                   }
 396         }
 397
 398 <EXPRESSION,BOTH,SCRIPT,VERS_NODE>"\""[^\"]*"\"" {
 399                                         /* No matter the state, quotes
 400                                            give what's inside */
 401                                         yylval.name = xstrdup (yytext + 1);
 402                                         yylval.name[yyleng - 2] = 0;
 403                                         return NAME;
 404                                 }
 405 <BOTH,SCRIPT,EXPRESSION>"\n"            { lineno++;}
 406 <MRI,BOTH,SCRIPT,EXPRESSION>[ \t\r]+    { }
 407
 408 <VERS_NODE,VERS_SCRIPT>[:,;]    { return *yytext; }
 409
 410 <VERS_NODE>global               { RTOKEN(GLOBAL); }
 411
 412 <VERS_NODE>local                { RTOKEN(LOCAL); }
 413
 414 <VERS_NODE>extern               { RTOKEN(EXTERN); }
 415
 416 <VERS_NODE>{V_IDENTIFIER}       { yylval.name = xstrdup (yytext);
 417                                   return VERS_IDENTIFIER; }
 418
 419 <VERS_SCRIPT>{V_TAG}            { yylval.name = xstrdup (yytext);
 420                                   return VERS_TAG; }
 421
 422 <VERS_START>"{"                 { BEGIN(VERS_SCRIPT); return *yytext; }
 423
 424 <VERS_SCRIPT>"{"                { BEGIN(VERS_NODE);
 425                                   vers_node_nesting = 0;
 426                                   return *yytext;
 427                                 }
 428 <VERS_SCRIPT>"}"                { return *yytext; }
 429 <VERS_NODE>"{"                  { vers_node_nesting++; return *yytext; }
 430 <VERS_NODE>"}"                  { if (--vers_node_nesting < 0)
 431                                     BEGIN(VERS_SCRIPT);
 432                                   return *yytext;
 433                                 }
 434
 435 <VERS_START,VERS_NODE,VERS_SCRIPT>[\n]          { lineno++; }
 436
 437 <VERS_START,VERS_NODE,VERS_SCRIPT>#.*           { /* Eat up comments */ }
 438
 439 <VERS_START,VERS_NODE,VERS_SCRIPT>[ \t\r]+      { /* Eat up whitespace */ }
 440
 441 <<EOF>> {
 442   include_stack_ptr--;
 443
 444   if (include_stack_ptr == 0)
 445   {
 446     yyterminate ();
 447   }
 448   else
 449   {
 450     yy_switch_to_buffer (include_stack[include_stack_ptr]);
 451   }
 452
 453   ldfile_input_filename = file_name_stack[include_stack_ptr - 1];
 454   lineno = lineno_stack[include_stack_ptr];
 455
 456   return END;
 457 }
 458
 459 <SCRIPT,MRI,VERS_START,VERS_SCRIPT,VERS_NODE>.  lex_warn_invalid (" in script", yytext);
 460 <EXPRESSION,DEFSYMEXP,BOTH>.    lex_warn_invalid (" in expression", yytext);
 461
 462 %%
 463 \f
 464
 465 /* Switch flex to reading script file NAME, open on FILE,
 466    saving the current input info on the include stack.  */
 467
 468 void
 469 lex_push_file (FILE *file, const char *name)
 470 {
 471   if (include_stack_ptr >= MAX_INCLUDE_DEPTH)
 472     {
 473       einfo ("%F:includes nested too deeply\n");
 474     }
 475   file_name_stack[include_stack_ptr] = name;
 476   lineno_stack[include_stack_ptr] = lineno;
 477   include_stack[include_stack_ptr] = YY_CURRENT_BUFFER;
 478
 479   include_stack_ptr++;
 480   lineno = 1;
 481   yyin = file;
 482   yy_switch_to_buffer (yy_create_buffer (yyin, YY_BUF_SIZE));
 483 }
 484
 485 /* Return a newly created flex input buffer containing STRING,
 486    which is SIZE bytes long.  */
 487
 488 static YY_BUFFER_STATE
 489 yy_create_string_buffer (const char *string, size_t size)
 490 {
 491   YY_BUFFER_STATE b;
 492
 493   /* Calls to m-alloc get turned by sed into xm-alloc.  */
 494   b = malloc (sizeof (struct yy_buffer_state));
 495   b->yy_input_file = 0;
 496   b->yy_buf_size = size;
 497
 498   /* yy_ch_buf has to be 2 characters longer than the size given because
 499      we need to put in 2 end-of-buffer characters.  */
 500   b->yy_ch_buf = malloc ((unsigned) (b->yy_buf_size + 3));
 501
 502   b->yy_ch_buf[0] = '\n';
 503   strcpy (b->yy_ch_buf+1, string);
 504   b->yy_ch_buf[size+1] = YY_END_OF_BUFFER_CHAR;
 505   b->yy_ch_buf[size+2] = YY_END_OF_BUFFER_CHAR;
 506   b->yy_n_chars = size+1;
 507   b->yy_buf_pos = &b->yy_ch_buf[1];
 508
 509   b->yy_is_our_buffer = 1;
 510   b->yy_is_interactive = 0;
 511   b->yy_at_bol = 1;
 512   b->yy_fill_buffer = 0;
 513
 514   /* flex 2.4.7 changed the interface.  FIXME: We should not be using
 515      a flex internal interface in the first place!  */
 516 #ifdef YY_BUFFER_NEW
 517   b->yy_buffer_status = YY_BUFFER_NEW;
 518 #else
 519   b->yy_eof_status = EOF_NOT_SEEN;
 520 #endif
 521
 522   return b;
 523 }
 524
 525 /* Switch flex to reading from STRING, saving the current input info
 526    on the include stack.  */
 527
 528 void
 529 lex_redirect (const char *string)
 530 {
 531   YY_BUFFER_STATE tmp;
 532
 533   yy_init = 0;
 534   if (include_stack_ptr >= MAX_INCLUDE_DEPTH)
 535     {
 536       einfo("%F: macros nested too deeply\n");
 537     }
 538   file_name_stack[include_stack_ptr] = "redirect";
 539   lineno_stack[include_stack_ptr] = lineno;
 540   include_stack[include_stack_ptr] = YY_CURRENT_BUFFER;
 541   include_stack_ptr++;
 542   lineno = 1;
 543   tmp = yy_create_string_buffer (string, strlen (string));
 544   yy_switch_to_buffer (tmp);
 545 }
 546 \f
 547 /* Functions to switch to a different flex start condition,
 548    saving the current start condition on `state_stack'.  */
 549
 550 static int state_stack[MAX_INCLUDE_DEPTH * 2];
 551 static int *state_stack_p = state_stack;
 552
 553 void
 554 ldlex_script (void)
 555 {
 556   *(state_stack_p)++ = yy_start;
 557   BEGIN (SCRIPT);
 558 }
 559
 560 void
 561 ldlex_mri_script (void)
 562 {
 563   *(state_stack_p)++ = yy_start;
 564   BEGIN (MRI);
 565 }
 566
 567 void
 568 ldlex_version_script (void)
 569 {
 570   *(state_stack_p)++ = yy_start;
 571   BEGIN (VERS_START);
 572 }
 573
 574 void
 575 ldlex_version_file (void)
 576 {
 577   *(state_stack_p)++ = yy_start;
 578   BEGIN (VERS_SCRIPT);
 579 }
 580
 581 void
 582 ldlex_defsym (void)
 583 {
 584   *(state_stack_p)++ = yy_start;
 585   BEGIN (DEFSYMEXP);
 586 }
 587
 588 void
 589 ldlex_expression (void)
 590 {
 591   *(state_stack_p)++ = yy_start;
 592   BEGIN (EXPRESSION);
 593 }
 594
 595 void
 596 ldlex_both (void)
 597 {
 598   *(state_stack_p)++ = yy_start;
 599   BEGIN (BOTH);
 600 }
 601
 602 void
 603 ldlex_popstate (void)
 604 {
 605   yy_start = *(--state_stack_p);
 606 }
 607 \f
 608
 609 /* Place up to MAX_SIZE characters in BUF and return in *RESULT
 610    either the number of characters read, or 0 to indicate EOF.  */
 611
 612 static void
 613 yy_input (char *buf, int *result, int max_size)
 614 {
 615   *result = 0;
 616   if (YY_CURRENT_BUFFER->yy_input_file)
 617     {
 618       if (yyin)
 619         {
 620           *result = fread (buf, 1, max_size, yyin);
 621           if (*result < max_size && ferror (yyin))
 622             einfo ("%F%P: read in flex scanner failed\n");
 623         }
 624     }
 625 }
 626
 627 /* Eat the rest of a C-style comment.  */
 628
 629 static void
 630 comment (void)
 631 {
 632   int c;
 633
 634   while (1)
 635   {
 636     c = input();
 637     while (c != '*' && c != EOF)
 638     {
 639       if (c == '\n')
 640         lineno++;
 641       c = input();
 642     }
 643
 644     if (c == '*')
 645     {
 646       c = input();
 647       while (c == '*')
 648        c = input();
 649       if (c == '/')
 650        break;                   /* found the end */
 651     }
 652
 653     if (c == '\n')
 654       lineno++;
 655
 656     if (c == EOF)
 657     {
 658       einfo( "%F%P: EOF in comment\n");
 659       break;
 660     }
 661   }
 662 }
 663
 664 /* Warn the user about a garbage character WHAT in the input
 665    in context WHERE.  */
 666
 667 static void
 668 lex_warn_invalid (char *where, char *what)
 669 {
 670   char buf[5];
 671
 672   /* If we have found an input file whose format we do not recognize,
 673      and we are therefore treating it as a linker script, and we find
 674      an invalid character, then most likely this is a real object file
 675      of some different format.  Treat it as such.  */
 676   if (ldfile_assumed_script)
 677     {
 678       bfd_set_error (bfd_error_file_not_recognized);
 679       einfo ("%F%s: file not recognized: %E\n", ldfile_input_filename);
 680     }
 681
 682   if (! ISPRINT (*what))
 683     {
 684       sprintf (buf, "\\%03o", (unsigned int) *what);
 685       what = buf;
 686     }
 687
 688   einfo ("%P:%S: ignoring invalid character `%s'%s\n", what, where);
 689 }