external/bsd/am-utils/dist/m4/macros/check_mnt2_nfs_opt.m4

   1 dnl ######################################################################
   2 dnl Find NFS-specific mount(2) options (hex numbers)
   3 dnl Usage: AMU_CHECK_MNT2_NFS_OPT(<fs>)
   4 dnl Check if there is an entry for NFSMNT_<fs> in sys/mntent.h or
   5 dnl mntent.h, then define MNT2_NFS_OPT_<fs> to the hex number.
   6 AC_DEFUN([AMU_CHECK_MNT2_NFS_OPT],
   7 [
   8 # what name to give to the fs
   9 ac_fs_name=$1
  10 # store variable name of fs
  11 ac_upcase_fs_name=`echo $ac_fs_name | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
  12 ac_safe=MNT2_NFS_OPT_$ac_upcase_fs_name
  13 # check for cache and set it if needed
  14 AMU_CACHE_CHECK_DYNAMIC(for NFS-specific mount(2) option $ac_fs_name,
  15 ac_cv_mnt2_nfs_opt_$ac_fs_name,
  16 [
  17 # undefine by default
  18 eval "ac_cv_mnt2_nfs_opt_$ac_fs_name=notfound"
  19 value=notfound
  20
  21 # first try NFSMNT_* (most systems)
  22 if test "$value" = notfound
  23 then
  24 AMU_EXPAND_CPP_HEX(
  25 AMU_MOUNT_HEADERS
  26 , NFSMNT_$ac_upcase_fs_name)
  27 fi
  28
  29 # next try NFS_MOUNT_* (linux)
  30 if test "$value" = notfound
  31 then
  32 AMU_EXPAND_CPP_HEX(
  33 AMU_MOUNT_HEADERS
  34 , NFS_MOUNT_$ac_upcase_fs_name)
  35 fi
  36
  37 # set cache variable to value
  38 eval "ac_cv_mnt2_nfs_opt_$ac_fs_name=$value"
  39 ])
  40 # outside cache check, if ok, define macro
  41 ac_tmp=`eval echo '$''{ac_cv_mnt2_nfs_opt_'$ac_fs_name'}'`
  42 if test "${ac_tmp}" != notfound
  43 then
  44   AC_DEFINE_UNQUOTED($ac_safe, $ac_tmp)
  45 fi
  46 ])
  47 dnl ======================================================================
  48
  49 dnl ######################################################################
  50 dnl run AMU_CHECK_MNT2_NFS_OPT on each argument given
  51 dnl Usage: AMU_CHECK_MNT2_NFS_OPTS(arg arg arg ...)
  52 AC_DEFUN([AMU_CHECK_MNT2_NFS_OPTS],
  53 [
  54 for ac_tmp_arg in $1
  55 do
  56 AMU_CHECK_MNT2_NFS_OPT($ac_tmp_arg)
  57 done
  58 ])
  59 dnl ======================================================================