lib/libc/arch/mips/gen/_setjmp.S

   1 /*      $NetBSD: _setjmp.S,v 1.20.34.3 2009/12/12 19:08:57 cliff Exp $  */
   2
   3 /*-
   4  * Copyright (c) 1991, 1993
   5  *      The Regents of the University of California.  All rights reserved.
   6  *
   7  * This code is derived from software contributed to Berkeley by
   8  * Ralph Campbell.
   9  *
  10  * Redistribution and use in source and binary forms, with or without
  11  * modification, are permitted provided that the following conditions
  12  * are met:
  13  * 1. Redistributions of source code must retain the above copyright
  14  *    notice, this list of conditions and the following disclaimer.
  15  * 2. Redistributions in binary form must reproduce the above copyright
  16  *    notice, this list of conditions and the following disclaimer in the
  17  *    documentation and/or other materials provided with the distribution.
  18  * 3. Neither the name of the University nor the names of its contributors
  19  *    may be used to endorse or promote products derived from this software
  20  *    without specific prior written permission.
  21  *
  22  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  23  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  24  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  25  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  26  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  27  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  28  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  29  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  30  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  31  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  32  * SUCH DAMAGE.
  33  */
  34
  35 #include <machine/cdefs.h>
  36 #include <mips/regnum.h>
  37 #include <mips/asm.h>
  38 #include <machine/setjmp.h>
  39 #include <machine/signal.h>             /* XXX */
  40
  41 #include "assym.h"
  42
  43 #include "SYS.h"
  44
  45 #if defined(LIBC_SCCS) && !defined(lint)
  46 #if 0
  47         RCSID("from: @(#)_setjmp.s      8.1 (Berkeley) 6/4/93")
  48 #else
  49         RCSID("$NetBSD: _setjmp.S,v 1.20.34.3 2009/12/12 19:08:57 cliff Exp $")
  50 #endif
  51 #endif /* LIBC_SCCS and not lint */
  52
  53 /*
  54  * C library -- _setjmp, _longjmp
  55  *
  56  *      _longjmp(a,v)
  57  * will generate a "return(v)" from
  58  * the last call to
  59  *      _setjmp(a)
  60  * by restoring registers from the stack,
  61  * The previous signal state is NOT restored.
  62  */
  63
  64         .set    noreorder
  65
  66 LEAF(_setjmp)
  67         REG_PROLOGUE
  68         REG_LI  v0, 0xACEDBADE                  # sigcontext magic number
  69         REG_S   ra, _OFFSETOF_SC_PC(a0)         # sc_pc = return address
  70         REG_S   v0, _OFFSETOF_SC_REGS(a0)       #   saved in sc_regs[0]
  71         REG_S   a1, _OFFSETOF_SC_REGS_V0(a0)    # save return value
  72         REG_S   s0, _OFFSETOF_SC_REGS_S0(a0)
  73         REG_S   s1, _OFFSETOF_SC_REGS_S1(a0)
  74         REG_S   s2, _OFFSETOF_SC_REGS_S2(a0)
  75         REG_S   s3, _OFFSETOF_SC_REGS_S3(a0)
  76         REG_S   s4, _OFFSETOF_SC_REGS_S4(a0)
  77         REG_S   s5, _OFFSETOF_SC_REGS_S5(a0)
  78         REG_S   s6, _OFFSETOF_SC_REGS_S6(a0)
  79         REG_S   s7, _OFFSETOF_SC_REGS_S7(a0)
  80         REG_S   sp, _OFFSETOF_SC_REGS_SP(a0)
  81         REG_S   s8, _OFFSETOF_SC_REGS_S8(a0)
  82 #if defined(__mips_n32) || defined(__mips_n64)
  83         REG_S   gp, _OFFSETOF_SC_REGS_GP(a0)    # newabi gp is callee-saved
  84 #endif
  85         cfc1    v0, $31                         # too bad cant check if FP used
  86         /*
  87          * In N32, FP registers F20, F22, F24, F26, F28, F30 are callee-saved.
  88          * In N64, FP registers F23 .. F31 are callee-saved.
  89          * In O32, FP registers F20 .. F23 are callee-saved.
  90          */
  91 #ifndef SOFTFLOAT_FOR_GCC
  92 #if defined(__mips_n64) || defined(__mips_n32)
  93         FP_S    $f30, _OFFSETOF_SC_FPREGS_F30(a0)
  94         FP_S    $f28, _OFFSETOF_SC_FPREGS_F28(a0)
  95         FP_S    $f26, _OFFSETOF_SC_FPREGS_F26(a0)
  96         FP_S    $f24, _OFFSETOF_SC_FPREGS_F24(a0)
  97 #endif
  98 #if defined(__mips_n32) || defined(__mips_o32) || defined(__mips_o64)
  99         FP_S    $f22, _OFFSETOF_SC_FPREGS_F22(a0)
 100         FP_S    $f20, _OFFSETOF_SC_FPREGS_F20(a0)
 101 #endif
 102 #if defined(__mips_o32) || defined(__mips_o64)
 103         FP_S    $f21, _OFFSETOF_SC_FPREGS_F21(a0)
 104         FP_S    $f23, _OFFSETOF_SC_FPREGS_F23(a0)
 105 #endif
 106 #if defined(__mips_n64)
 107         FP_S    $f25, _OFFSETOF_SC_FPREGS_F25(a0)
 108         FP_S    $f27, _OFFSETOF_SC_FPREGS_F27(a0)
 109         FP_S    $f29, _OFFSETOF_SC_FPREGS_F29(a0)
 110         FP_S    $f31, _OFFSETOF_SC_FPREGS_F31(a0)
 111 #endif
 112 #endif  /* SOFTFLOAT_FOR_GCC */
 113         INT_S   v0, _OFFSETOF_SC_FPREGS_FCSR(a0)
 114         REG_EPILOGUE
 115
 116         j       ra
 117         move    v0, zero
 118 END(_setjmp)
 119
 120 LEAF(_longjmp)
 121         PIC_PROLOGUE(_longjmp)
 122         PTR_SUBU        sp, sp, CALLFRAME_SIZ
 123         SAVE_GP(CALLFRAME_GP)
 124
 125         REG_PROLOGUE
 126         REG_L           v0, _OFFSETOF_SC_REGS(a0)       # get magic number
 127         REG_L           ra, _OFFSETOF_SC_PC(a0)
 128         REG_LI          t0, 0xACEDBADE
 129         bne             v0, t0, botch           # jump if error
 130         PTR_ADDU        sp, sp, CALLFRAME_SIZ   # does not matter, sanity
 131         REG_L           s0, _OFFSETOF_SC_REGS_S0(a0)
 132         REG_L           s1, _OFFSETOF_SC_REGS_S1(a0)
 133         REG_L           s2, _OFFSETOF_SC_REGS_S2(a0)
 134         REG_L           s3, _OFFSETOF_SC_REGS_S3(a0)
 135         REG_L           s4, _OFFSETOF_SC_REGS_S4(a0)
 136         REG_L           s5, _OFFSETOF_SC_REGS_S5(a0)
 137         REG_L           s6, _OFFSETOF_SC_REGS_S6(a0)
 138         REG_L           s7, _OFFSETOF_SC_REGS_S7(a0)
 139 #if defined(__mips_n32) || defined(__mips_n64)
 140         REG_L           gp, _OFFSETOF_SC_REGS_GP(a0)
 141 #endif
 142         # get fpu status
 143         INT_L           v0, _OFFSETOF_SC_FPREGS_FCSR(a0)
 144         REG_L           sp, _OFFSETOF_SC_REGS_SP(a0)
 145         REG_L           s8, _OFFSETOF_SC_REGS_S8(a0)
 146         ctc1            v0, $31
 147         /*
 148          * In N32, FP registers F20, F22, F24, F26, F28, F30 are callee-saved.
 149          * In N64, FP registers F23 .. F31 are callee-saved.
 150          * In O32, FP registers F20 .. F23 are callee-saved.
 151          */
 152 #ifndef SOFTFLOAT_FOR_GCC
 153 #if defined(__mips_n64) || defined(__mips_n32)
 154         FP_L    $f30, _OFFSETOF_SC_FPREGS_F30(a0)
 155         FP_L    $f28, _OFFSETOF_SC_FPREGS_F28(a0)
 156         FP_L    $f26, _OFFSETOF_SC_FPREGS_F26(a0)
 157         FP_L    $f24, _OFFSETOF_SC_FPREGS_F24(a0)
 158 #endif
 159 #if defined(__mips_n32) || defined(__mips_o32) || defined(__mips_o64)
 160         FP_L    $f22, _OFFSETOF_SC_FPREGS_F22(a0)
 161         FP_L    $f20, _OFFSETOF_SC_FPREGS_F20(a0)
 162 #endif
 163 #if defined(__mips_o32) || defined(__mips_o64)
 164         FP_L    $f21, _OFFSETOF_SC_FPREGS_F21(a0)
 165         FP_L    $f23, _OFFSETOF_SC_FPREGS_F23(a0)
 166 #endif
 167 #if defined(__mips_n64)
 168         FP_L    $f25, _OFFSETOF_SC_FPREGS_F25(a0)
 169         FP_L    $f27, _OFFSETOF_SC_FPREGS_F27(a0)
 170         FP_L    $f29, _OFFSETOF_SC_FPREGS_F29(a0)
 171         FP_L    $f31, _OFFSETOF_SC_FPREGS_F31(a0)
 172 #endif
 173 #endif  /* SOFTFLOAT_FOR_GCC */
 174
 175         REG_EPILOGUE
 176         REG_L   v0, _OFFSETOF_SC_REGS_V0(a0)
 177         j       ra
 178         nop
 179
 180 botch:
 181         /*
 182          * We know we aren't returning so we don't care about restoring
 183          * our caller's GP.
 184          */
 185         jal     _C_LABEL(longjmperror)
 186
 187         PIC_TAILCALL(abort)
 188 END(_longjmp)