external/bsd/atf/dist/m4/compiler-flags.m4

   1 dnl
   2 dnl Automated Testing Framework (atf)
   3 dnl
   4 dnl Copyright (c) 2007, 2008, 2009 The NetBSD Foundation, Inc.
   5 dnl All rights reserved.
   6 dnl
   7 dnl Redistribution and use in source and binary forms, with or without
   8 dnl modification, are permitted provided that the following conditions
   9 dnl are met:
  10 dnl 1. Redistributions of source code must retain the above copyright
  11 dnl    notice, this list of conditions and the following disclaimer.
  12 dnl 2. Redistributions in binary form must reproduce the above copyright
  13 dnl    notice, this list of conditions and the following disclaimer in the
  14 dnl    documentation and/or other materials provided with the distribution.
  15 dnl
  16 dnl THIS SOFTWARE IS PROVIDED BY THE NETBSD FOUNDATION, INC. AND
  17 dnl CONTRIBUTORS ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES,
  18 dnl INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF
  19 dnl MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
  20 dnl IN NO EVENT SHALL THE FOUNDATION OR CONTRIBUTORS BE LIABLE FOR ANY
  21 dnl DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  22 dnl DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE
  23 dnl GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
  24 dnl INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER
  25 dnl IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR
  26 dnl OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN
  27 dnl IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  28 dnl
  29
  30 dnl -----------------------------------------------------------------------
  31 dnl Check for C/C++ compiler flags
  32 dnl -----------------------------------------------------------------------
  33
  34 dnl
  35 dnl ATF_CC_FLAG(flag_name, accum_var)
  36 dnl
  37 dnl Checks whether the C compiler supports the flag 'flag_name' and, if
  38 dnl found, appends it to the variable 'accum_var'.
  39 dnl
  40 AC_DEFUN([ATF_CC_FLAG], [
  41     AC_LANG_PUSH(C)
  42     AC_MSG_CHECKING(whether ${CC} supports $1)
  43     saved_cflags="${CFLAGS}"
  44     valid_cflag=no
  45     CFLAGS="${CFLAGS} $1"
  46     AC_LINK_IFELSE([int main(void) { return 0; }],
  47                    AC_MSG_RESULT(yes)
  48                    valid_cflag=yes,
  49                    AC_MSG_RESULT(no))
  50     CFLAGS="${saved_cflags}"
  51     AC_LANG_POP()
  52
  53     if test ${valid_cflag} = yes; then
  54         $2="${$2} $1"
  55     fi
  56 ])
  57
  58 dnl
  59 dnl ATF_CC_FLAGS(flag_names, accum_var)
  60 dnl Checks whether the C compiler supports the flags 'flag_names', one by
  61 dnl one, and appends the valid ones to 'accum_var'.
  62 dnl
  63 AC_DEFUN([ATF_CC_FLAGS], [
  64     valid_cflags=
  65     for f in $1; do
  66         ATF_CC_FLAG(${f}, valid_cflags)
  67     done
  68     if test -n "${valid_cflags}"; then
  69         $2="${$2} ${valid_cflags}"
  70     fi
  71 ])
  72
  73 dnl
  74 dnl ATF_CXX_FLAG(flag_name, accum_var)
  75 dnl
  76 dnl Checks whether the C++ compiler supports the flag 'flag_name' and, if
  77 dnl found, appends it to the variable 'accum_var'.
  78 dnl
  79 AC_DEFUN([ATF_CXX_FLAG], [
  80     AC_LANG_PUSH(C++)
  81     AC_MSG_CHECKING(whether ${CXX} supports $1)
  82     saved_cxxflags="${CXXFLAGS}"
  83     valid_cxxflag=no
  84     CXXFLAGS="${CXXFLAGS} $1"
  85     AC_LINK_IFELSE([int main(void) { return 0; }],
  86                    AC_MSG_RESULT(yes)
  87                    valid_cxxflag=yes,
  88                    AC_MSG_RESULT(no))
  89     CXXFLAGS="${saved_cxxflags}"
  90     AC_LANG_POP()
  91
  92     if test ${valid_cxxflag} = yes; then
  93         $2="${$2} $1"
  94     fi
  95 ])
  96
  97 dnl
  98 dnl ATF_CXX_FLAGS(flag_names, accum_var)
  99 dnl Checks whether the C++ compiler supports the flags 'flag_names', one by
 100 dnl one, and appends the valid ones to 'accum_var'.
 101 dnl
 102 AC_DEFUN([ATF_CXX_FLAGS], [
 103     valid_cxxflags=
 104     for f in $1; do
 105         ATF_CXX_FLAG(${f}, valid_cxxflags)
 106     done
 107     if test -n "${valid_cxxflags}"; then
 108         $2="${$2} ${valid_cxxflags}"
 109     fi
 110 ])