external/bsd/am-utils/dist/m4/macros/check_mnt2_gen_opt.m4

   1 dnl ######################################################################
   2 dnl Find generic mount(2) options (hex numbers)
   3 dnl Usage: AMU_CHECK_MNT2_GEN_OPT(<fs>)
   4 dnl Check if there is an entry for MS_<fs>, MNT_<fs>, or M_<fs>
   5 dnl (in that order) in mntent.h, sys/mntent.h, or mount.h...
   6 dnl then define MNT2_GEN_OPT_<fs> to the hex number.
   7 AC_DEFUN([AMU_CHECK_MNT2_GEN_OPT],
   8 [
   9 # what name to give to the fs
  10 ac_fs_name=$1
  11 # store variable name of fs
  12 ac_upcase_fs_name=`echo $ac_fs_name | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
  13 ac_safe=MNT2_GEN_OPT_$ac_upcase_fs_name
  14 # check for cache and set it if needed
  15 AMU_CACHE_CHECK_DYNAMIC(for generic mount(2) option $ac_fs_name,
  16 ac_cv_mnt2_gen_opt_$ac_fs_name,
  17 [
  18 # undefine by default
  19 eval "ac_cv_mnt2_gen_opt_$ac_fs_name=notfound"
  20 value=notfound
  21
  22 # first, try MS_* (most systems).  Must be the first test!
  23 if test "$value" = notfound
  24 then
  25 AMU_EXPAND_CPP_HEX(
  26 AMU_MOUNT_HEADERS
  27 , MS_$ac_upcase_fs_name)
  28 fi
  29
  30 # if failed, try MNT_* (bsd44 systems)
  31 if test "$value" = notfound
  32 then
  33 AMU_EXPAND_CPP_HEX(
  34 AMU_MOUNT_HEADERS
  35 , MNT_$ac_upcase_fs_name)
  36 fi
  37
  38 # if failed, try MS_*  as an integer (linux systems)
  39 if test "$value" = notfound
  40 then
  41 AMU_EXPAND_CPP_INT(
  42 AMU_MOUNT_HEADERS
  43 , MS_$ac_upcase_fs_name)
  44 fi
  45
  46 # If failed try M_* (must be last test since svr4 systems define M_DATA etc.
  47 # in <sys/stream.h>
  48 # This test was off for now, because of the conflicts with other systems.
  49 # but I turned it back on by faking the inclusion of <sys/stream.h> already.
  50 if test "$value" = notfound
  51 then
  52 AMU_EXPAND_CPP_HEX(
  53 #ifndef _sys_stream_h
  54 # define _sys_stream_h
  55 #endif /* not _sys_stream_h */
  56 #ifndef _SYS_STREAM_H
  57 # define _SYS_STREAM_H
  58 #endif  /* not _SYS_STREAM_H */
  59 AMU_MOUNT_HEADERS
  60 , M_$ac_upcase_fs_name)
  61 fi
  62
  63 # set cache variable to value
  64 eval "ac_cv_mnt2_gen_opt_$ac_fs_name=$value"
  65 ])
  66 # outside cache check, if ok, define macro
  67 ac_tmp=`eval echo '$''{ac_cv_mnt2_gen_opt_'$ac_fs_name'}'`
  68 if test "${ac_tmp}" != notfound
  69 then
  70   AC_DEFINE_UNQUOTED($ac_safe, $ac_tmp)
  71 fi
  72 ])
  73 dnl ======================================================================
  74
  75 dnl ######################################################################
  76 dnl run AMU_CHECK_MNT2_GEN_OPT on each argument given
  77 dnl Usage: AMU_CHECK_MNT2_GEN_OPTS(arg arg arg ...)
  78 AC_DEFUN([AMU_CHECK_MNT2_GEN_OPTS],
  79 [
  80 for ac_tmp_arg in $1
  81 do
  82 AMU_CHECK_MNT2_GEN_OPT($ac_tmp_arg)
  83 done
  84 ])
  85 dnl ======================================================================