configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_INIT(nasm.c)
   3
   4 dnl Check for broken VPATH handling on older NetBSD makes.
   5 AC_DEFUN(AC_PROG_MAKE_VPATHOK,
   6 [AC_MSG_CHECKING(whether ${MAKE-make} has sane VPATH handling)
   7 set dummy ${MAKE-make}; ac_make=`echo "[$]2" | sed 'y%./+-%__p_%'`
   8 AC_CACHE_VAL(ac_cv_prog_make_vpathok,
   9 [mkdir conftestdir
  10 cat > conftestdir/conftestmake <<\EOF
  11 VPATH = ..
  12 conftestfoo: conftestbar
  13         @echo ac_make2temp=ok
  14 conftestbar: conftestbaz
  15         @echo ac_maketemp=broken
  16         @touch conftestbar
  17 EOF
  18 echo > conftestbaz # these two lines need to be...
  19 echo > conftestbar # ... in this order not the other
  20 changequote(, )dnl
  21 unset ac_maketemp
  22 unset ac_make2temp
  23 # GNU make sometimes prints "make[1]: Entering...", which would confuse us.
  24 eval `cd conftestdir; ${MAKE-make} -f conftestmake 2>/dev/null | grep temp=`
  25 changequote([, ])dnl
  26 if test -n "$ac_maketemp"; then
  27   ac_cv_prog_make_vpathok=no
  28 else
  29   if test -n "$ac_make2temp"; then
  30     ac_cv_prog_make_vpathok=yes
  31   else
  32     ac_cv_prog_make_vpathok=no
  33   fi
  34 fi
  35 rm -rf conftestdir
  36 rm -f conftestbar conftestbaz])dnl
  37 if test $ac_cv_prog_make_vpathok = yes; then
  38   AC_MSG_RESULT(yes)
  39 else
  40   AC_MSG_RESULT(no)
  41 fi
  42 ])
  43
  44 AC_PREFIX_PROGRAM(nasm)
  45
  46 dnl Checks for programs.
  47 AC_PROG_CC
  48 AC_PROG_LN_S
  49 AC_PROG_MAKE_SET
  50 if test -f nasm.c; then
  51   # we're building in the source dir, so we don't need this check at all
  52   ac_cv_prog_make_vpathok=yes
  53 else
  54   AC_PROG_MAKE_VPATHOK
  55 fi
  56 AC_PROG_INSTALL
  57
  58 if test "$GCC" = "yes"; then
  59   GCCFLAGS="-Wall -ansi -pedantic"
  60 else
  61   GCCFLAGS=
  62 fi
  63 AC_SUBST(GCCFLAGS)
  64
  65 dnl Checks for header files.
  66 AC_HEADER_STDC
  67 if test $ac_cv_header_stdc = no; then
  68   AC_MSG_ERROR([NASM requires ANSI C header files to compile])
  69 fi
  70
  71 AC_CHECK_HEADERS(limits.h)
  72 if test $ac_cv_header_limits_h = no; then
  73   AC_MSG_ERROR([NASM requires '<limits.h>' to compile])
  74 fi
  75
  76 dnl Checks for typedefs, structures, and compiler characteristics.
  77 AC_C_CONST
  78 if test $ac_cv_c_const = no; then
  79   AC_MSG_ERROR([NASM requires ANSI C (specifically, working "const")])
  80 fi
  81
  82 AC_TYPE_SIZE_T
  83 if test $ac_cv_type_size_t = no; then
  84   AC_MSG_ERROR([NASM requires ANSI C (specifically, "size_t")])
  85 fi
  86
  87 dnl Checks for library functions.
  88 AC_FUNC_VPRINTF
  89 if test $ac_cv_func_vprintf = no; then
  90   AC_MSG_ERROR([NASM requires ANSI C (specifically, "vprintf" and friends)])
  91 fi
  92
  93 AC_CHECK_FUNCS(strcspn)
  94 if test $ac_cv_func_strcspn = no; then
  95   AC_MSG_ERROR([NASM requires ANSI C (specifically, "strcspn")])
  96 fi
  97
  98 AC_CHECK_FUNCS(strspn)
  99 if test $ac_cv_func_strspn = no; then
 100   AC_MSG_ERROR([NASM requires ANSI C (specifically, "strspn")])
 101 fi
 102
 103 if test $ac_cv_prog_make_vpathok = no; then
 104   echo Copying generated srcs into build directory to compensate for VPATH breakage
 105   if test ! -f insnsa.c; then cp -p ${srcdir}/insnsa.c .; fi
 106   if test ! -f insnsd.c; then cp -p ${srcdir}/insnsd.c .; fi
 107   if test ! -f macros.c; then cp -p ${srcdir}/macros.c .; fi
 108 fi
 109
 110 AC_OUTPUT(Makefile rdoff/Makefile)