crypto/dist/heimdal/cf/aix.m4

   1 dnl
   2 dnl $Heimdal: aix.m4 14147 2004-08-25 14:14:01Z joda $
   3 dnl $NetBSD$
   4 dnl
   5
   6 AC_DEFUN([rk_AIX],[
   7
   8 aix=no
   9 case "$host" in
  10 *-*-aix3*)
  11         aix=3
  12         ;;
  13 *-*-aix4*|*-*-aix5*)
  14         aix=4
  15         ;;
  16 esac
  17
  18 AM_CONDITIONAL(AIX, test "$aix" != no)dnl
  19 AM_CONDITIONAL(AIX4, test "$aix" = 4)
  20
  21
  22 AC_ARG_ENABLE(dynamic-afs,
  23         AS_HELP_STRING([--disable-dynamic-afs],
  24                 [do not use loaded AFS library with AIX]))
  25
  26 if test "$aix" != no; then
  27         if test "$enable_dynamic_afs" != no; then
  28                 AC_REQUIRE([rk_DLOPEN])
  29                 if test "$ac_cv_func_dlopen" = no; then
  30                         AC_FIND_FUNC_NO_LIBS(loadquery, ld)
  31                 fi
  32                 if test "$ac_cv_func_dlopen" != no; then
  33                         AIX_EXTRA_KAFS='$(LIB_dlopen)'
  34                 elif test "$ac_cv_func_loadquery" != no; then
  35                         AIX_EXTRA_KAFS='$(LIB_loadquery)'
  36                 else
  37                         AC_MSG_NOTICE([not using dynloaded AFS library])
  38                         AIX_EXTRA_KAFS=
  39                         enable_dynamic_afs=no
  40                 fi
  41         else
  42                 AIX_EXTRA_KAFS=
  43         fi
  44 fi
  45
  46 AM_CONDITIONAL(AIX_DYNAMIC_AFS, test "$enable_dynamic_afs" != no)dnl
  47 AC_SUBST(AIX_EXTRA_KAFS)dnl
  48
  49 AH_BOTTOM([#if _AIX
  50 #define _ALL_SOURCE
  51 /* XXX this is gross, but kills about a gazillion warnings */
  52 struct ether_addr;
  53 struct sockaddr;
  54 struct sockaddr_dl;
  55 struct sockaddr_in;
  56 #endif])
  57
  58 ])