winpcap/wpcap/libpcap/configure.in

   1 dnl @(#) $Header: /tcpdump/master/libpcap/configure.in,v 1.120.2.8 2006/04/07 07:08:50 guy Exp $ (LBL)
   2 dnl
   3 dnl Copyright (c) 1994, 1995, 1996, 1997
   4 dnl     The Regents of the University of California.  All rights reserved.
   5 dnl
   6 dnl Process this file with autoconf to produce a configure script.
   7 dnl
   8
   9 AC_REVISION($Revision: 1.120.2.8 $)
  10 AC_PREREQ(2.50)
  11 AC_INIT(pcap.c)
  12
  13 AC_CANONICAL_SYSTEM
  14
  15 AC_LBL_C_INIT(V_CCOPT, V_INCLS, V_LIBS)
  16 AC_LBL_C_INLINE
  17 AC_C___ATTRIBUTE__
  18
  19 AC_LBL_CHECK_TYPE(u_int8_t, u_char)
  20 AC_LBL_CHECK_TYPE(u_int16_t, u_short)
  21 AC_LBL_CHECK_TYPE(u_int32_t, u_int)
  22
  23 dnl
  24 dnl libpcap doesn't itself use <sys/ioccom.h>; however, the test program
  25 dnl in "AC_LBL_FIXINCLUDES" in "aclocal.m4" uses it, so we have to
  26 dnl test for it and set "HAVE_SYS_IOCCOM_H" if we have it, otherwise
  27 dnl "AC_LBL_FIXINCLUDES" won't work on some platforms such as Solaris.
  28 dnl
  29 AC_CHECK_HEADERS(sys/ioccom.h sys/sockio.h limits.h)
  30 AC_CHECK_HEADERS(netinet/if_ether.h, , , [#include <sys/types.h>
  31 #include <sys/socket.h>])
  32 if test "$ac_cv_header_netinet_if_ether_h" != yes; then
  33         #
  34         # The simple test didn't work.
  35         # Do we need to include <net/if.h> first?
  36         # Unset ac_cv_header_netinet_if_ether_h so we don't
  37         # treat the previous failure as a cached value and
  38         # suppress the next test.
  39         #
  40         AC_MSG_NOTICE([Rechecking with some additional includes])
  41         unset ac_cv_header_netinet_if_ether_h
  42         AC_CHECK_HEADERS(netinet/if_ether.h, , , [#include <sys/types.h>
  43 #include <sys/socket.h>
  44 #include <netinet/in.h>
  45 struct mbuf;
  46 struct rtentry;
  47 #include <net/if.h>])
  48 fi
  49
  50 AC_LBL_FIXINCLUDES
  51
  52 AC_CHECK_FUNCS(strerror strlcpy)
  53
  54 needsnprintf=no
  55 AC_CHECK_FUNCS(vsnprintf snprintf,,
  56         [needsnprintf=yes])
  57 if test $needsnprintf = yes; then
  58         AC_LIBOBJ(snprintf)
  59 fi
  60
  61 #
  62 # Do this before checking for ether_hostton(), as it's a
  63 # "gethostbyname() -ish function".
  64 #
  65 AC_LBL_LIBRARY_NET
  66
  67 #
  68 # You are in a twisty little maze of UN*Xes, all different.
  69 # Some might not have ether_hostton().
  70 # Some might have it, but not declare it in any header file.
  71 # Some might have it, but declare it in <netinet/if_ether.h>.
  72 # Some might have it, but declare it in <netinet/ether.h>
  73 # (And some might have it but document it as something declared in
  74 # <netinet/ethernet.h>, although <netinet/if_ether.h> appears to work.)
  75 #
  76 # Before you is a C compiler.
  77 #
  78 AC_CHECK_FUNCS(ether_hostton)
  79 if test "$ac_cv_func_ether_hostton" = yes; then
  80         #
  81         # OK, we have ether_hostton().  Do we have <netinet/if_ether.h>?
  82         #
  83         if test "$ac_cv_header_netinet_if_ether_h" = yes; then
  84                 #
  85                 # Yes.  Does it declare ether_hostton()?
  86                 #
  87                 AC_CHECK_DECL(ether_hostton,
  88                     [
  89                         AC_DEFINE(NETINET_IF_ETHER_H_DECLARES_ETHER_HOSTTON,,
  90                             [Define to 1 if netinet/if_ether.h declares `ether_hostton'])
  91                     ],,
  92                     [
  93 #include <sys/types.h>
  94 #include <sys/socket.h>
  95 #include <netinet/in.h>
  96 #include <arpa/inet.h>
  97 struct mbuf;
  98 struct rtentry;
  99 #include <net/if.h>
 100 #include <netinet/if_ether.h>
 101                     ])
 102         fi
 103         #
 104         # Did that succeed?
 105         #
 106         if test "$ac_cv_have_decl_ether_hostton" != yes; then
 107                 #
 108                 # No, how about <netinet/ether.h>, as on Linux?
 109                 #
 110                 AC_CHECK_HEADERS(netinet/ether.h)
 111                 if test "$ac_cv_header_netinet_ether_h" = yes; then
 112                         #
 113                         # We have it - does it declare ether_hostton()?
 114                         # Unset ac_cv_have_decl_ether_hostton so we don't
 115                         # treat the previous failure as a cached value and
 116                         # suppress the next test.
 117                         #
 118                         unset ac_cv_have_decl_ether_hostton
 119                         AC_CHECK_DECL(ether_hostton,
 120                             [
 121                                 AC_DEFINE(NETINET_ETHER_H_DECLARES_ETHER_HOSTTON,,
 122                                     [Define to 1 if netinet/ether.h declares `ether_hostton'])
 123                             ],,
 124                             [
 125 #include <netinet/ether.h>
 126                             ])
 127                 fi
 128         fi
 129         #
 130         # Is ether_hostton() declared?
 131         #
 132         if test "$ac_cv_have_decl_ether_hostton" != yes; then
 133                 #
 134                 # No, we'll have to declare it ourselves.
 135                 # Do we have "struct ether_addr"?
 136                 #
 137                 AC_CHECK_TYPES(struct ether_addr,,,
 138                     [
 139 #include <sys/types.h>
 140 #include <sys/socket.h>
 141 #include <netinet/in.h>
 142 #include <arpa/inet.h>
 143 struct mbuf;
 144 struct rtentry;
 145 #include <net/if.h>
 146 #include <netinet/if_ether.h>
 147                     ])
 148                 AC_DEFINE(HAVE_DECL_ETHER_HOSTTON, 0,
 149                     [Define to 1 if you have the declaration of `ether_hostton', and to 0 if you
 150 don't.])
 151         else
 152                 AC_DEFINE(HAVE_DECL_ETHER_HOSTTON, 1,
 153                     [Define to 1 if you have the declaration of `ether_hostton', and to 0 if you
 154 don't.])
 155         fi
 156 fi
 157
 158 dnl to pacify those who hate protochain insn
 159 AC_MSG_CHECKING(if --disable-protochain option is specified)
 160 AC_ARG_ENABLE(protochain, [  --disable-protochain    disable \"protochain\" insn])
 161 case "x$enable_protochain" in
 162 xyes)   enable_protochain=enabled       ;;
 163 xno)    enable_protochain=disabled      ;;
 164 x)      enable_protochain=enabled       ;;
 165 esac
 166
 167 if test "$enable_protochain" = "disabled"; then
 168         AC_DEFINE(NO_PROTOCHAIN,1,[do not use protochain])
 169 fi
 170 AC_MSG_RESULT(${enable_protochain})
 171
 172 dnl
 173 dnl Not all versions of test support -c (character special) but it's a
 174 dnl better way of testing since the device might be protected. So we
 175 dnl check in our normal order using -r and then check the for the /dev
 176 dnl guys again using -c.
 177 dnl
 178 dnl XXX This could be done for cross-compiling, but for now it's not.
 179 dnl
 180 if test -z "$with_pcap" && test "$cross_compiling" = yes; then
 181         AC_MSG_ERROR(pcap type not determined when cross-compiling; use --with-pcap=...)
 182 fi
 183 AC_ARG_WITH(pcap, [  --with-pcap=TYPE        use packet capture TYPE])
 184 AC_MSG_CHECKING(packet capture type)
 185 if test ! -z "$with_pcap" ; then
 186         V_PCAP="$withval"
 187 elif test -r /dev/bpf0 ; then
 188         V_PCAP=bpf
 189 elif test -r /usr/include/net/pfilt.h ; then
 190         V_PCAP=pf
 191 elif test -r /dev/enet ; then
 192         V_PCAP=enet
 193 elif test -r /dev/nit ; then
 194         V_PCAP=snit
 195 elif test -r /usr/include/sys/net/nit.h ; then
 196         V_PCAP=nit
 197 elif test -r /usr/include/linux/socket.h ; then
 198         V_PCAP=linux
 199 elif test -r /usr/include/net/raw.h ; then
 200         V_PCAP=snoop
 201 elif test -r /usr/include/odmi.h ; then
 202         #
 203         # On AIX, the BPF devices might not yet be present - they're
 204         # created the first time libpcap runs after booting.
 205         # We check for odmi.h instead.
 206         #
 207         V_PCAP=bpf
 208 elif test -r /usr/include/sys/dlpi.h ; then
 209         V_PCAP=dlpi
 210 elif test -c /dev/bpf0 ; then           # check again in case not readable
 211         V_PCAP=bpf
 212 elif test -c /dev/enet ; then           # check again in case not readable
 213         V_PCAP=enet
 214 elif test -c /dev/nit ; then            # check again in case not readable
 215         V_PCAP=snit
 216 else
 217         V_PCAP=null
 218 fi
 219 AC_MSG_RESULT($V_PCAP)
 220
 221 dnl
 222 dnl Now figure out how we get a list of interfaces and addresses,
 223 dnl if we support capturing.  Don't bother if we don't support
 224 dnl capturing.
 225 dnl
 226 if test "$V_PCAP" = null
 227 then
 228         #
 229         # We can't capture, so we can't open any capture
 230         # devices, so we won't return any interfaces.
 231         #
 232         V_FINDALLDEVS=null
 233 else
 234         AC_CHECK_FUNC(getifaddrs,[
 235                 #
 236                 # We have "getifaddrs()"; make sure we have <ifaddrs.h>
 237                 # as well, just in case some platform is really weird.
 238                 #
 239                 AC_CHECK_HEADER(ifaddrs.h,[
 240                     #
 241                     # We have the header, so we use "getifaddrs()" to
 242                     # get the list of interfaces.
 243                     #
 244                     V_FINDALLDEVS=getad
 245                 ],[
 246                     #
 247                     # We don't have the header - give up.
 248                     # XXX - we could also fall back on some other
 249                     # mechanism, but, for now, this'll catch this
 250                     # problem so that we can at least try to figure
 251                     # out something to do on systems with "getifaddrs()"
 252                     # but without "ifaddrs.h", if there is something
 253                     # we can do on those systems.
 254                     #
 255                     AC_MSG_ERROR([Your system has getifaddrs() but doesn't have a usable <ifaddrs.h>.])
 256                 ])
 257         ],[
 258                 #
 259                 # Well, we don't have "getifaddrs()", so we have to use
 260                 # some other mechanism; determine what that mechanism is.
 261                 #
 262                 # The first thing we use is the type of capture mechanism,
 263                 # which is somewhat of a proxy for the OS we're using.
 264                 #
 265                 case "$V_PCAP" in
 266
 267                 dlpi)
 268                         #
 269                         # This might be Solaris 8 or later, with
 270                         # SIOCGLIFCONF, or it might be some other OS
 271                         # or some older version of Solaris, with
 272                         # just SIOCGIFCONF.
 273                         #
 274                         AC_MSG_CHECKING(whether we have SIOCGLIFCONF)
 275                         AC_CACHE_VAL(ac_cv_lbl_have_siocglifconf,
 276                             AC_TRY_COMPILE(
 277                                 [#include <sys/param.h>
 278                                 #include <sys/file.h>
 279                                 #include <sys/ioctl.h>
 280                                 #include <sys/socket.h>
 281                                 #include <sys/sockio.h>],
 282                                 [ioctl(0, SIOCGLIFCONF, (char *)0);],
 283                                 ac_cv_lbl_have_siocglifconf=yes,
 284                                 ac_cv_lbl_have_siocglifconf=no))
 285                         AC_MSG_RESULT($ac_cv_lbl_have_siocglifconf)
 286                         if test $ac_cv_lbl_have_siocglifconf = yes ; then
 287                                 V_FINDALLDEVS=glifc
 288                         else
 289                                 V_FINDALLDEVS=gifc
 290                         fi
 291                         ;;
 292
 293                 *)
 294                         #
 295                         # Assume we just have SIOCGIFCONF.
 296                         # (XXX - on at least later Linux kernels, there's
 297                         # another mechanism, and we should be using that
 298                         # instead.)
 299                         #
 300                         V_FINDALLDEVS=gifc
 301                         ;;
 302                 esac])
 303 fi
 304
 305 dnl HAVE_REMOTE
 306 AC_MSG_CHECKING(if --disable-remote option is specified)
 307 AC_ARG_ENABLE(remote, [  --disable-remote        disable remote capture capabilities])
 308
 309 case "x$enable_remote" in
 310 xyes)   enable_remote=enabled   ;;
 311 xno)    enable_remote=disabled  ;;
 312 x)      enable_remote=enabled   ;;
 313 esac
 314
 315 AC_MSG_RESULT(${enable_remote})
 316
 317
 318 if test "$enable_remote" = "enabled"; then
 319
 320         dnl
 321         dnl Checking if the remote features of libpcap are supported by
 322         dnl the OS and must be compiled
 323         dnl
 324
 325         AC_MSG_CHECKING(if remote capture is supported)
 326
 327         if test -e ./remote-ext.h ; then        # Check that the remote extensions are there
 328
 329                 case "$V_PCAP" in
 330
 331                 linux)
 332                         V_REMOTE_FILES="pcap-new.c pcap-remote.c sockutils.c"
 333                         V_HAVE_REMOTE="-DHAVE_REMOTE"
 334                         AC_DEFINE(HAVE_REMOTE,1,[Enable remote capture support])
 335                         have_remote=yes
 336                         ;;
 337
 338                 bpf)
 339                         V_REMOTE_FILES="pcap-new.c pcap-remote.c sockutils.c"
 340                         V_HAVE_REMOTE="-DHAVE_REMOTE"
 341                         AC_DEFINE(HAVE_REMOTE,1,[Enable remote capture support])
 342                         have_remote=yes
 343                         ;;
 344
 345                 *)
 346                         have_remote=no
 347                         ;;
 348
 349                 esac
 350
 351         AC_MSG_RESULT(${have_remote})
 352         fi
 353
 354 fi
 355 dnl END HAVE_REMOTE
 356
 357 AC_MSG_CHECKING(if --enable-ipv6 option is specified)
 358 AC_ARG_ENABLE(ipv6, [  --enable-ipv6           build IPv6-capable version])
 359 if test "$enable_ipv6" = "yes"; then
 360         AC_DEFINE(INET6,1,[IPv6])
 361 fi
 362 AC_MSG_RESULT(${enable_ipv6-no})
 363
 364 AC_MSG_CHECKING(whether to build optimizer debugging code)
 365 AC_ARG_ENABLE(optimizer-dbg, [  --enable-optimizer-dbg  build optimizer debugging code])
 366 if test "$enable_optimizer_dbg" = "yes"; then
 367         AC_DEFINE(BDEBUG,1,[Enable optimizer debugging])
 368 fi
 369 AC_MSG_RESULT(${enable_optimizer_dbg-no})
 370
 371 AC_MSG_CHECKING(whether to build parser debugging code)
 372 AC_ARG_ENABLE(yydebug, [  --enable-yydebug        build parser debugging code])
 373 if test "$enable_yydebug" = "yes"; then
 374         AC_DEFINE(YYDEBUG,1,[Enable parser debugging])
 375 fi
 376 AC_MSG_RESULT(${enable_yydebug-no})
 377
 378 case "$V_PCAP" in
 379
 380 dlpi)
 381         AC_CHECK_HEADERS(sys/bufmod.h sys/dlpi_ext.h)
 382         AC_MSG_CHECKING(for /dev/dlpi device)
 383         if test -c /dev/dlpi ; then
 384                 AC_MSG_RESULT(yes)
 385                 AC_DEFINE(HAVE_DEV_DLPI, 1, [define if you have a /dev/dlpi])
 386         else
 387                 AC_MSG_RESULT(no)
 388                 dir="/dev/dlpi"
 389                 AC_MSG_CHECKING(for $dir directory)
 390                 if test -d $dir ; then
 391                         AC_MSG_RESULT(yes)
 392                         AC_DEFINE_UNQUOTED(PCAP_DEV_PREFIX, "$dir", [/dev/dlpi directory])
 393                 else
 394                         AC_MSG_RESULT(no)
 395                 fi
 396         fi
 397         ;;
 398
 399 linux)
 400         AC_MSG_CHECKING(Linux kernel version)
 401         if test "$cross_compiling" = yes; then
 402                 AC_CACHE_VAL(ac_cv_linux_vers,
 403                     ac_cv_linux_vers=unknown)
 404         else
 405                 AC_CACHE_VAL(ac_cv_linux_vers,
 406                     ac_cv_linux_vers=`uname -r 2>&1 | \
 407                         sed -n -e '$s/.* //' -e '$s/\..*//p'`)
 408         fi
 409         AC_MSG_RESULT($ac_cv_linux_vers)
 410         if test $ac_cv_linux_vers = unknown ; then
 411                 AC_MSG_ERROR(cannot determine linux version when cross-compiling)
 412         fi
 413         if test $ac_cv_linux_vers -lt 2 ; then
 414                 AC_MSG_ERROR(version 2 or higher required; see the INSTALL doc for more info)
 415         fi
 416         AC_LBL_TPACKET_STATS
 417         ;;
 418
 419 dag)
 420         V_DEFS="$V_DEFS -DDAG_ONLY"
 421         ;;
 422
 423 septel)
 424         V_DEFS="$V_DEFS -DSEPTEL_ONLY"
 425         ;;
 426
 427 null)
 428         AC_MSG_WARN(cannot determine packet capture interface)
 429         AC_MSG_WARN((see the INSTALL doc for more info))
 430         ;;
 431
 432 esac
 433
 434 AC_MSG_CHECKING(whether we have /proc/net/dev)
 435 if test -r /proc/net/dev ; then
 436         ac_cv_lbl_proc_net_dev=yes
 437 else
 438         ac_cv_lbl_proc_net_dev=no
 439 fi
 440 if test $ac_cv_lbl_proc_net_dev = yes; then
 441         AC_DEFINE(HAVE_PROC_NET_DEV, 1, [define if you have a /proc/net/dev])
 442 fi
 443 AC_MSG_RESULT($ac_cv_lbl_proc_net_dev)
 444
 445 # Check for Endace DAG card support.
 446 AC_ARG_WITH([dag], [  --with-dag[[=DIR]]        include Endace DAG support ("yes", "no" or DIR; default="yes" on BSD and Linux if present)],
 447 [
 448         if test "$withval" = no
 449         then
 450                 # User doesn't want DAG support.
 451                 want_dag=no
 452         elif test "$withval" = yes
 453         then
 454                 # User wants DAG support but hasn't specified a directory.
 455                 want_dag=yes
 456         else
 457                 # User wants DAG support and has specified a directory, so use the provided value.
 458                 want_dag=yes
 459                 dag_root=$withval
 460         fi
 461 ],[
 462         #
 463         # Use DAG API if present, otherwise don't
 464         #
 465         want_dag=ifpresent
 466 ])
 467
 468 AC_ARG_WITH([dag-includes], [  --with-dag-includes=DIR   Endace DAG include directory],
 469 [
 470         # User wants DAG support and has specified a header directory, so use the provided value.
 471         want_dag=yes
 472         dag_include_dir=$withval
 473 ],[])
 474
 475 AC_ARG_WITH([dag-libraries], [  --with-dag-libraries=DIR  Endace DAG library directory],
 476 [
 477         # User wants DAG support and has specified a library directory, so use the provided value.
 478         want_dag=yes
 479         dag_lib_dir=$withval
 480 ],[])
 481
 482 case "$V_PCAP" in
 483 linux|bpf|dag)
 484         #
 485         # We support the DAG API if we're on Linux or BSD, or if we're
 486         # building a DAG-only libpcap.
 487         #
 488         ;;
 489 *)
 490         #
 491         # If the user explicitly requested DAG, tell them it's not
 492         # supported.
 493         #
 494         # If they expressed no preference, don't include it.
 495         #
 496         if test $want_dag = yes; then
 497                 AC_MSG_ERROR([DAG support is only available with 'linux' 'bpf' and 'dag' packet capture types])
 498         elif test $want_dag = yes; then
 499                 want_dag=no
 500         fi
 501         ;;
 502 esac
 503
 504 ac_cv_lbl_dag_api=no
 505 if test "$want_dag" != no; then
 506
 507         AC_MSG_CHECKING([whether we have DAG API headers])
 508
 509         # If necessary, set default paths for DAG API headers and libraries.
 510         if test -z "$dag_root"; then
 511             dag_root=/usr/local
 512         fi
 513
 514         if test -z "$dag_include_dir"; then
 515                 dag_include_dir="$dag_root/include"
 516         fi
 517
 518         if test -z "$dag_lib_dir"; then
 519             dag_lib_dir="$dag_root/lib"
 520         fi
 521
 522         if test -z "$dag_tools_dir"; then
 523             dag_tools_dir="$dag_root/tools"
 524                 fi
 525
 526         if test -r $dag_include_dir/dagapi.h; then
 527                 ac_cv_lbl_dag_api=yes
 528         fi
 529         AC_MSG_RESULT([$ac_cv_lbl_dag_api ($dag_include_dir)])
 530 fi
 531
 532 if test $ac_cv_lbl_dag_api = yes; then
 533
 534         AC_MSG_CHECKING([dagapi.o])
 535         dagapi_obj=no
 536         if test -r $dag_tools_dir/dagapi.o; then
 537                 # 2.4.x.
 538                 dagapi_obj=$dag_tools_dir/dagapi.o
 539         elif test -r $dag_lib_dir/dagapi.o; then
 540                 # 2.5.x.
 541                 dagapi_obj=$dag_lib_dir/dagapi.o
 542         elif test -r $dag_lib_dir/libdag.a; then
 543                 # 2.5.x.
 544                 ar x $dag_lib_dir/libdag.a dagapi.o
 545                 if test -r ./dagapi.o; then
 546                     dagapi_obj=./dagapi.o
 547                 fi
 548         fi
 549
 550         if test $dagapi_obj = no; then
 551                 AC_MSG_RESULT([no (checked $dag_lib_dir  $dag_tools_dir  $dag_lib_dir/libdag.a)])
 552                         ac_cv_lbl_dag_api=no
 553         else
 554                 AC_MSG_RESULT([yes ($dagapi_obj)])
 555         fi
 556 fi
 557
 558 if test $ac_cv_lbl_dag_api = yes; then
 559
 560         AC_MSG_CHECKING([dagopts.o])
 561         dagopts_obj=no
 562         if test -r $dag_tools_dir/dagopts.o; then
 563                 # 2.4.x.
 564                 dagopts_obj=$dag_tools_dir/dagopts.o
 565         elif test -r $dag_lib_dir/dagopts.o; then
 566                 # 2.5.x.
 567                 dagopts_obj=$dag_lib_dir/dagopts.o
 568         elif test -r $dag_lib_dir/libdag.a; then
 569                 # 2.5.x.
 570                 ar x $dag_lib_dir/libdag.a dagopts.o
 571                 if test -r ./dagopts.o; then
 572                     dagopts_obj=./dagopts.o
 573                 fi
 574         fi
 575
 576         if test $dagopts_obj = no; then
 577                 AC_MSG_RESULT([no (checked $dag_lib_dir  $dag_tools_dir  $dag_lib_dir/libdag.a)])
 578                 ac_cv_lbl_dag_api=no
 579         else
 580                 AC_MSG_RESULT([yes ($dagopts_obj)])
 581         fi
 582 fi
 583
 584 if test $ac_cv_lbl_dag_api = yes; then
 585         # Under 2.5.x only we need to add dagreg.o.
 586         if test -r $dag_include_dir/dagreg.h; then
 587                 AC_MSG_CHECKING([dagreg.o])
 588                 dagreg_obj=no
 589                 if test -r $dag_lib_dir/dagreg.o; then
 590                         # Object file is ready and waiting.
 591                         dagreg_obj=$dag_lib_dir/dagreg.o
 592                 elif test -r $dag_lib_dir/libdag.a; then
 593                         # Extract from libdag.a.
 594                         ar x $dag_lib_dir/libdag.a dagreg.o
 595                         if test -r ./dagreg.o; then
 596                                 dagreg_obj=./dagreg.o
 597                         fi
 598                 fi
 599
 600                 if test $dagreg_obj = no; then
 601                         AC_MSG_RESULT([no (checked $dag_lib_dir  $dag_lib_dir/libdag.a)])
 602                         ac_cv_lbl_dag_api=no
 603                 else
 604                         AC_MSG_RESULT([yes ($dagreg_obj)])
 605                 fi
 606         fi
 607 fi
 608
 609 if test $ac_cv_lbl_dag_api = yes; then
 610         V_INCLS="$V_INCLS -I$dag_include_dir"
 611         V_LIBS="$V_LIBS $dagapi_obj $dagopts_obj $dagreg_obj"
 612         if test $V_PCAP != dag ; then
 613                  SSRC="pcap-dag.c"
 614         fi
 615
 616         # See if we can find a general version string.
 617         # Don't need to save and restore LIBS to prevent -ldag being
 618         # included if there's a found-action (arg 3).
 619         saved_ldflags=$LDFLAGS
 620         LDFLAGS="-L$dag_lib_dir"
 621         AC_CHECK_LIB([dag], [dag_attach_stream], [dag_version="2.5.x"], [dag_version="2.4.x"])
 622         AC_CHECK_LIB([dag],[dag_get_erf_types], [
 623                 AC_DEFINE(HAVE_DAG_GET_ERF_TYPES, 1, [define if you have dag_get_erf_types()])]
 624         )
 625         LDFLAGS=$saved_ldflags
 626
 627         if test "$dag_version" = 2.5.x; then
 628                 AC_DEFINE(HAVE_DAG_STREAMS_API, 1, [define if you have streams capable DAG API])
 629         fi
 630
 631         # See if we can find a specific version string.
 632         AC_MSG_CHECKING([the DAG API version])
 633         if test -r "$dag_root/VERSION"; then
 634                 dag_version="`cat $dag_root/VERSION`"
 635         fi
 636         AC_MSG_RESULT([$dag_version])
 637         AC_DEFINE(HAVE_DAG_API, 1, [define if you have the DAG API])
 638 fi
 639
 640 if test $ac_cv_lbl_dag_api = no; then
 641         if test "$want_dag" = yes; then
 642                 # User wanted DAG support but we couldn't find it.
 643                 AC_MSG_ERROR([DAG API requested, but not found at $dag_root: use --without-dag])
 644         fi
 645
 646         if test "$V_PCAP" = dag; then
 647                 # User requested "dag" capture type but the DAG API wasn't
 648                 # found.
 649                 AC_MSG_ERROR([Specifying the capture type as "dag" requires the DAG API to be present; use the --with-dag options to specify the location. (Try "./configure --help" for more information.)])
 650         fi
 651 fi
 652
 653 AC_ARG_WITH(septel, [  --with-septel[[=DIR]]     include Septel support (located in directory DIR, if supplied).  [default=yes, on Linux, if present]],
 654 [
 655         if test "$withval" = no
 656         then
 657                 want_septel=no
 658         elif test "$withval" = yes
 659         then
 660                 want_septel=yes
 661                 septel_root=
 662         else
 663                 want_septel=yes
 664                 septel_root=$withval
 665         fi
 666 ],[
 667         #
 668         # Use Septel API if present, otherwise don't
 669         #
 670         want_septel=ifpresent
 671         septel_root=./../septel
 672 ])
 673 ac_cv_lbl_septel_api=no
 674 case "$V_PCAP" in
 675 linux|septel)
 676         #
 677         # We support the Septel API if we're on Linux, or if we're building
 678         # a Septel-only libpcap.
 679         #
 680         ;;
 681 *)
 682         #
 683         # If the user explicitly requested Septel, tell them it's not
 684         # supported.
 685         #
 686         # If they expressed no preference, don't include it.
 687         #
 688         if test $want_septel = yes; then
 689                 AC_MSG_ERROR(Septel support only available with 'linux' and 'septel' packet capture types)
 690         elif test $want_septel = yes; then
 691                 want_septel=no
 692         fi
 693         ;;
 694 esac
 695
 696 if test "$with_septel" != no; then
 697         AC_MSG_CHECKING(whether we have Septel API)
 698
 699         if test -z "$septel_root"; then
 700                 septel_root=$srcdir/../septel
 701
 702         fi
 703
 704         septel_tools_dir="$septel_root"
 705         septel_include_dir="$septel_root/INC"
 706         DEF="-DHAVE_SEPTEL_API"
 707
 708         ac_cv_lbl_septel_api=no
 709         if test -r "$septel_include_dir/msg.h"; then
 710                 V_INCLS="$V_INCLS -I$septel_include_dir"
 711                 V_DEFS="$V_DEFS $DEF"
 712                 V_LIBS="$V_LIBS $septel_tools_dir/asciibin.o $septel_tools_dir/bit2byte.o $septel_tools_dir/confirm.o $septel_tools_dir/fmtmsg.o $septel_tools_dir/gct_unix.o $septel_tools_dir/hqueue.o $septel_tools_dir/ident.o $septel_tools_dir/mem.o $septel_tools_dir/pack.o $septel_tools_dir/parse.o $septel_tools_dir/pool.o $septel_tools_dir/sdlsig.o $septel_tools_dir/strtonum.o $septel_tools_dir/timer.o $septel_tools_dir/trace.o "
 713
 714                 if test "$V_PCAP" != septel ; then
 715                          SSRC="pcap-septel.c"
 716
 717                 fi
 718                 ac_cv_lbl_septel_api=yes
 719         fi
 720
 721         AC_MSG_RESULT($ac_cv_lbl_septel_api)
 722         if test $ac_cv_lbl_septel_api = no; then
 723                 if test "$want_septel" = yes; then
 724                         AC_MSG_ERROR(Septel API not found under directory $septel_root; use --without-septel)
 725                 fi
 726         else
 727                 AC_DEFINE(HAVE_SEPTEL_API, 1, [define if you have a Septel API])
 728         fi
 729 fi
 730
 731 if test "$V_PCAP" = septel -a "$ac_cv_lbl_septel_api" = no; then
 732         AC_MSG_ERROR(Specifying the capture type as 'septel' requires the Septel API to be present; use --with-septel=DIR)
 733 fi
 734
 735
 736 AC_LBL_LEX_AND_YACC(V_LEX, V_YACC, pcap_)
 737 if test "$V_LEX" = lex ; then
 738 # Some versions of lex can't handle the definitions section of scanner.l .
 739 # Try lexing it and complain if it can't deal.
 740         AC_CACHE_CHECK([for capable lex], tcpdump_cv_capable_lex,
 741                 if lex -t scanner.l > /dev/null 2>&1; then
 742                         tcpdump_cv_capable_lex=yes
 743                 else
 744                         tcpdump_cv_capable_lex=insufficient
 745                 fi)
 746         if test $tcpdump_cv_capable_lex = insufficient ; then
 747                 AC_MSG_ERROR([Your operating system's lex is insufficient to compile
 748  libpcap.  flex is a lex replacement that has many advantages, including
 749  being able to compile libpcap.  For more information, see
 750  http://www.gnu.org/software/flex/flex.html .])
 751         fi
 752 fi
 753
 754 DYEXT="so"
 755 case "$host_os" in
 756
 757 aix*)
 758         dnl Workaround to enable certain features
 759         AC_DEFINE(_SUN,1,[define on AIX to get certain functions])
 760         ;;
 761
 762 hpux9*)
 763         AC_DEFINE(HAVE_HPUX9,1,[on HP-UX 9.x])
 764         ;;
 765
 766 hpux10.0*)
 767         ;;
 768
 769 hpux10.1*)
 770         ;;
 771
 772 hpux*)
 773         dnl HPUX 10.20 and above is similar to HPUX 9, but
 774         dnl not the same....
 775         dnl
 776         dnl XXX - DYEXT should be set to "sl" if this is building
 777         dnl for 32-bit PA-RISC, but should be left as "so" for
 778         dnl 64-bit PA-RISC or, I suspect, IA-64.
 779         AC_DEFINE(HAVE_HPUX10_20_OR_LATER,1,[on HP-UX 10.20 or later])
 780         ;;
 781
 782 sinix*)
 783         AC_MSG_CHECKING(if SINIX compiler defines sinix)
 784         AC_CACHE_VAL(ac_cv_cc_sinix_defined,
 785                 AC_TRY_COMPILE(
 786                     [],
 787                     [int i = sinix;],
 788                     ac_cv_cc_sinix_defined=yes,
 789                     ac_cv_cc_sinix_defined=no))
 790             AC_MSG_RESULT($ac_cv_cc_sinix_defined)
 791             if test $ac_cv_cc_sinix_defined = no ; then
 792                     AC_DEFINE(sinix,1,[on sinix])
 793             fi
 794         ;;
 795
 796 solaris*)
 797         AC_DEFINE(HAVE_SOLARIS,1,[On solaris])
 798         ;;
 799
 800 darwin*)
 801         DYEXT="dylib"
 802         V_CCOPT="$V_CCOPT -fno-common"
 803         ;;
 804 esac
 805
 806 AC_PROG_RANLIB
 807
 808 AC_LBL_DEVEL(V_CCOPT)
 809
 810 AC_LBL_SOCKADDR_SA_LEN
 811
 812 AC_LBL_SOCKADDR_STORAGE
 813
 814 AC_LBL_HP_PPA_INFO_T_DL_MODULE_ID_1
 815
 816 AC_LBL_UNALIGNED_ACCESS
 817
 818 #
 819 # Makefile.in includes rules to generate version.h, so we assume
 820 # that it will be generated if autoconf is used.
 821 #
 822 AC_DEFINE(HAVE_VERSION_H, 1, [define if version.h is generated in the build procedure])
 823
 824 rm -f net
 825 ln -s ${srcdir}/bpf/net net
 826
 827 AC_SUBST(V_CCOPT)
 828 AC_SUBST(V_DEFS)
 829 AC_SUBST(V_INCLS)
 830 AC_SUBST(V_LIBS)
 831 AC_SUBST(V_LEX)
 832 AC_SUBST(V_PCAP)
 833 AC_SUBST(V_FINDALLDEVS)
 834 # HAVE_REMOTE
 835 AC_SUBST(V_HAVE_REMOTE)
 836 AC_SUBST(V_REMOTE_FILES)
 837 # END HAVE_REMOTE
 838 AC_SUBST(V_RANLIB)
 839 AC_SUBST(V_YACC)
 840 AC_SUBST(SSRC)
 841 AC_SUBST(DYEXT)
 842
 843 AC_PROG_INSTALL
 844
 845 AC_CONFIG_HEADER(config.h)
 846
 847 AC_OUTPUT(Makefile)
 848
 849 if test -f .devel ; then
 850         make depend
 851 fi
 852 exit 0