configure.ac

   1 dnl Configure script for NBD system
   2 dnl (c) 1998 Martin Mares <mj@ucw.cz>, (c) 2000 Pavel Machek <pavel@ucw.cz>,
   3 dnl (c) 2003-2006 Wouter Verhelst <wouter@debian.org>
   4 AC_INIT([nbd],
   5   m4_esyscmd(support/genver.sh | tr -d '\n'),
   6   [nbd@other.debian.org],,
   7   [http://nbd.sourceforge.net/])
   8 m4_define([serial_tests], [
   9   m4_esyscmd([automake --version |
  10               head -1 |
  11               awk '{split ($NF,a,"."); if (a[1] == 1 && a[2] >= 12) { print "serial-tests" }}'
  12   ])
  13 ])
  14 AM_INIT_AUTOMAKE(foreign dist-xz serial_tests subdir-objects)
  15 AM_MAINTAINER_MODE([enable])
  16 AC_CONFIG_MACRO_DIR([support])
  17 LT_INIT
  18
  19 AC_ARG_ENABLE(
  20   lfs,
  21   AC_HELP_STRING(--disable-lfs,Disable Large File Support (default on)),
  22   [
  23     if test "x$enableval" = "xyes" ; then
  24       NBD_LFS=1
  25     else
  26       NBD_LFS=0
  27     fi
  28   ],
  29   [NBD_LFS=1]
  30 )
  31 AC_MSG_CHECKING([whether Large File Support should be enabled])
  32 if test $NBD_LFS -eq 1; then
  33   AC_DEFINE(NBD_LFS,1, [Define to 1 if Large File Support should be enabled])
  34   AC_MSG_RESULT([yes])
  35 else
  36   AC_DEFINE(NBD_LFS,0)
  37   AC_MSG_RESULT([no])
  38 fi
  39
  40 AC_ARG_ENABLE(
  41   syslog,
  42   AC_HELP_STRING(--enable-syslog,Enable Syslog logging),
  43   [
  44     if test "x$enableval" = "xyes" ; then
  45       ISSERVER=1
  46     else
  47       ISSERVER=0
  48     fi
  49   ],
  50   [ISSERVER=0]
  51 )
  52
  53 AC_MSG_CHECKING([whether syslog logging is requested])
  54 if test $ISSERVER -eq 1; then
  55   AC_DEFINE(ISSERVER,1, [Define to 1 if you want nbd-server to log through syslog])
  56   AC_MSG_RESULT([yes])
  57 else
  58   AC_MSG_RESULT([no])
  59 fi
  60
  61 AC_ARG_ENABLE(
  62   debug,
  63   AC_HELP_STRING(--enable-debug,Build a debugging version of the server),
  64   [
  65     if test "x$enableval" = "xyes"; then
  66       DODBG=1
  67     else
  68       DODBG=0
  69     fi
  70   ],
  71   [DODBG=0]
  72 )
  73
  74 AC_MSG_CHECKING([whether a debugging version is requested])
  75 if test $DODBG -eq 1; then
  76   AC_MSG_RESULT([yes])
  77   if test $ISSERVER -eq 1; then
  78     AC_MSG_ERROR([You requested both syslog logging and a debugging version of the server. Bad idea!])
  79   fi
  80   AC_DEFINE(DODBG,1,[Define if you want a debugging version of nbd-server (lots of copious output)])
  81   AC_DEFINE(NOFORK,1,[Define if you do not want the nbd-server to fork()])
  82 else
  83   AC_MSG_RESULT([no])
  84 fi
  85
  86 AC_ARG_ENABLE(
  87   sdp,
  88   AC_HELP_STRING(--enable-sdp,Build a version of nbd-server with support for the Socket Direct Protocol (SDP). Requires you to build and install a kernel with the InfiniBand patches (default disabled)),
  89   [
  90     if test "x$enableval" = "xyes"; then
  91       AC_DEFINE(WITH_SDP, 1, [Define to 1 if you have and want support for the Socket Direct Protocol])
  92     fi
  93   ]
  94 )
  95
  96 AC_ARG_ENABLE(
  97   [gznbd],
  98   [AS_HELP_STRING([--enable-gznbd],[Build gznbd too (nbd server with on-the-fly decompression of images. NOTE: no support for newstyle protocol.)])],
  99   [
 100     AS_IF(
 101       [test "x$enableval" = "xyes"],
 102       [ENABLE_GZNBD=yes],
 103       [ENABLE_GZNBD=no]
 104     )
 105   ],
 106   [ENABLE_GZNBD=no]
 107 )
 108
 109 AC_PROG_CC_C99
 110 AC_PROG_CPP
 111 AC_PROG_INSTALL
 112 PKG_PROG_PKG_CONFIG
 113 AC_CANONICAL_HOST
 114 AC_C_BIGENDIAN
 115 AC_C_INLINE
 116 AC_C_CONST
 117 AC_CHECK_SIZEOF(unsigned short int)
 118 AC_CHECK_SIZEOF(unsigned int)
 119 AC_CHECK_SIZEOF(unsigned long int)
 120 AC_CHECK_SIZEOF(unsigned long long int)
 121 AC_STRUCT_DIRENT_D_TYPE
 122 AC_CHECK_FUNCS([llseek alarm gethostbyname inet_ntoa memset socket strerror strstr mkstemp fdatasync])
 123 HAVE_FL_PH=no
 124
 125 AC_CHECK_FUNC(fallocate,
 126   [
 127     AC_CHECK_HEADERS([linux/falloc.h])
 128     if test "x$ac_cv_header_linux_falloc_h" = "xyes"
 129     then
 130       AC_CHECK_DECL(FALLOC_FL_PUNCH_HOLE, [HAVE_FL_PH=yes], [HAVE_FL_PH=no], [[#include <linux/falloc.h>]])
 131     fi
 132   ]
 133 )
 134
 135 AC_MSG_CHECKING([for FALLOC_FL_PUNCH_HOLE support])
 136 if test "x$HAVE_FL_PH" = "xyes"
 137 then
 138         AC_DEFINE(HAVE_FALLOC_PH, 1, [Define to 1 if you have FALLOC_FL_PUNCH_HOLE])
 139         AC_MSG_RESULT([yes])
 140 else
 141         AC_DEFINE(HAVE_FALLOC_PH, 0, [Define to 1 if you have FALLOC_FL_PUNCH_HOLE])
 142         AC_MSG_RESULT([no])
 143 fi
 144
 145 AC_CHECK_FUNC(splice, [HAVE_SPLICE=yes], [HAVE_SPLICE=no])
 146 if test "$HAVE_SPLICE" = "yes"
 147 then
 148         HAVE_SETPIPE_SZ=no
 149         AC_CHECK_DECL(F_SETPIPE_SZ, [HAVE_SETPIPE_SZ=yes],
 150                 [
 151                         unset ac_cv_have_decl_F_SETPIPE_SZ
 152                         AC_CHECK_HEADERS([linux/fcntl.h])
 153                         if test "$ac_cv_header_linux_fcntl_h" = "yes"
 154                         then
 155                                 AC_CHECK_DECL(F_SETPIPE_SZ, [HAVE_SETPIPE_SZ=define], [HAVE_SETPIPE_SZ=no], [[#include <linux/fcntl.h>]])
 156                         fi
 157                 ],
 158                 [[
 159                         #define _GNU_SOURCE
 160                         #include <fcntl.h>
 161                 ]]
 162         )
 163         AC_MSG_CHECKING([for F_SETPIPE_SZ support])
 164         case $HAVE_SETPIPE_SZ in
 165                 yes)
 166                         AC_DEFINE(HAVE_SPLICE, 1, [Define to 1 if we have splice support])
 167                         AC_MSG_RESULT([yes])
 168                 ;;
 169                 define)
 170                         AC_DEFINE(HAVE_SPLICE, 1, [Define to 1 if we have splice support])
 171                         AC_DEFINE(F_SETPIPE_SZ, 1031, [Define to 1031 if we have kernel support but no userspace support])
 172                         AC_MSG_RESULT([yes])
 173                 ;;
 174                 no)
 175                         AC_MSG_RESULT([missing, disabling splice support])
 176                 ;;
 177         esac
 178 fi
 179
 180 m4_ifndef([PKG_CHECK_MODULES], [m4_fatal([Missing pkg-config M4 macros. Please ensure that pkg-config is installed.])])
 181
 182 dnl AC_MSG_CHECKING([where to puth systemd unit files])
 183 dnl AC_ARG_WITH(
 184 dnl   systemd,
 185 dnl   AS_HELP_STRING([--with-systemd=loc|pkgconfig],[Install systemd files in loc; if passing pkgconfig, use pkg-config to detect the correct location and install there.])
 186 dnl   [
 187 dnl     if test "x$enableval" = "xyes"; then
 188 dnl       ENABLE_SYSTEMD=yes
 189 dnl     else
 190 dnl       ENABLE_SYSTEMD=no
 191 dnl     fi
 192 dnl   ],[]
 193 dnl )
 194 dnl
 195 dnl if test "x$ENABLE_SYSTEMD" != "xno"; then
 196 dnl     PKG_CHECK_VAR([SYSTEMDUNIT],[systemd],systemdsystemunitdir],[AC_SUBST([SYSTEMDLOC], [$SYSTEMDUNIT])])
 197 dnl fi
 198 dnl AM_CONDITIONAL(SYSTEMD, [test ! -z "$SYSTEMDUNIT"])
 199 dnl if test ! -z $SYSTEMDUNIT; then
 200 dnl     AC_MSG_RESULT([$SYSTEMDUNIT])
 201 dnl else
 202 dnl     case $ENABLE_SYSTEMD in
 203 dnl             no)
 204 dnl                     AC_MSG_RESULT([disabled])
 205 dnl             ;;
 206 dnl             yes)
 207 dnl                     AC_MSG_ERROR([systemd not found])
 208 dnl             ;;
 209 dnl             *)
 210 dnl                     AC_MSG_RESULT([not found])
 211 dnl             ;;
 212 dnl     esac
 213 dnl fi
 214
 215 PKG_CHECK_MODULES(GnuTLS, [gnutls >= 2.12.0],[HAVE_GNUTLS=1],[HAVE_GNUTLS=0])
 216 if test x$HAVE_GNUTLS = x1; then
 217         AC_DEFINE(HAVE_GNUTLS, 1, [Define to 1 if you have a GnuTLS version of 2.12 or above])
 218 else
 219         AC_DEFINE(HAVE_GNUTLS, 0)
 220 fi
 221 AM_CONDITIONAL([GNUTLS], [test "x$HAVE_GNUTLS" = "x1"])
 222
 223 AC_CHECK_HEADERS([winioctl.h], [], [],
 224 [#include <io.h>
 225 #include <windef.h>
 226 #include <winbase.h>
 227 ])
 228 HAVE_FSCTL_SET_ZERO_DATA=no
 229 if test "x$ac_cv_header_winioctl_h" = "xyes"
 230 then
 231         AC_CHECK_DECL(FSCTL_SET_ZERO_DATA, [HAVE_FSCTL_SET_ZERO_DATA=yes], [HAVE_FSCTL_SET_ZERO_DATA=no],
 232         [#include <windef.h>
 233         #include <winbase.h>
 234         #include <winioctl.h>
 235         ])
 236 fi
 237 if test "x$HAVE_FSCTL_SET_ZERO_DATA" = "xyes"
 238 then
 239         AC_DEFINE(HAVE_FSCTL_SET_ZERO_DATA, 1, [Define to 1 if you have FSCTL_SET_ZERO_DATA])
 240 else
 241         AC_DEFINE(HAVE_FSCTL_SET_ZERO_DATA, 0, [Define to 1 if you have FSCTL_SET_ZERO_DATA])
 242 fi
 243
 244 AC_CHECK_FUNC([sync_file_range],
 245         [AC_DEFINE([HAVE_SYNC_FILE_RANGE], [sync_file_range(2) is not supported], [sync_file_range(2) is supported])],
 246         [])
 247 AC_FUNC_FORK
 248 AC_FUNC_SETVBUF_REVERSED
 249 AC_MSG_CHECKING(whether client should be built)
 250 case $host_os in
 251         linux*) NBD_CLIENT_NAME="nbd-client"
 252                 AC_MSG_RESULT(yes)
 253                 ;;
 254         *)      NBD_CLIENT_NAME=""
 255                 AC_MSG_RESULT(no)
 256                 ;;
 257 esac
 258 AM_CONDITIONAL(CLIENT, [test ! -z "$NBD_CLIENT_NAME"])
 259 AC_SEARCH_LIBS(bind, socket,, AC_MSG_ERROR([Could not find an implementation of the bind() system call]))
 260 AC_SEARCH_LIBS(inet_ntoa, nsl,, AC_MSG_ERROR([Could not find an implementation of the inet_ntoa() system call]))
 261 AC_SEARCH_LIBS(daemon, resolv,, AC_MSG_ERROR([Could not find an implementation of the daemon() system call]))
 262 AC_CHECK_HEADERS([sys/mount.h],,,
 263 [[#include <sys/param.h>
 264 ]])
 265 AC_CHECK_HEADERS([arpa/inet.h fcntl.h netdb.h netinet/in.h sys/ioctl.h sys/socket.h syslog.h linux/types.h sys/dirent.h sys/uio.h])
 266 PKG_CHECK_MODULES(GLIB, [glib-2.0 >= 2.26.0 gthread-2.0 >= 2.26.0], [HAVE_GLIB=yes], AC_MSG_ERROR([Missing glib]))
 267
 268 my_save_cflags="$CFLAGS"
 269 CFLAGS="-Wdeprecated-declarations -Werror $GLIB_CFLAGS"
 270 AC_MSG_CHECKING([if we are using an old glib 2.0 library])
 271 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 272         [[#include <glib.h>]],
 273         [[g_thread_init(NULL);]])],
 274         [
 275                 AC_MSG_RESULT(yes)
 276                 AC_DEFINE(HAVE_OLD_GLIB, 1, [Define to 1 if you have an old glib library])
 277         ],
 278         [
 279                 AC_MSG_RESULT(no)
 280                 AC_DEFINE(HAVE_OLD_GLIB, 0, [Define to 1 if you have an old glib library])
 281         ]
 282 )
 283 CFLAGS="$my_save_cflags"
 284
 285 AC_MSG_CHECKING([whether _BSD_SOURCE needs to be defined for DT_* macros])
 286 AC_PREPROC_IFELSE(
 287         [AC_LANG_PROGRAM([[#include <dirent.h>]],
 288                          [[#ifndef DT_UNKNOWN
 289 #error nope
 290 #endif]])],
 291         [AC_MSG_RESULT([no]); NEED_BSD_SOURCE=0],
 292         [AC_MSG_RESULT([yes]); NEED_BSD_SOURCE=1])
 293 AC_DEFINE([NEED_BSD_SOURCE], $NEED_BSD_SOURCE, [Define to 1 if _BSD_SOURCE needs to be defined before certain inclusions])
 294
 295 PKG_CHECK_MODULES(LIBNL3, libnl-genl-3.0 >= 3.1, [have_libnl3=yes], [have_libnl3=no])
 296 if test "${have_libnl3}" = "yes"
 297 then
 298         AC_DEFINE(HAVE_NETLINK, 1, [Define to 1 if we have netlink support])
 299         CFLAGS+=" $LIBNL3_CFLAGS"
 300         LIBS+=" $LIBNL3_LIBS"
 301 else
 302         AC_DEFINE(HAVE_NETLINK, 0, [Define to 1 if we have netlink support])
 303 fi
 304
 305 AC_HEADER_SYS_WAIT
 306 AC_TYPE_OFF_T
 307 AC_TYPE_PID_T
 308 AM_CPPFLAGS=$AM_CPPFLAGS" -DSYSCONFDIR='\"$sysconfdir\"'"
 309 AC_SUBST(AM_CPPFLAGS)
 310 AM_CONDITIONAL(GZNBD, [test "x$ENABLE_GZNBD" = "xyes"])
 311 AC_CONFIG_HEADERS([config.h])
 312 AC_CONFIG_FILES([Makefile
 313                  doc/Doxyfile
 314                  doc/Makefile
 315                  man/Makefile
 316                  gznbd/Makefile
 317                  tests/Makefile
 318                  tests/code/Makefile
 319                  tests/run/Makefile
 320                  man/nbd-client.8.sh
 321                  man/nbd-server.5.sh
 322                  man/nbd-server.1.sh
 323                  man/nbd-trdump.1.sh
 324                  man/nbdtab.5.sh
 325                  systemd/Makefile
 326                  systemd/nbd@.service.sh
 327                 ])
 328 AC_OUTPUT
 329