lib/libc/arch/vax/sys/__vfork14.S

   1 /*
   2  * Copyright (c) 1983, 1993
   3  *      The Regents of the University of California.  All rights reserved.
   4  *
   5  * Redistribution and use in source and binary forms, with or without
   6  * modification, are permitted provided that the following conditions
   7  * are met:
   8  * 1. Redistributions of source code must retain the above copyright
   9  *    notice, this list of conditions and the following disclaimer.
  10  * 2. Redistributions in binary form must reproduce the above copyright
  11  *    notice, this list of conditions and the following disclaimer in the
  12  *    documentation and/or other materials provided with the distribution.
  13  * 3. Neither the name of the University nor the names of its contributors
  14  *    may be used to endorse or promote products derived from this software
  15  *    without specific prior written permission.
  16  *
  17  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  18  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  19  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  20  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  21  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  22  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  23  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  24  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  25  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  26  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  27  * SUCH DAMAGE.
  28  */
  29
  30 #if defined(SYSLIBC_SCCS) && !defined(lint)
  31         /* .asciz "@(#)Ovfork.s 8.1 (Berkeley) 6/4/93" */
  32         .asciz "$NetBSD: __vfork14.S,v 1.4 2002/02/24 01:06:20 matt Exp $"
  33 #endif /* SYSLIBC_SCCS and not lint */
  34
  35 /*
  36  * @(#)vfork.s  4.1 (Berkeley) 12/21/80
  37  * C library -- vfork
  38  */
  39
  40 #include "SYS.h"
  41
  42 /*
  43  * pid = vfork();
  44  *
  45  * %r1 == 0 in parent process, %r1 == 1 in child process.
  46  * %r0 == pid of child in parent, %r0 == pid of parent in child.
  47  *
  48  * trickery here, due to keith sklower, uses ret to clear the stack,
  49  * and then returns with a jump indirect, since only one person can return
  50  * with a ret off this stack... we do the ret before we vfork!
  51  */
  52
  53 ENTRY(__vfork14, 0)
  54         movl    16(%fp),%r2     # save return address before we smash it
  55         movab   here,16(%fp)
  56         ret
  57 here:
  58         chmk    $ SYS___vfork14
  59         bcs     err             # if failed, set errno and return -1
  60         /* this next trick is Chris Torek's fault */
  61         mnegl   %r1,%r1         # %r1 = 0xffffffff if child, 0 if parent
  62         bicl2   %r1,%r0         # %r0 &= ~%r1, i.e., 0 if child, else unchanged
  63         jmp     (%r2)
  64
  65 err:
  66 #ifdef _REENTRANT
  67         pushr   $0x5
  68         calls   $0,_C_LABEL(__errno)
  69         movl    (%sp)+,(%r0)
  70         mnegl   $1,%r0
  71         rsb
  72 #else
  73         movl    %r0,_C_LABEL(errno)
  74         mnegl   $1,%r0
  75         jmp     (%r2)
  76 #endif