configure.ac

   1 dnl Configure script for NBD system
   2 dnl (c) 1998 Martin Mares <mj@ucw.cz>, (c) 2000 Pavel Machek <pavel@ucw.cz>,
   3 dnl (c) 2003-2006 Wouter Verhelst <wouter@debian.org>
   4 AC_INIT([nbd],
   5   m4_esyscmd(support/genver.sh | tr -d '\n'),
   6   [wouter@debian.org],,
   7   [http://nbd.sourceforge.net/])
   8 m4_define([serial_tests], [
   9   m4_esyscmd([automake --version |
  10               head -1 |
  11               awk '{split ($NF,a,"."); if (a[1] == 1 && a[2] >= 12) { print "serial-tests" }}'
  12   ])
  13 ])
  14 AM_INIT_AUTOMAKE(foreign dist-xz serial_tests subdir-objects)
  15 AM_MAINTAINER_MODE([enable])
  16 AC_CONFIG_MACRO_DIR([support])
  17 LT_INIT
  18
  19 AC_ARG_ENABLE(
  20   lfs,
  21   AC_HELP_STRING(--disable-lfs,Disable Large File Support (default on)),
  22   [
  23     if test "x$enableval" = "xyes" ; then
  24       NBD_LFS=1
  25     else
  26       NBD_LFS=0
  27     fi
  28   ],
  29   [NBD_LFS=1]
  30 )
  31 AC_MSG_CHECKING([whether Large File Support should be enabled])
  32 if test $NBD_LFS -eq 1; then
  33   AC_DEFINE(NBD_LFS,1, [Define to 1 if Large File Support should be enabled])
  34   AC_MSG_RESULT([yes])
  35 else
  36   AC_DEFINE(NBD_LFS,0)
  37   AC_MSG_RESULT([no])
  38 fi
  39
  40 AC_ARG_ENABLE(
  41   syslog,
  42   AC_HELP_STRING(--enable-syslog,Enable Syslog logging),
  43   [
  44     if test "x$enableval" = "xyes" ; then
  45       ISSERVER=1
  46     else
  47       ISSERVER=0
  48     fi
  49   ],
  50   [ISSERVER=0]
  51 )
  52
  53 AC_MSG_CHECKING([whether syslog logging is requested])
  54 if test $ISSERVER -eq 1; then
  55   AC_DEFINE(ISSERVER,1, [Define to 1 if you want nbd-server to log through syslog])
  56   AC_MSG_RESULT([yes])
  57 else
  58   AC_MSG_RESULT([no])
  59 fi
  60
  61 AC_ARG_ENABLE(
  62   debug,
  63   AC_HELP_STRING(--enable-debug,Build a debugging version of the server),
  64   [
  65     if test "x$enableval" = "xyes"; then
  66       DODBG=1
  67     else
  68       DODBG=0
  69     fi
  70   ],
  71   [DODBG=0]
  72 )
  73
  74 AC_MSG_CHECKING([whether a debugging version is requested])
  75 if test $DODBG -eq 1; then
  76   AC_MSG_RESULT([yes])
  77   if test $ISSERVER -eq 1; then
  78     AC_MSG_ERROR([You requested both syslog logging and a debugging version of the server. Bad idea!])
  79   fi
  80   AC_DEFINE(DODBG,1,[Define if you want a debugging version of nbd-server (lots of copious output)])
  81   AC_DEFINE(NOFORK,1,[Define if you don't want the nbd-server to fork()])
  82 else
  83   AC_MSG_RESULT([no])
  84 fi
  85
  86 AC_ARG_ENABLE(
  87   sdp,
  88   AC_HELP_STRING(--enable-sdp,Build a version of nbd-server with support for the Socket Direct Protocol (SDP). Requires you to build and install a kernel with the InfiniBand patches (default disabled)),
  89   [
  90     if test "x$enableval" = "xyes"; then
  91       AC_DEFINE(WITH_SDP, 1, [Define to 1 if you have and want support for the Socket Direct Protocol])
  92     fi
  93   ]
  94 )
  95
  96 AC_ARG_ENABLE(
  97   [gznbd],
  98   [AS_HELP_STRING([--enable-gznbd],[Build gznbd too (nbd server with on-the-fly decompression of images. NOTE: no support for newstyle protocol.)])],
  99   [
 100     AS_IF(
 101       [test "x$enableval" = "xyes"],
 102       [ENABLE_GZNBD=yes],
 103       [ENABLE_GZNBD=no]
 104     )
 105   ],
 106   [ENABLE_GZNBD=no]
 107 )
 108
 109 AC_PROG_CC_C99
 110 AC_PROG_CPP
 111 AC_PROG_INSTALL
 112 PKG_PROG_PKG_CONFIG
 113 AC_CANONICAL_HOST
 114 AC_C_BIGENDIAN
 115 AC_C_INLINE
 116 AC_C_CONST
 117 AC_CHECK_SIZEOF(unsigned short int)
 118 AC_CHECK_SIZEOF(unsigned int)
 119 AC_CHECK_SIZEOF(unsigned long int)
 120 AC_CHECK_SIZEOF(unsigned long long int)
 121 AC_STRUCT_DIRENT_D_TYPE
 122 AC_CHECK_FUNCS([llseek alarm gethostbyname inet_ntoa memset socket strerror strstr mkstemp fdatasync])
 123 HAVE_FL_PH=no
 124
 125 AC_CHECK_FUNC(fallocate,
 126   [
 127     AC_CHECK_HEADERS([linux/falloc.h])
 128     if test "x$ac_cv_header_linux_falloc_h" = "xyes"
 129     then
 130       AC_CHECK_DECL(FALLOC_FL_PUNCH_HOLE, [HAVE_FL_PH=yes], [HAVE_FL_PH=no], [[#include <linux/falloc.h>]])
 131     fi
 132   ]
 133 )
 134
 135 AC_MSG_CHECKING([for FALLOC_FL_PUNCH_HOLE support])
 136 if test "x$HAVE_FL_PH" = "xyes"
 137 then
 138         AC_DEFINE(HAVE_FALLOC_PH, 1, [Define to 1 if you have FALLOC_FL_PUNCH_HOLE])
 139         AC_MSG_RESULT([yes])
 140 else
 141         AC_DEFINE(HAVE_FALLOC_PH, 0, [Define to 1 if you have FALLOC_FL_PUNCH_HOLE])
 142         AC_MSG_RESULT([no])
 143 fi
 144
 145 AC_CHECK_FUNC(splice, [HAVE_SPLICE=yes], [HAVE_SPLICE=no])
 146 if test "$HAVE_SPLICE" = "yes"
 147 then
 148         HAVE_SETPIPE_SZ=no
 149         AC_CHECK_DECL(F_SETPIPE_SZ, [HAVE_SETPIPE_SZ=yes],
 150                 [
 151                         unset ac_cv_have_decl_F_SETPIPE_SZ
 152                         AC_CHECK_HEADERS([linux/fcntl.h])
 153                         if test "$ac_cv_header_linux_fcntl_h" = "yes"
 154                         then
 155                                 AC_CHECK_DECL(F_SETPIPE_SZ, [HAVE_SETPIPE_SZ=define], [HAVE_SETPIPE_SZ=no], [[#include <linux/fcntl.h>]])
 156                         fi
 157                 ],
 158                 [[
 159                         #define _GNU_SOURCE
 160                         #include <fcntl.h>
 161                 ]]
 162         )
 163         AC_MSG_CHECKING([for F_SETPIPE_SZ support])
 164         case $HAVE_SETPIPE_SZ in
 165                 yes)
 166                         AC_DEFINE(HAVE_SPLICE, 1, [Define to 1 if we have splice support])
 167                         AC_MSG_RESULT([yes])
 168                 ;;
 169                 define)
 170                         AC_DEFINE(HAVE_SPLICE, 1, [Define to 1 if we have splice support])
 171                         AC_DEFINE(F_SETPIPE_SZ, 1031, [Define to 1031 if we have kernel support but no userspace support])
 172                         AC_MSG_RESULT([yes])
 173                 ;;
 174                 no)
 175                         AC_MSG_RESULT([missing, disabling splice support])
 176                 ;;
 177         esac
 178 fi
 179
 180 dnl AC_MSG_CHECKING([where to puth systemd unit files])
 181 dnl AC_ARG_WITH(
 182 dnl   systemd,
 183 dnl   AS_HELP_STRING([--with-systemd=loc|pkgconfig],[Install systemd files in loc; if passing pkgconfig, use pkg-config to detect the correct location and install there.])
 184 dnl   [
 185 dnl     if test "x$enableval" = "xyes"; then
 186 dnl       ENABLE_SYSTEMD=yes
 187 dnl     else
 188 dnl       ENABLE_SYSTEMD=no
 189 dnl     fi
 190 dnl   ],[]
 191 dnl )
 192 dnl
 193 dnl if test "x$ENABLE_SYSTEMD" != "xno"; then
 194 dnl     PKG_CHECK_VAR([SYSTEMDUNIT],[systemd],systemdsystemunitdir],[AC_SUBST([SYSTEMDLOC], [$SYSTEMDUNIT])])
 195 dnl fi
 196 dnl AM_CONDITIONAL(SYSTEMD, [test ! -z "$SYSTEMDUNIT"])
 197 dnl if test ! -z $SYSTEMDUNIT; then
 198 dnl     AC_MSG_RESULT([$SYSTEMDUNIT])
 199 dnl else
 200 dnl     case $ENABLE_SYSTEMD in
 201 dnl             no)
 202 dnl                     AC_MSG_RESULT([disabled])
 203 dnl             ;;
 204 dnl             yes)
 205 dnl                     AC_MSG_ERROR([systemd not found])
 206 dnl             ;;
 207 dnl             *)
 208 dnl                     AC_MSG_RESULT([not found])
 209 dnl             ;;
 210 dnl     esac
 211 dnl fi
 212
 213 PKG_CHECK_MODULES(GnuTLS, [gnutls >= 2.12.0],[HAVE_GNUTLS=1],[HAVE_GNUTLS=0])
 214 if test x$HAVE_GNUTLS = x1; then
 215         AC_DEFINE(HAVE_GNUTLS, 1, [Define to 1 if you have a GnuTLS version of 2.12 or above])
 216 else
 217         AC_DEFINE(HAVE_GNUTLS, 0)
 218 fi
 219 AM_CONDITIONAL([GNUTLS], [test "x$HAVE_GNUTLS" = "x1"])
 220
 221 AC_CHECK_HEADERS([winioctl.h], [], [],
 222 [#include <io.h>
 223 #include <windef.h>
 224 #include <winbase.h>
 225 ])
 226 HAVE_FSCTL_SET_ZERO_DATA=no
 227 if test "x$ac_cv_header_winioctl_h" = "xyes"
 228 then
 229         AC_CHECK_DECL(FSCTL_SET_ZERO_DATA, [HAVE_FSCTL_SET_ZERO_DATA=yes], [HAVE_FSCTL_SET_ZERO_DATA=no],
 230         [#include <windef.h>
 231         #include <winbase.h>
 232         #include <winioctl.h>
 233         ])
 234 fi
 235 if test "x$HAVE_FSCTL_SET_ZERO_DATA" = "xyes"
 236 then
 237         AC_DEFINE(HAVE_FSCTL_SET_ZERO_DATA, 1, [Define to 1 if you have FSCTL_SET_ZERO_DATA])
 238 else
 239         AC_DEFINE(HAVE_FSCTL_SET_ZERO_DATA, 0, [Define to 1 if you have FSCTL_SET_ZERO_DATA])
 240 fi
 241
 242 AC_CHECK_FUNC([sync_file_range],
 243         [AC_DEFINE([HAVE_SYNC_FILE_RANGE], [sync_file_range(2) is not supported], [sync_file_range(2) is supported])],
 244         [])
 245 AC_FUNC_FORK
 246 AC_FUNC_SETVBUF_REVERSED
 247 AC_MSG_CHECKING(whether client should be built)
 248 case $host_os in
 249         linux*) NBD_CLIENT_NAME="nbd-client"
 250                 AC_MSG_RESULT(yes)
 251                 ;;
 252         *)      NBD_CLIENT_NAME=""
 253                 AC_MSG_RESULT(no)
 254                 ;;
 255 esac
 256 AM_CONDITIONAL(CLIENT, [test ! -z "$NBD_CLIENT_NAME"])
 257 AC_SEARCH_LIBS(bind, socket,, AC_MSG_ERROR([Could not find an implementation of the bind() system call]))
 258 AC_SEARCH_LIBS(inet_ntoa, nsl,, AC_MSG_ERROR([Could not find an implementation of the inet_ntoa() system call]))
 259 AC_SEARCH_LIBS(daemon, resolv,, AC_MSG_ERROR([Could not find an implementation of the daemon() system call]))
 260 AC_CHECK_HEADERS([sys/mount.h],,,
 261 [[#include <sys/param.h>
 262 ]])
 263 AC_CHECK_HEADERS([arpa/inet.h fcntl.h netdb.h netinet/in.h sys/ioctl.h sys/socket.h syslog.h linux/types.h sys/dirent.h])
 264 AM_PATH_GLIB_2_0(2.26.0, [HAVE_GLIB=yes], AC_MSG_ERROR([Missing glib]), gthread)
 265
 266 my_save_cflags="$CFLAGS"
 267 CFLAGS="-Wdeprecated-declarations -Werror $GLIB_CFLAGS"
 268 AC_MSG_CHECKING([if we are using an old glib 2.0 library])
 269 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 270         [[#include <glib.h>]],
 271         [[g_thread_init(NULL);]])],
 272         [
 273                 AC_MSG_RESULT(yes)
 274                 AC_DEFINE(HAVE_OLD_GLIB, 1, [Define to 1 if you have an old glib library])
 275         ],
 276         [
 277                 AC_MSG_RESULT(no)
 278                 AC_DEFINE(HAVE_OLD_GLIB, 0, [Define to 1 if you have an old glib library])
 279         ]
 280 )
 281 CFLAGS="$my_save_cflags"
 282
 283 AC_HEADER_SYS_WAIT
 284 AC_TYPE_OFF_T
 285 AC_TYPE_PID_T
 286 AM_CPPFLAGS=$AM_CPPFLAGS" -DSYSCONFDIR='\"$sysconfdir\"'"
 287 AC_SUBST(AM_CPPFLAGS)
 288 AM_CONDITIONAL(GZNBD, [test "x$ENABLE_GZNBD" = "xyes"])
 289 AC_CONFIG_HEADERS([config.h])
 290 AC_CONFIG_FILES([Makefile
 291                  doc/Doxyfile
 292                  doc/Makefile
 293                  man/Makefile
 294                  gznbd/Makefile
 295                  tests/Makefile
 296                  tests/code/Makefile
 297                  tests/run/Makefile
 298                  man/nbd-client.8.sh
 299                  man/nbd-server.5.sh
 300                  man/nbd-server.1.sh
 301                  man/nbd-trdump.1.sh
 302                  man/nbdtab.5.sh
 303                  systemd/Makefile
 304                  systemd/nbd@.service.sh
 305                 ])
 306 AC_OUTPUT
 307