gnu/dist/autoconf/configure.ac

   1 #                                                       -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3 AC_PREREQ(2.50)
   4 AC_INIT(GNU Autoconf, 2.52, bug-autoconf@gnu.org)
   5 AC_CONFIG_SRCDIR(acgeneral.m4)
   6 AC_CONFIG_AUX_DIR(config)
   7 AM_INIT_AUTOMAKE(autoconf, 2.52)
   8
   9 # Initialize the test suite.
  10 AT_CONFIG(..)
  11 AC_PATH_PROG(EXPR, expr)
  12
  13 # We use a path for GNU m4 so even if users have another m4 first in
  14 # their path, the installer can configure with a path that has GNU m4
  15 # first and get that path embedded in the installed autoconf and
  16 # autoheader scripts.
  17 AC_PROG_GNU_M4
  18 if test x"$ac_cv_prog_gnu_m4" != xyes; then
  19   AC_MSG_ERROR([GNU m4 1.4 is required])
  20 fi
  21 # This is needed because Automake does not seem to realize there is
  22 # a AC-SUBST inside AC-PROG-GNU-M4.  Grmph!
  23 AC_SUBST(M4)
  24
  25 # `autoconf' and `ifnames' use AWK.  And we need decent RE support.
  26 AC_PROG_AWK
  27 # Some AWK fail
  28 if echo xfoo | $AWK '/foo|^bar$/ { print }' | grep xfoo >/dev/null; then :; else
  29   AC_MSG_ERROR([the regex engine of $AWK is too broken to be used
  30                 you might want to install GNU AWK])
  31 fi
  32
  33 # Generating man pages.
  34 AM_MISSING_PROG(HELP2MAN, help2man)
  35
  36 # We use a path for perl so the #! line in autoscan will work.
  37 AC_PATH_PROG(PERL, perl, no)
  38 AC_SUBST(PERL)dnl
  39 AC_SUBST(PERLSCRIPTS)dnl
  40 if test "$PERL" != no; then
  41   PERLSCRIPTS="autoscan autoupdate"
  42 else
  43   AC_MSG_WARN([autoscan and autoupdate will not be built since perl is not found])
  44 fi
  45
  46 AC_PROG_INSTALL
  47
  48 # Automake can't see inner AC_SUBSTS (`aclocal' is bypassed), so we tag the
  49 # AC_SUBSTS here too.
  50 AC_SUBST(PACKAGE_NAME)
  51 AC_SUBST(PACKAGE)
  52 AC_SUBST(VERSION)
  53
  54 AC_CONFIG_FILES(Makefile m4/Makefile man/Makefile doc/Makefile config/Makefile
  55                 tests/Makefile tests/atconfig)
  56
  57 AC_OUTPUT
  58
  59 # Report the state of this version of Autoconf if this is a beta.
  60 case AC_PACKAGE_VERSION in
  61   *[[a-z]]*)
  62     cat <<EOF
  63
  64 You are about to use an experimental version of Autoconf.  Be sure to
  65 read the relevant mailing lists, most importantly <autoconf@gnu.org>.
  66
  67 Below you will find information on the status of this version of Autoconf.
  68
  69
  70 EOF
  71     sed -n '/^\* Status/,$p' $srcdir/BUGS;;
  72 esac