gnu/dist/gdb6/gdb/testsuite/gdb.base/logical.exp

   1 # This testcase is part of GDB, the GNU debugger.
   2
   3 # Copyright 1998, 1999, 2004 Free Software Foundation, Inc.
   4
   5 # This program is free software; you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 2 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; if not, write to the Free Software
  17 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  18
  19 # This file was written by Elena Zannoni (ezannoni@cygnus.com)
  20
  21 # Tests for correctenss of logical operators, associativity and
  22 # precedence with integer type variables
  23
  24
  25 if $tracelevel then {
  26     strace $tracelevel
  27 }
  28
  29 #
  30 # test running programs
  31 #
  32 set prms_id 0
  33 set bug_id 0
  34
  35 set testfile "int-type"
  36 set srcfile ${testfile}.c
  37 set binfile ${objdir}/${subdir}/${testfile}
  38
  39 if  { [gdb_compile "${srcdir}/${subdir}/${srcfile}" "${binfile}" executable {debug nowarnings}] != "" } {
  40     gdb_suppress_entire_file "Testcase compile failed, so all tests in this file will automatically fail."
  41 }
  42
  43 if [get_compiler_info ${binfile}] {
  44     return -1;
  45 }
  46
  47 gdb_exit
  48 gdb_start
  49 gdb_reinitialize_dir $srcdir/$subdir
  50 gdb_load ${binfile}
  51
  52
  53 #
  54 # set it up at a breakpoint so we can play with the variable values
  55 #
  56
  57 if ![runto_main] then {
  58     perror "couldn't run to breakpoint"
  59     continue
  60 }
  61
  62 proc evaluate { vars ops } {
  63     for {set vari 0} {$vari < [llength $vars]} {incr vari} {
  64         set var [lindex $vars $vari]
  65         for {set opi 0} {$opi < [llength $ops]} {incr opi} {
  66             set op [lindex [lindex $ops $opi] 0]
  67             set val [lindex [lindex $ops $opi] [expr $vari + 1]]
  68             gdb_test "print $var, $op" " = $val" "evaluate $op; variables $var; expecting $val"
  69         }
  70     }
  71 }
  72
  73 # Unary
  74
  75 evaluate {
  76     {x = 0} {x = 1}
  77 } {
  78     { {x}   0 1 }
  79     { {!x}  1 0 }
  80     { {!!x} 0 1 }
  81 }
  82
  83 # Binary (with unary)
  84
  85 evaluate {
  86     {x = 0, y = 0} {x = 0, y = 1} {x = 1, y = 0} {x = 1, y = 1}
  87 } {
  88     { {x && y}   0 0 0 1 }
  89     { {!x && y}  0 1 0 0 }
  90     { {x && !y}  0 0 1 0 }
  91     { {!x && !y} 1 0 0 0 }
  92
  93     { {x || y}   0 1 1 1 }
  94     { {!x || y}  1 1 0 1 }
  95     { {x || !y}  1 0 1 1 }
  96     { {!x || !y} 1 1 1 0 }
  97
  98     { {x < y}    0 1 0 0 }
  99     { {x <= y}   1 1 0 1 }
 100     { {x == y}   1 0 0 1 }
 101     { {x != y}   0 1 1 0 }
 102     { {x >= y}   1 0 1 1 }
 103     { {x > y}    0 0 1 0 }
 104 }
 105
 106 # Full table of &&, || combinations, followed by random mix of unary ops
 107
 108 evaluate {
 109     {x = 0, y = 0, z = 0} {x = 0, y = 0, z = 1} {x = 0, y = 1, z = 0} {x = 0, y = 1, z = 1}
 110     {x = 1, y = 0, z = 0} {x = 1, y = 0, z = 1} {x = 1, y = 1, z = 0} {x = 1, y = 1, z = 1}
 111 } {
 112     { {x && y && z}    0 0 0 0  0 0 0 1 }
 113     { {x || y && z}    0 0 0 1  1 1 1 1 }
 114     { {x && y || z}    0 1 0 1  0 1 1 1 }
 115     { {x || y || z}    0 1 1 1  1 1 1 1 }
 116
 117     { {x || !y && z}   0 1 0 0  1 1 1 1 }
 118     { {!x || y && z}   1 1 1 1  0 0 0 1 }
 119     { {!x || y && !z}  1 1 1 1  0 0 1 0 }
 120 }
 121
 122 # More complex operations
 123
 124 evaluate {
 125     {x = 1, y = 2, w = 3, z = 3}
 126     {x = 1, y = 2, w = 1, z = 3}
 127     {x = 2, y = 2, w = 2, z = 3}
 128 } {
 129     { {x > y || w == z}   1 0 0 }
 130     { {x >= y && w != z}  0 0 1 }
 131     { {! x > y || w + z}  1 1 1 }
 132 }