configure.in

   1 dnl Process this file with autoconf 2.61 or later to produce
   2 dnl a configure script.
   3 AC_PREREQ(2.61)
   4 AC_INIT(config.h.in)
   5 AC_CONFIG_HEADERS(config.h)
   6
   7 dnl Check for broken VPATH handling on older NetBSD makes.
   8 AC_DEFUN(AC_PROG_MAKE_VPATHOK,
   9 [AC_MSG_CHECKING(whether ${MAKE-make} has sane VPATH handling)
  10 set dummy ${MAKE-make}; ac_make=`echo "[$]2" | sed 'y%./+-%__p_%'`
  11 AC_CACHE_VAL(ac_cv_prog_make_vpathok,
  12 [mkdir conftestdir
  13 cat > conftestdir/conftestmake <<\EOF
  14 VPATH = ..
  15 conftestfoo: conftestbar
  16         @echo ac_make2temp=ok
  17 conftestbar: conftestbaz
  18         @echo ac_maketemp=broken
  19         @touch conftestbar
  20 EOF
  21 echo > conftestbaz # these two lines need to be...
  22 echo > conftestbar # ... in this order not the other
  23 changequote(, )dnl
  24 unset ac_maketemp
  25 unset ac_make2temp
  26 # GNU make sometimes prints "make[1]: Entering...", which would confuse us.
  27 eval `cd conftestdir; ${MAKE-make} -f conftestmake 2>/dev/null | grep temp=`
  28 changequote([, ])dnl
  29 if test -n "$ac_maketemp"; then
  30   ac_cv_prog_make_vpathok=no
  31 else
  32   if test -n "$ac_make2temp"; then
  33     ac_cv_prog_make_vpathok=yes
  34   else
  35     ac_cv_prog_make_vpathok=no
  36   fi
  37 fi
  38 rm -rf conftestdir
  39 rm -f conftestbar conftestbaz])dnl
  40 if test $ac_cv_prog_make_vpathok = yes; then
  41   AC_MSG_RESULT(yes)
  42 else
  43   AC_MSG_RESULT(no)
  44 fi
  45 ])
  46
  47 AC_PREFIX_PROGRAM(nasm)
  48
  49 dnl Checks for programs.
  50 dnl Consider AC_USE_SYSTEM_EXTENSIONS if autoconf 2.61 is OK in the future
  51 AC_USE_SYSTEM_EXTENSIONS
  52 AC_PROG_CC
  53 AC_PROG_LN_S
  54 AC_PROG_MAKE_SET
  55 if test -f nasm.c; then
  56   # we're building in the source dir, so we don't need this check at all
  57   ac_cv_prog_make_vpathok=yes
  58 else
  59   AC_PROG_MAKE_VPATHOK
  60 fi
  61 AC_PROG_INSTALL
  62
  63 dnl If we have gcc, add appropriate options
  64 PA_ADD_CFLAGS([-W])
  65 PA_ADD_CFLAGS([-Wall])
  66 PA_ADD_CFLAGS([-std=c99])
  67 PA_ADD_CFLAGS([-pedantic])
  68
  69 dnl Look for programs...
  70 AC_CHECK_PROGS(NROFF,    nroff,    echo)
  71 AC_CHECK_PROGS(ACRODIST, acrodist, false)
  72 AC_CHECK_PROGS(PS2PDF,   ps2pdf,   false)
  73 AC_CHECK_PROGS(PSTOPDF,  pstopdf,  false)
  74
  75 dnl Checks for header files.
  76 AC_HEADER_STDC
  77 if test $ac_cv_header_stdc = no; then
  78   AC_MSG_ERROR([NASM requires ANSI C header files to compile])
  79 fi
  80
  81 AC_CHECK_HEADERS(limits.h)
  82 if test $ac_cv_header_limits_h = no; then
  83   AC_MSG_ERROR([NASM requires '<limits.h>' to compile])
  84 fi
  85
  86 dnl Check for <inttypes.h> or add a substitute version
  87 AC_CHECK_HEADERS(inttypes.h, , CFLAGS="$CFLAGS -I\$(top_srcdir)/inttypes")
  88
  89 dnl The standard header for str*casecmp is <strings.h>
  90 AC_CHECK_HEADERS(strings.h)
  91
  92 dnl Look for <stdbool.h>
  93 AC_CHECK_HEADERS(stdbool.h)
  94
  95 dnl Checks for typedefs, structures, and compiler characteristics.
  96 AC_C_CONST
  97 AC_C_INLINE
  98 AC_C_RESTRICT
  99 AC_TYPE_SIZE_T
 100 AC_C_BIGENDIAN(AC_DEFINE(WORDS_BIGENDIAN),AC_DEFINE(WORDS_LITTLEENDIAN))
 101 AH_TEMPLATE(WORDS_BIGENDIAN,
 102 [Define to 1 if your processor stores words with the most significant
 103 byte first (like Motorola and SPARC, unlike Intel and VAX).])
 104 AH_TEMPLATE(WORDS_LITTLEENDIAN,
 105 [Define to 1 if your processor stores words with the least significant
 106 byte first (like Intel and VAX, unlike Motorola and SPARC).])
 107
 108 dnl Checks for library functions.
 109 AC_SUBST(XOBJS)
 110
 111 AC_CHECK_FUNCS(strcspn, ,
 112   AC_MSG_ERROR([NASM requires ANSI C (specifically, "strcspn")]))
 113
 114 AC_CHECK_FUNCS(strspn, ,
 115   AC_MSG_ERROR([NASM requires ANSI C (specifically, "strspn")]))
 116
 117 missing=true
 118 AC_CHECK_FUNCS([vsnprintf _vsnprintf], missing=false)
 119 if $missing; then
 120    XOBJS="$XOBJS lib/vsnprintf.o"
 121 fi
 122
 123 missing=true
 124 AC_CHECK_FUNCS([snprintf _snprintf], missing=false)
 125 if $missing; then
 126    XOBJS="$XOBJS lib/snprintf.o"
 127 fi
 128
 129 AC_CHECK_FUNCS(strcasecmp stricmp)
 130 AC_CHECK_FUNCS(strncasecmp strnicmp)
 131 AC_CHECK_FUNCS(strsep)
 132
 133 AC_CHECK_FUNCS(getuid)
 134 AC_CHECK_FUNCS(getgid)
 135
 136 dnl Check for functions that might not be declared in the headers for
 137 dnl various idiotic reasons (mostly because of library authors
 138 dnl abusing the meaning of __STRICT_ANSI__)
 139 AC_CHECK_DECLS(strcasecmp)
 140 AC_CHECK_DECLS(stricmp)
 141 AC_CHECK_DECLS(strncasecmp)
 142 AC_CHECK_DECLS(strnicmp)
 143 AC_CHECK_DECLS(strsep)
 144
 145 if test $ac_cv_prog_make_vpathok = no; then
 146   echo Copying generated srcs into build directory to compensate for VPATH breakage
 147   for file in macros.c insnsa.c insnsd.c insnsn.c insnsi.h version.h version.mac; do
 148     if test ! -f $file; then cp -p ${srcdir}/${file} .; fi
 149   done
 150 fi
 151
 152 AC_OUTPUT_COMMANDS([mkdir -p output])
 153 AC_OUTPUT(Makefile rdoff/Makefile doc/Makefile)