libexec/ld.aout_so/arch/m68k/mdprologue.S

   1 /*      $NetBSD$        */
   2
   3 /*
   4  * Copyright (c) 1993 Paul Mackerras
   5  * All rights reserved.
   6  *
   7  * Redistribution and use in source and binary forms, with or without
   8  * modification, are permitted provided that the following conditions
   9  * are met:
  10  * 1. Redistributions of source code must retain the above copyright
  11  *    notice, this list of conditions and the following disclaimer.
  12  * 2. Redistributions in binary form must reproduce the above copyright
  13  *    notice, this list of conditions and the following disclaimer in the
  14  *    documentation and/or other materials provided with the distribution.
  15  * 3. All advertising materials mentioning features or use of this software
  16  *    must display the following acknowledgement:
  17  *      This product includes software developed by Paul Mackerras.
  18  * 4. The name of the author may not be used to endorse or promote products
  19  *    derived from this software without specific prior written permission
  20  *
  21  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
  22  * IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
  23  * OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
  24  * IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
  25  * INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
  26  * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  27  * DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  28  * THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  29  * (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
  30  * THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  31  */
  32
  33 /*
  34  * Run-time link editor entry points for m68k architecture.
  35  */
  36
  37         .globl  _rtl
  38 _rtl:
  39         link    a6,#0
  40         movel   a5,sp@-
  41         movel   a6@(12),a0                      | -> crt_ldso structure
  42         movel   a0@,a1                          | base address
  43         movel   #__GLOBAL_OFFSET_TABLE_,a5      | PIC function prologue
  44         lea     pc@(0,a5:l),a5
  45         movel   a5@,d0                          | 1st entry in GOT
  46         addl    a1,d0                           | add ld.so base address
  47         movel   d0,sp@-                         | gives address of __DYNAMIC
  48         movel   a0,sp@-                         | crt_ldso pointer
  49         movel   a6@(8),sp@-                     | version
  50         addl    a5@(_rtld:w),a1                 | relocate _rtld function
  51         jsr     a1@                             | call it
  52 |       movel   #0x80000004,d0                  | CC_EXTPURGE | CC_IPURGE
  53 |       trap    #12                             | cachectl
  54         movel   a6@(-4),a5
  55         unlk    a6
  56         rts
  57
  58         .globl  _binder_entry
  59 _binder_entry:
  60         movml   a0-a1/d0-d1,sp@-        | preserve scratch registers
  61         movl    sp@(16),a0              | grab return address (within PLT)
  62         moveq   #0,d0
  63         movw    a0@,d0                  | get function index
  64         movel   d0,sp@-
  65         subql   #6,a0                   | point to PLT slot
  66         movel   a0,sp@-
  67         jbsr    _binder                 | relocate function address
  68         addql   #8,sp
  69         movel   d0,sp@(16)              | put function address on stack
  70 |       movel   #0x80000004,d0          | CC_EXTPURGE | CC_IPURGE
  71 |       trap    #12                     | cachectl
  72         movml   sp@+,a0-a1/d0-d1        | restore scratch registers
  73         rts                             | jump into function (via address on stack)
  74
  75         .globl  __cachectl
  76 __cachectl:
  77         movel   sp@(4),a1               | address
  78         movel   sp@(8),d1               | length
  79         movel   #0x80000004,d0          | function = CC_EXTPURGE | CC_IPURGE
  80         trap    #12                     | cachectl "syscall"
  81         rts