sys/arch/i386/conf/kern.ldscript.4MB

   1 /*      $NetBSD: kern.ldscript.4MB,v 1.8 2006/12/02 04:49:37 christos Exp $     */
   2
   3 OUTPUT_FORMAT("elf32-i386", "elf32-i386",
   4               "elf32-i386")
   5 OUTPUT_ARCH(i386)
   6 ENTRY(_start)
   7 SECTIONS
   8 {
   9    /* Read-only sections, merged into text segment: */
  10    .text :
  11    AT (ADDR(.text) & 0x0fffffff)
  12    {
  13      *(.text)
  14      *(.text.*)
  15      *(.stub)
  16    } =0
  17    _etext = . ;
  18    PROVIDE (etext = .) ;
  19
  20    .rodata :
  21    AT (LOADADDR(.text) + (ADDR(.rodata) - ADDR(.text)))
  22    {
  23      *(.rodata)
  24      *(.rodata.*)
  25    }
  26
  27    /* Adjust the address for the data segment.  We push the data segment
  28       up to the next 4MB boundary so that we can map the text with large
  29       pages. */
  30    . = ALIGN(0x400000);
  31    __data_start = . ;
  32    .data :
  33    AT (LOADADDR(.text) + (ADDR(.data) - ADDR(.text)))
  34    {
  35      *(.data)
  36      *(.data.*)
  37    }
  38    _edata = . ;
  39    PROVIDE (edata = .) ;
  40    __bss_start = . ;
  41    .bss :
  42    AT (LOADADDR(.text) + (ADDR(.bss) - ADDR(.text)))
  43    {
  44      *(.bss)
  45      *(.bss.*)
  46      *(COMMON)
  47      . = ALIGN(32 / 8);
  48    }
  49    . = ALIGN(32 / 8);
  50   _end = . ;
  51   PROVIDE (end = .) ;
  52   .note.netbsd.ident :
  53   {
  54     KEEP(*(.note.netbsd.ident));
  55   }
  56 }