external/bsd/am-utils/dist/m4/macros/struct_field_nfs_fh.m4

   1 dnl ######################################################################
   2 dnl Find the name of the nfs filehandle field in nfs_args_t.
   3 AC_DEFUN([AMU_STRUCT_FIELD_NFS_FH],
   4 [
   5 dnl make sure this is called before macros which depend on it
   6 AC_BEFORE([$0], [AC_TYPE_NFS_FH])
   7 AC_CACHE_CHECK(for the name of the nfs filehandle field in nfs_args_t,
   8 ac_cv_struct_field_nfs_fh,
   9 [
  10 # set to a default value
  11 ac_cv_struct_field_nfs_fh=notfound
  12 # look for name "fh" (most systems)
  13 if test "$ac_cv_struct_field_nfs_fh" = notfound
  14 then
  15 AC_TRY_COMPILE_NFS(
  16 [ nfs_args_t nat;
  17   char *cp = (char *) &(nat.fh);
  18 ], ac_cv_struct_field_nfs_fh=fh, ac_cv_struct_field_nfs_fh=notfound)
  19 fi
  20
  21 # look for name "root" (for example Linux)
  22 if test "$ac_cv_struct_field_nfs_fh" = notfound
  23 then
  24 AC_TRY_COMPILE_NFS(
  25 [ nfs_args_t nat;
  26   char *cp = (char *) &(nat.root);
  27 ], ac_cv_struct_field_nfs_fh=root, ac_cv_struct_field_nfs_fh=notfound)
  28 fi
  29 ])
  30 if test "$ac_cv_struct_field_nfs_fh" != notfound
  31 then
  32   AC_DEFINE_UNQUOTED(NFS_FH_FIELD, $ac_cv_struct_field_nfs_fh)
  33 fi
  34 ])
  35 dnl ======================================================================