external/gpl3/binutils/dist/ld/configure.in

   1 dnl Process this file with autoconf to produce a configure script
   2 dnl
   3 AC_PREREQ(2.59)
   4 AC_INIT
   5 AC_CONFIG_SRCDIR(ldmain.c)
   6
   7 AC_CANONICAL_TARGET
   8 AC_ISC_POSIX
   9
  10 changequote(,)dnl
  11 BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[         ]*\([^  ]*\)[   ]*).*/\1/p' < ${srcdir}/../bfd/configure.in`
  12 changequote([,])dnl
  13 AM_INIT_AUTOMAKE(ld, ${BFD_VERSION})
  14
  15 AC_ARG_WITH(lib-path, [  --with-lib-path=dir1:dir2...  set default LIB_PATH],LIB_PATH=$withval)
  16 AC_ARG_ENABLE(targets,
  17 [  --enable-targets        alternative target configurations],
  18 [case "${enableval}" in
  19   yes | "") AC_MSG_ERROR(enable-targets option must specify target names or 'all')
  20             ;;
  21   no)       enable_targets= ;;
  22   *)        enable_targets=$enableval ;;
  23 esac])dnl
  24 AC_ARG_ENABLE(64-bit-bfd,
  25 [  --enable-64-bit-bfd     64-bit support (on hosts with narrower word sizes)],
  26 [case "${enableval}" in
  27   yes)  want64=true  ;;
  28   no)   want64=false ;;
  29   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
  30 esac],[want64=false])dnl
  31
  32 AC_ARG_WITH(sysroot,
  33 [  --with-sysroot[=DIR] Search for usr/lib et al within DIR.],
  34 [
  35  case ${with_sysroot} in
  36  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
  37  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
  38  esac
  39
  40  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
  41  use_sysroot=yes
  42
  43  if test "x$prefix" = xNONE; then
  44   test_prefix=/usr/local
  45  else
  46   test_prefix=$prefix
  47  fi
  48  if test "x$exec_prefix" = xNONE; then
  49   test_exec_prefix=$test_prefix
  50  else
  51   test_exec_prefix=$exec_prefix
  52  fi
  53  case ${TARGET_SYSTEM_ROOT} in
  54  "${test_prefix}"|"${test_prefix}/"*|\
  55  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
  56  '${prefix}'|'${prefix}/'*|\
  57  '${exec_prefix}'|'${exec_prefix}/'*)
  58    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
  59    TARGET_SYSTEM_ROOT_DEFINE="$t"
  60    ;;
  61  esac
  62 ], [
  63  use_sysroot=no
  64  TARGET_SYSTEM_ROOT=
  65  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
  66 ])
  67 AC_SUBST(use_sysroot)
  68 AC_SUBST(TARGET_SYSTEM_ROOT)
  69 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
  70
  71 AC_ARG_ENABLE([got],
  72 AS_HELP_STRING([--enable-got=<type>],
  73                [GOT handling scheme (target, single, negative, multigot)]),
  74 [case "${enableval}" in
  75   target | single | negative | multigot)  got_handling=$enableval ;;
  76   *)  AC_MSG_ERROR(bad value ${enableval} for --enable-got option) ;;
  77 esac],
  78 [got_handling=target])
  79
  80 case "${got_handling}" in
  81   target)
  82     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_TARGET_DEFAULT],
  83               [Define to choose default GOT handling scheme]) ;;
  84   single)
  85     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_SINGLE],
  86               [Define to choose default GOT handling scheme]) ;;
  87   negative)
  88     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_NEGATIVE],
  89               [Define to choose default GOT handling scheme]) ;;
  90   multigot)
  91     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_MULTIGOT],
  92               [Define to choose default GOT handling scheme]) ;;
  93   *)  AC_MSG_ERROR(bad value ${got_handling} for --enable-got option) ;;
  94 esac
  95
  96 AM_BINUTILS_WARNINGS
  97
  98 AC_CONFIG_HEADERS([config.h:config.in])
  99
 100 if test -z "$target" ; then
 101     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
 102 fi
 103 if test -z "$host" ; then
 104     AC_MSG_ERROR(Unrecognized host system type; please check config.sub.)
 105 fi
 106
 107 # host-specific stuff:
 108
 109 AC_PROG_CC
 110 AC_GNU_SOURCE
 111 AC_USE_SYSTEM_EXTENSIONS
 112 AC_PROG_INSTALL
 113
 114 LT_INIT
 115
 116 ALL_LINGUAS="fr sv tr es da vi zh_CN zh_TW ga fi"
 117 ZW_GNU_GETTEXT_SISTER_DIR
 118 AM_PO_SUBDIRS
 119
 120 AC_EXEEXT
 121
 122 AC_PROG_YACC
 123 AM_PROG_LEX
 124
 125 AM_MAINTAINER_MODE
 126 AM_CONDITIONAL(GENINSRC_NEVER, false)
 127
 128 . ${srcdir}/configure.host
 129
 130 AC_SUBST(HDEFINES)
 131 AC_SUBST(HOSTING_CRT0)
 132 AC_SUBST(HOSTING_LIBS)
 133 AC_SUBST(NATIVE_LIB_DIRS)
 134
 135 AC_CHECK_HEADERS(string.h strings.h stdlib.h unistd.h elf-hints.h limits.h sys/param.h)
 136 AC_CHECK_FUNCS(glob mkstemp realpath sbrk waitpid)
 137 AC_HEADER_DIRENT
 138
 139 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
 140 AC_CACHE_VAL(ld_cv_decl_getopt_unistd_h,
 141 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);])],
 142 ld_cv_decl_getopt_unistd_h=yes, ld_cv_decl_getopt_unistd_h=no)])
 143 AC_MSG_RESULT($ld_cv_decl_getopt_unistd_h)
 144 if test $ld_cv_decl_getopt_unistd_h = yes; then
 145   AC_DEFINE([HAVE_DECL_GETOPT], 1,
 146             [Is the prototype for getopt in <unistd.h> in the expected format?])
 147 fi
 148
 149 BFD_BINARY_FOPEN
 150
 151 AC_CHECK_DECLS([strstr, free, sbrk, getenv, environ])
 152
 153 # Link in zlib if we can.  This is needed only for the bootstrap tests
 154 # right now, since those tests use libbfd, which depends on zlib.
 155 AC_SEARCH_LIBS(zlibVersion, z, [AC_CHECK_HEADERS(zlib.h)])
 156
 157 # When converting linker scripts into strings for use in emulation
 158 # files, use astring.sed if the compiler supports ANSI string
 159 # concatenation, or ostring.sed otherwise.  This is to support the
 160 # broken Microsoft MSVC compiler, which limits the length of string
 161 # constants, while still supporting pre-ANSI compilers which do not
 162 # support string concatenation.
 163 AC_MSG_CHECKING([whether ANSI C string concatenation works])
 164 AC_CACHE_VAL(ld_cv_string_concatenation,
 165 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [char *a = "a" "a";])],
 166   ld_cv_string_concatenation=yes,
 167   ld_cv_string_concatenation=no)])
 168 AC_MSG_RESULT($ld_cv_string_concatenation)
 169 if test "$ld_cv_string_concatenation" = "yes"; then
 170   STRINGIFY=astring.sed
 171 else
 172   STRINGIFY=ostring.sed
 173 fi
 174 AC_SUBST(STRINGIFY)
 175
 176 # target-specific stuff:
 177
 178 all_targets=
 179 EMUL=
 180 all_emuls=
 181 all_emul_extras=
 182 all_libpath=
 183
 184 dnl We need to get an arbitrary number of tdir definitions into
 185 dnl Makefile.  We can't do it using AC_SUBST, because autoconf does
 186 dnl not permit literal newlines in an AC_SUBST variables.  So we use a
 187 dnl file.
 188 rm -f tdirs
 189
 190 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 191 do
 192   if test "$targ_alias" = "all"; then
 193     all_targets=true
 194   else
 195     # Canonicalize the secondary target names.
 196     result=`$ac_config_sub $targ_alias 2>/dev/null`
 197     if test -n "$result"; then
 198         targ=$result
 199     else
 200         targ=$targ_alias
 201     fi
 202
 203     . ${srcdir}/configure.tgt
 204
 205     if test "$targ" = "$target"; then
 206       EMUL=$targ_emul
 207     fi
 208
 209     if test x${want64} = xfalse; then
 210       . ${srcdir}/../bfd/config.bfd
 211     fi
 212
 213     if test x${want64} = xtrue; then
 214       targ_extra_emuls="$targ_extra_emuls $targ64_extra_emuls"
 215       targ_extra_libpath="$targ_extra_libpath $targ64_extra_libpath"
 216     fi
 217
 218     for i in $targ_emul $targ_extra_emuls $targ_extra_libpath; do
 219         case " $all_emuls " in
 220         *" e${i}.o "*) ;;
 221         *)
 222           all_emuls="$all_emuls e${i}.o"
 223           eval result=\$tdir_$i
 224           test -z "$result" && result=$targ_alias
 225           echo tdir_$i=$result >> tdirs
 226           ;;
 227         esac
 228     done
 229
 230     for i in $targ_emul $targ_extra_libpath; do
 231         case " $all_libpath " in
 232         *" ${i} "*) ;;
 233         *)
 234           if test -z "$all_libpath"; then
 235             all_libpath=${i}
 236           else
 237             all_libpath="$all_libpath ${i}"
 238           fi
 239           ;;
 240         esac
 241     done
 242
 243     for i in $targ_extra_ofiles; do
 244         case " $all_emul_extras " in
 245         *" ${i} "*) ;;
 246         *)
 247           all_emul_extras="$all_emul_extras ${i}"
 248           ;;
 249         esac
 250     done
 251   fi
 252 done
 253
 254 AC_SUBST(EMUL)
 255
 256 TDIRS=tdirs
 257 AC_SUBST_FILE(TDIRS)
 258
 259 if test x${all_targets} = xtrue; then
 260   if test x${want64} = xfalse; then
 261     AC_CHECK_SIZEOF(long)
 262     if test "x${ac_cv_sizeof_long}" = "x8"; then
 263       want64=true
 264     fi
 265   fi
 266   if test x${want64} = xtrue; then
 267     EMULATION_OFILES='$(ALL_EMULATIONS) $(ALL_64_EMULATIONS)'
 268   else
 269     EMULATION_OFILES='$(ALL_EMULATIONS)'
 270   fi
 271   EMUL_EXTRA_OFILES='$(ALL_EMUL_EXTRA_OFILES)'
 272 else
 273   EMULATION_OFILES=$all_emuls
 274   EMUL_EXTRA_OFILES=$all_emul_extras
 275 fi
 276 AC_SUBST(EMULATION_OFILES)
 277 AC_SUBST(EMUL_EXTRA_OFILES)
 278 AC_SUBST(LIB_PATH)
 279
 280 EMULATION_LIBPATH=$all_libpath
 281 AC_SUBST(EMULATION_LIBPATH)
 282
 283 if test x${enable_static} = xno; then
 284   TESTBFDLIB="--rpath ../bfd/.libs ../bfd/.libs/libbfd.so"
 285 else
 286   TESTBFDLIB="../bfd/.libs/libbfd.a"
 287 fi
 288 AC_SUBST(TESTBFDLIB)
 289
 290 target_vendor=${target_vendor=$host_vendor}
 291 case "$target_vendor" in
 292   hp) EXTRA_SHLIB_EXTENSION=".sl" ;;
 293   *)  EXTRA_SHLIB_EXTENSION= ;;
 294 esac
 295
 296 case "$target_os" in
 297   lynxos) EXTRA_SHLIB_EXTENSION=".a" ;;
 298 esac
 299
 300 if test x${EXTRA_SHLIB_EXTENSION} != x ; then
 301   AC_DEFINE_UNQUOTED(EXTRA_SHLIB_EXTENSION, "$EXTRA_SHLIB_EXTENSION",
 302    [Additional extension a shared object might have.])
 303 fi
 304
 305 dnl Required by html and install-html
 306 AC_SUBST(datarootdir)
 307 AC_SUBST(docdir)
 308 AC_SUBST(htmldir)
 309
 310 AC_CONFIG_FILES(Makefile po/Makefile.in:po/Make-in)
 311 AC_OUTPUT