lib/libc/compat/arch/vax/gen/compat_setjmp.S

   1 /*
   2  * Copyright (c) 1983, 1993
   3  *      The Regents of the University of California.  All rights reserved.
   4  *
   5  * Redistribution and use in source and binary forms, with or without
   6  * modification, are permitted provided that the following conditions
   7  * are met:
   8  * 1. Redistributions of source code must retain the above copyright
   9  *    notice, this list of conditions and the following disclaimer.
  10  * 2. Redistributions in binary form must reproduce the above copyright
  11  *    notice, this list of conditions and the following disclaimer in the
  12  *    documentation and/or other materials provided with the distribution.
  13  * 3. Neither the name of the University nor the names of its contributors
  14  *    may be used to endorse or promote products derived from this software
  15  *    without specific prior written permission.
  16  *
  17  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  18  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  19  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  20  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  21  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  22  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  23  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  24  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  25  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  26  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  27  * SUCH DAMAGE.
  28  */
  29
  30 #if defined(LIBC_SCCS) && !defined(lint)
  31         /* .asciz "@(#)setjmp.s 8.1 (Berkeley) 6/4/93" */
  32         .asciz "$NetBSD: setjmp.S,v 1.7 2005/05/03 04:37:33 matt Exp $"
  33 #endif /* LIBC_SCCS and not lint */
  34
  35 /*
  36  * C library -- setjmp, longjmp
  37  *
  38  *      longjmp(a,v)
  39  * will generate a "return(v)" from
  40  * the last call to
  41  *      setjmp(a)
  42  * by restoring registers from the stack,
  43  * and a struct sigcontext, see <signal.h>
  44  */
  45
  46 #include "DEFS.h"
  47 #include "assym.h"
  48
  49 ENTRY(setjmp, R6)
  50         movl    4(%ap),%r6              # construct sigcontext
  51         subl2   $12,%sp                 # space for current struct sigstack
  52         pushl   %sp                     # get current values
  53         pushl   $0                      # no new values
  54         calls   $4,_C_LABEL(__sigaltstack14) # pop args plus signal stack value
  55         movl    (%sp)+,(%r6)+           # save onsigstack status of caller
  56         subl2   $SS_LEN,%sp
  57         pushl   %sp
  58         pushl   $0
  59         pushl   $SIG_BLOCK
  60         calls   $3,_C_LABEL(sigprocmask)# get signal mask
  61         movl    (%sp),(%r6)+            # save signal mask of caller
  62         movl    (%ap),%r0
  63         moval   4(%ap)[%r0],(%r6)+      # save sp of caller
  64         movl    12(%fp),(%r6)+          # save frame pointer of caller
  65         movl    8(%fp),(%r6)+           # save argument pointer of caller
  66         movl    16(%fp),(%r6)+          # save pc of caller
  67         movpsl  (%r6)                   # save psl of caller
  68         movw    4(%fp),(%r6)
  69         clrl    %r0
  70         ret
  71
  72 ENTRY(longjmp, 0)
  73         movl    8(%ap),%r0              # return(v)
  74         movl    4(%ap),%r1              # fetch buffer
  75         tstl    12(%r1)
  76         beql    botch
  77 loop:
  78         cmpl    12(%r1),%fp             # are we there yet?
  79         beql    done
  80         blssu   botch
  81         moval   20(%fp),%r2
  82         blbc    6(%fp),1f               # was %r0 saved?
  83         movl    %r0,(%r2)+
  84 1:
  85         bbc     $1,6(%fp),2f            # was %r1 saved?
  86         movl    %r1,(%r2)
  87 2:
  88         movab   loop,16(%fp)
  89         ret                             # pop another frame
  90
  91 done:
  92         pushl   SC13_LEN+20(%r1)        # here we fake a sigcontext
  93         pushl   SC13_LEN+16(%r1)        # from a sigcontext13
  94         pushl   SC13_LEN+12(%r1)
  95         pushl   SC13_LEN+8(%r1)         # first do save registers
  96         pushl   SC13_LEN+4(%r1)
  97         pushl   SC13_LEN+0(%r1)
  98         pushl   $0                      # fill out the sigset
  99         pushl   $0
 100         pushl   $0
 101         pushl   SC13_MASK(%r1)
 102         pushl   SC13_PS(%r1)            # now do everything else
 103         pushl   SC13_PC(%r1)
 104         pushl   SC13_AP(%r1)
 105         pushl   SC13_FP(%r1)
 106         pushl   SC13_AP(%r1)
 107         pushl   $0
 108         pushl   SC13_ONSTACK(%r1)
 109         movl    %sp,%r1
 110         pushl   %r0                     # the return value
 111         pushl   %r1                     # the sigcontext
 112         calls   $2,_C_LABEL(__longjmp14)
 113 botch:
 114         calls   $0,_C_LABEL(longjmperror)
 115         halt