configure.ac

   1 dnl Configure script for NBD system
   2 dnl (c) 1998 Martin Mares <mj@ucw.cz>, (c) 2000 Pavel Machek <pavel@ucw.cz>,
   3 dnl (c) 2003-2006 Wouter Verhelst <wouter@debian.org>
   4 AC_INIT([nbd],
   5   m4_esyscmd(support/genver.sh | tr -d '\n'),
   6   [nbd@other.debian.org],,
   7   [http://nbd.sourceforge.net/])
   8 m4_define([serial_tests], [
   9   m4_esyscmd([automake --version |
  10               head -1 |
  11               awk '{split ($NF,a,"."); if (a[1] == 1 && a[2] >= 12) { print "serial-tests" }}'
  12   ])
  13 ])
  14 AM_INIT_AUTOMAKE(foreign dist-xz serial_tests subdir-objects)
  15 AM_MAINTAINER_MODE([enable])
  16 AM_SILENT_RULES([yes])
  17 AC_CONFIG_MACRO_DIR([support])
  18 LT_INIT
  19
  20 AC_ARG_ENABLE(
  21   lfs,
  22   AS_HELP_STRING([--disable-lfs],[Disable Large File Support (default on)]),
  23   [
  24     if test "x$enableval" = "xyes" ; then
  25       NBD_LFS=1
  26     else
  27       NBD_LFS=0
  28     fi
  29   ],
  30   [NBD_LFS=1]
  31 )
  32 AC_MSG_CHECKING([whether Large File Support should be enabled])
  33 if test $NBD_LFS -eq 1; then
  34   AC_DEFINE(NBD_LFS,1, [Define to 1 if Large File Support should be enabled])
  35   AC_MSG_RESULT([yes])
  36 else
  37   AC_DEFINE(NBD_LFS,0)
  38   AC_MSG_RESULT([no])
  39 fi
  40
  41 AC_ARG_ENABLE(
  42   syslog,
  43   AS_HELP_STRING([--enable-syslog],[Enable Syslog logging]),
  44   [
  45     if test "x$enableval" = "xyes" ; then
  46       ISSERVER=1
  47     else
  48       ISSERVER=0
  49     fi
  50   ],
  51   [ISSERVER=0]
  52 )
  53
  54 AC_MSG_CHECKING([whether syslog logging is requested])
  55 if test $ISSERVER -eq 1; then
  56   AC_DEFINE(ISSERVER,1, [Define to 1 if you want nbd-server to log through syslog])
  57   AC_MSG_RESULT([yes])
  58 else
  59   AC_MSG_RESULT([no])
  60 fi
  61
  62 AC_ARG_ENABLE(
  63   debug,
  64   AS_HELP_STRING([--enable-debug],[Build a debugging version of the server]),
  65   [
  66     if test "x$enableval" = "xyes"; then
  67       DODBG=1
  68     else
  69       DODBG=0
  70     fi
  71   ],
  72   [DODBG=0]
  73 )
  74
  75 AC_MSG_CHECKING([whether a debugging version is requested])
  76 if test $DODBG -eq 1; then
  77   AC_MSG_RESULT([yes])
  78   if test $ISSERVER -eq 1; then
  79     AC_MSG_ERROR([You requested both syslog logging and a debugging version of the server. Bad idea!])
  80   fi
  81   AC_DEFINE(DODBG,1,[Define if you want a debugging version of nbd-server (lots of copious output)])
  82   AC_DEFINE(NOFORK,1,[Define if you do not want the nbd-server to fork()])
  83 else
  84   AC_MSG_RESULT([no])
  85 fi
  86
  87 AC_ARG_ENABLE(
  88   sdp,
  89   AS_HELP_STRING([--enable-sdp],[Build a version of nbd-server with support for the Socket Direct Protocol (SDP). Requires you to build and install a kernel with the InfiniBand patches (default disabled)]),
  90   [
  91     if test "x$enableval" = "xyes"; then
  92       AC_DEFINE(WITH_SDP, 1, [Define to 1 if you have and want support for the Socket Direct Protocol])
  93     fi
  94   ]
  95 )
  96
  97 AC_ARG_ENABLE(
  98   [gznbd],
  99   [AS_HELP_STRING([--enable-gznbd],[Build gznbd too (nbd server with on-the-fly decompression of images. NOTE: no support for newstyle protocol.)])],
 100   [
 101     AS_IF(
 102       [test "x$enableval" = "xyes"],
 103       [ENABLE_GZNBD=yes],
 104       [ENABLE_GZNBD=no]
 105     )
 106   ],
 107   [ENABLE_GZNBD=no]
 108 )
 109
 110 AC_PROG_CC
 111 AC_PROG_CPP
 112 AC_PROG_INSTALL
 113 AM_PROG_LEX(noyywrap)
 114 m4_ifdef([AX_PROG_BISON],,
 115  [m4_fatal([The m4 macro AX_PROG_BISON has not been defined. Please install the autoconf-archive package.])])
 116 AX_PROG_BISON([],AC_MSG_ERROR([bison is required]))
 117 PKG_PROG_PKG_CONFIG
 118 AC_CANONICAL_HOST
 119 AC_C_BIGENDIAN
 120 AC_C_INLINE
 121 AC_C_CONST
 122 AC_CHECK_SIZEOF(unsigned short int)
 123 AC_CHECK_SIZEOF(unsigned int)
 124 AC_CHECK_SIZEOF(unsigned long int)
 125 AC_CHECK_SIZEOF(unsigned long long int)
 126 AC_STRUCT_DIRENT_D_TYPE
 127 AC_CHECK_FUNCS([llseek alarm gethostbyname inet_ntoa memset socket strerror strstr mkstemp fdatasync])
 128 HAVE_FL_PH=no
 129
 130 AC_CHECK_FUNC(fallocate,
 131   [
 132     AC_CHECK_HEADERS([linux/falloc.h])
 133     if test "x$ac_cv_header_linux_falloc_h" = "xyes"
 134     then
 135       AC_CHECK_DECL(FALLOC_FL_PUNCH_HOLE, [HAVE_FL_PH=yes], [HAVE_FL_PH=no], [[#include <linux/falloc.h>]])
 136     fi
 137   ]
 138 )
 139
 140 AC_MSG_CHECKING([for FALLOC_FL_PUNCH_HOLE support])
 141 if test "x$HAVE_FL_PH" = "xyes"
 142 then
 143         AC_DEFINE(HAVE_FALLOC_PH, 1, [Define to 1 if you have FALLOC_FL_PUNCH_HOLE])
 144         AC_MSG_RESULT([yes])
 145 else
 146         AC_DEFINE(HAVE_FALLOC_PH, 0, [Define to 1 if you have FALLOC_FL_PUNCH_HOLE])
 147         AC_MSG_RESULT([no])
 148 fi
 149
 150 AC_CHECK_DECL([BLKDISCARD], AC_DEFINE(HAVE_BLKDISCARD, 1, [Define to 1 if you have the BLKDISCARD ioctl]), AC_DEFINE(HAVE_BLKDISCARD, 0), [#include <linux/fs.h>])
 151
 152 AC_CHECK_FUNC(splice, [HAVE_SPLICE=yes], [HAVE_SPLICE=no])
 153 if test "$HAVE_SPLICE" = "yes"
 154 then
 155         HAVE_SETPIPE_SZ=no
 156         AC_CHECK_DECL(F_SETPIPE_SZ, [HAVE_SETPIPE_SZ=yes],
 157                 [
 158                         unset ac_cv_have_decl_F_SETPIPE_SZ
 159                         AC_CHECK_HEADERS([linux/fcntl.h])
 160                         if test "$ac_cv_header_linux_fcntl_h" = "yes"
 161                         then
 162                                 AC_CHECK_DECL(F_SETPIPE_SZ, [HAVE_SETPIPE_SZ=define], [HAVE_SETPIPE_SZ=no], [[#include <linux/fcntl.h>]])
 163                         fi
 164                 ],
 165                 [[
 166                         #define _GNU_SOURCE
 167                         #include <fcntl.h>
 168                 ]]
 169         )
 170         AC_MSG_CHECKING([for F_SETPIPE_SZ support])
 171         case $HAVE_SETPIPE_SZ in
 172                 yes)
 173                         AC_DEFINE(HAVE_SPLICE, 1, [Define to 1 if we have splice support])
 174                         AC_MSG_RESULT([yes])
 175                 ;;
 176                 define)
 177                         AC_DEFINE(HAVE_SPLICE, 1, [Define to 1 if we have splice support])
 178                         AC_DEFINE(F_SETPIPE_SZ, 1031, [Define to 1031 if we have kernel support but no userspace support])
 179                         AC_MSG_RESULT([yes])
 180                 ;;
 181                 no)
 182                         AC_MSG_RESULT([missing, disabling splice support])
 183                 ;;
 184         esac
 185 fi
 186
 187 m4_ifndef([PKG_CHECK_MODULES], [m4_fatal([Missing pkg-config M4 macros. Please ensure that pkg-config is installed.])])
 188
 189 dnl AC_MSG_CHECKING([where to puth systemd unit files])
 190 dnl AC_ARG_WITH(
 191 dnl   systemd,
 192 dnl   AS_HELP_STRING([--with-systemd=loc|pkgconfig],[Install systemd files in loc; if passing pkgconfig, use pkg-config to detect the correct location and install there.])
 193 dnl   [
 194 dnl     if test "x$enableval" = "xyes"; then
 195 dnl       ENABLE_SYSTEMD=yes
 196 dnl     else
 197 dnl       ENABLE_SYSTEMD=no
 198 dnl     fi
 199 dnl   ],[]
 200 dnl )
 201 dnl
 202 dnl if test "x$ENABLE_SYSTEMD" != "xno"; then
 203 dnl     PKG_CHECK_VAR([SYSTEMDUNIT],[systemd],systemdsystemunitdir],[AC_SUBST([SYSTEMDLOC], [$SYSTEMDUNIT])])
 204 dnl fi
 205 dnl AM_CONDITIONAL(SYSTEMD, [test ! -z "$SYSTEMDUNIT"])
 206 dnl if test ! -z $SYSTEMDUNIT; then
 207 dnl     AC_MSG_RESULT([$SYSTEMDUNIT])
 208 dnl else
 209 dnl     case $ENABLE_SYSTEMD in
 210 dnl             no)
 211 dnl                     AC_MSG_RESULT([disabled])
 212 dnl             ;;
 213 dnl             yes)
 214 dnl                     AC_MSG_ERROR([systemd not found])
 215 dnl             ;;
 216 dnl             *)
 217 dnl                     AC_MSG_RESULT([not found])
 218 dnl             ;;
 219 dnl     esac
 220 dnl fi
 221
 222 AC_ARG_WITH([gnutls],
 223         [AS_HELP_STRING([--without-gnutls],
 224                 [do not use gnutls])],
 225         [],
 226         [with_gnutls=check]
 227 )
 228 if test "x$with_gnutls" != "xno"; then
 229         PKG_CHECK_MODULES(GnuTLS, [gnutls >= 2.12.0],
 230                 [HAVE_GNUTLS=1
 231                 AC_DEFINE(HAVE_GNUTLS, 1, [Define to 1 if you have a GnuTLS version of 2.12 or above])],
 232                 [if test "x$with_gnutls" = "xyes"; then
 233                         AC_MSG_ERROR([--with-gnutls given but cannot find gnutls])
 234                 else
 235                         HAVE_GNUTLS=0
 236                         AC_DEFINE(HAVE_GNUTLS, 0)
 237                 fi]
 238         )
 239 else
 240         HAVE_GNUTLS=0
 241         AC_DEFINE(HAVE_GNUTLS, 0)
 242 fi
 243 AM_CONDITIONAL([GNUTLS], [test "x$HAVE_GNUTLS" = "x1"])
 244
 245 AC_CHECK_HEADERS([winioctl.h], [], [],
 246 [#include <io.h>
 247 #include <windef.h>
 248 #include <winbase.h>
 249 ])
 250 HAVE_FSCTL_SET_ZERO_DATA=no
 251 if test "x$ac_cv_header_winioctl_h" = "xyes"
 252 then
 253         AC_CHECK_DECL(FSCTL_SET_ZERO_DATA, [HAVE_FSCTL_SET_ZERO_DATA=yes], [HAVE_FSCTL_SET_ZERO_DATA=no],
 254         [#include <windef.h>
 255         #include <winbase.h>
 256         #include <winioctl.h>
 257         ])
 258 fi
 259 if test "x$HAVE_FSCTL_SET_ZERO_DATA" = "xyes"
 260 then
 261         AC_DEFINE(HAVE_FSCTL_SET_ZERO_DATA, 1, [Define to 1 if you have FSCTL_SET_ZERO_DATA])
 262 else
 263         AC_DEFINE(HAVE_FSCTL_SET_ZERO_DATA, 0, [Define to 1 if you have FSCTL_SET_ZERO_DATA])
 264 fi
 265
 266 AC_CHECK_FUNC([sync_file_range],
 267         [AC_DEFINE([HAVE_SYNC_FILE_RANGE], [sync_file_range(2) is not supported], [sync_file_range(2) is supported])],
 268         [])
 269 AC_FUNC_FORK
 270 AC_MSG_CHECKING(whether client should be built)
 271 AS_CASE([$host_os],
 272   [linux*], [NBD_CLIENT_NAME="nbd-client"; AC_MSG_RESULT(yes)],
 273   [NBD_CLIENT_NAME=""; AC_MSG_RESULT(no)]
 274 )
 275 AC_MSG_CHECKING(whether to expect tlshuge test to fail)
 276 AS_CASE([$host_os],
 277   [darwin*], [RUN_XFAIL=tlshuge; AC_MSG_RESULT(yes)],
 278   [RUN_XFAIL=""; AC_MSG_RESULT(no)]
 279 )
 280 AC_SUBST([RUN_XFAIL])
 281 AM_CONDITIONAL(CLIENT, [test ! -z "$NBD_CLIENT_NAME"])
 282 AC_SEARCH_LIBS(bind, socket,, AC_MSG_ERROR([Could not find an implementation of the bind() system call]))
 283 AC_SEARCH_LIBS(inet_ntoa, nsl,, AC_MSG_ERROR([Could not find an implementation of the inet_ntoa() system call]))
 284 AC_SEARCH_LIBS(daemon, resolv,, AC_MSG_ERROR([Could not find an implementation of the daemon() system call]))
 285 AC_CHECK_HEADERS([sys/mount.h],,,
 286 [[#include <sys/param.h>
 287 ]])
 288 AC_CHECK_HEADERS([arpa/inet.h fcntl.h netdb.h netinet/in.h sys/ioctl.h sys/socket.h syslog.h linux/types.h sys/dirent.h sys/uio.h])
 289 PKG_CHECK_MODULES(GLIB, [glib-2.0 >= 2.26.0 gthread-2.0 >= 2.26.0], [HAVE_GLIB=yes], AC_MSG_ERROR([Missing glib]))
 290
 291 my_save_cflags="$CFLAGS"
 292 my_save_libs="$LIBS"
 293 CFLAGS="-Wdeprecated-declarations -Werror $GLIB_CFLAGS"
 294 LIBS="$GLIB_LIBS"
 295 AC_MSG_CHECKING([if we are using an old glib 2.0 library])
 296 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 297         [[#include <glib.h>]],
 298         [[g_thread_init(NULL);]])],
 299         [
 300                 AC_MSG_RESULT(yes)
 301                 AC_DEFINE(HAVE_OLD_GLIB, 1, [Define to 1 if you have an old glib library])
 302         ],
 303         [
 304                 AC_MSG_RESULT(no)
 305                 AC_DEFINE(HAVE_OLD_GLIB, 0, [Define to 1 if you have an old glib library])
 306         ]
 307 )
 308 dnl g_memdup2 added in glib-2.68
 309 AC_CHECK_FUNCS([g_memdup2])
 310 CFLAGS="$my_save_cflags"
 311 LIBS="$my_save_libs"
 312
 313 AC_MSG_CHECKING([whether _BSD_SOURCE needs to be defined for DT_* macros])
 314 AC_PREPROC_IFELSE(
 315         [AC_LANG_PROGRAM([[#include <dirent.h>]],
 316                          [[#ifndef DT_UNKNOWN
 317 #error nope
 318 #endif]])],
 319         [AC_MSG_RESULT([no]); NEED_BSD_SOURCE=0],
 320         [AC_MSG_RESULT([yes]); NEED_BSD_SOURCE=1])
 321 AC_DEFINE([NEED_BSD_SOURCE], $NEED_BSD_SOURCE, [Define to 1 if _BSD_SOURCE needs to be defined before certain inclusions])
 322
 323 AC_ARG_WITH([libnl],
 324         [AS_HELP_STRING([--without-libnl],
 325                 [do not use libnl])],
 326         [],
 327         [with_libnl=check]
 328 )
 329 if test "x$with_libnl" != "xno"; then
 330         PKG_CHECK_MODULES(LIBNL3, libnl-genl-3.0 >= 3.1,
 331                 [HAVE_NETLINK=1
 332                 AC_DEFINE(HAVE_NETLINK, 1, [Define to 1 if we have netlink support])
 333                 CFLAGS="$CFLAGS $LIBNL3_CFLAGS"
 334                 LIBS="$LIBS $LIBNL3_LIBS"],
 335                 [if test "x$with_libnl" = "xyes"; then
 336                         AC_MSG_ERROR([--with-libnl given but cannot find libnl])
 337                 else
 338                         HAVE_NETLINK=0
 339                         AC_DEFINE(HAVE_NETLINK, 0)
 340                 fi]
 341         )
 342 else
 343         HAVE_NETLINK=0
 344         AC_DEFINE(HAVE_NETLINK, 0, [Define to 1 if we have netlink support])
 345 fi
 346
 347 AC_ARG_ENABLE([manpages],
 348         AS_HELP_STRING([--disable-manpages], [Do not install man pages]))
 349 AM_CONDITIONAL(MANPAGES, test "x$enable_manpages" != "xno")
 350 AS_IF([test "x$enable_manpages" != "xno"], [
 351         AC_SUBST([MAN_CONFIG_FILES],["\
 352                 man/nbd-client.8.sh \
 353                 man/nbd-server.5.sh \
 354                 man/nbd-server.1.sh \
 355                 man/nbd-trdump.1.sh \
 356                 man/nbd-trplay.1.sh \
 357                 man/nbdtab.5.sh \
 358                 "])
 359         ])
 360
 361 AC_HEADER_SYS_WAIT
 362 AC_TYPE_OFF_T
 363 AC_TYPE_PID_T
 364 AM_CPPFLAGS=$AM_CPPFLAGS" -DSYSCONFDIR='\"$sysconfdir\"'"
 365 AC_SUBST(AM_CPPFLAGS)
 366 AM_CONDITIONAL(GZNBD, [test "x$ENABLE_GZNBD" = "xyes"])
 367 AC_CONFIG_HEADERS([config.h])
 368 AC_CONFIG_LINKS([tests/run/buffer.c:buffer.c
 369                  tests/run/crypto-gnutls.c:crypto-gnutls.c
 370                  tests/run/cliserv.c:cliserv.c])
 371 AC_CONFIG_FILES([Makefile
 372                  doc/Doxyfile
 373                  doc/Makefile
 374                  man/Makefile
 375                  gznbd/Makefile
 376                  tests/Makefile
 377                  tests/code/Makefile
 378                  tests/run/Makefile
 379                  tests/parse/Makefile
 380                  man/nbd-client.8.sh
 381                  man/nbd-server.5.sh
 382                  man/nbd-server.1.sh
 383                  man/nbd-trdump.1.sh
 384                  man/nbd-trplay.1.sh
 385                  man/nbdtab.5.sh
 386                  systemd/Makefile
 387                  systemd/nbd@.service.sh
 388                 ])
 389 AC_OUTPUT
 390