gnu/dist/gettext/gettext-tools/m4/csharpexec.m4

   1 # csharpexec.m4 serial 1 (gettext-0.14)
   2 dnl Copyright (C) 2003-2004 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 # Prerequisites of csharpexec.sh.
   8 # Sets HAVE_CSHARPEXEC to nonempty if csharpexec.sh will work.
   9
  10 AC_DEFUN([gt_CSHARPEXEC],
  11 [
  12   AC_REQUIRE([gt_CSHARP_CHOICE])
  13   AC_MSG_CHECKING([for C[#] program execution engine])
  14   AC_EGREP_CPP(yes, [
  15 #if defined _WIN32 || defined __WIN32__ || defined __EMX__ || defined __DJGPP__
  16   yes
  17 #endif
  18 ], MONO_PATH_SEPARATOR=';', MONO_PATH_SEPARATOR=':')
  19   HAVE_CSHARPEXEC=1
  20   pushdef([AC_MSG_CHECKING],[:])dnl
  21   pushdef([AC_CHECKING],[:])dnl
  22   pushdef([AC_MSG_RESULT],[:])dnl
  23   AC_CHECK_PROG(HAVE_ILRUN_IN_PATH, ilrun, yes)
  24   AC_CHECK_PROG(HAVE_MONO_IN_PATH, mono, yes)
  25   popdef([AC_MSG_RESULT])dnl
  26   popdef([AC_CHECKING])dnl
  27   popdef([AC_MSG_CHECKING])dnl
  28   for impl in "$CSHARP_CHOICE" pnet mono no; do
  29     case "$impl" in
  30       pnet)
  31         if test -n "$HAVE_ILRUN_IN_PATH" \
  32            && ilrun --version >/dev/null 2>/dev/null; then
  33           HAVE_ILRUN=1
  34           ac_result="ilrun"
  35           break
  36         fi
  37         ;;
  38       mono)
  39         if test -n "$HAVE_MONO_IN_PATH" \
  40            && mono --version >/dev/null 2>/dev/null; then
  41           HAVE_MONO=1
  42           ac_result="mono"
  43           break
  44         fi
  45         ;;
  46       no)
  47         HAVE_CSHARPEXEC=
  48         ac_result="no"
  49         break
  50         ;;
  51     esac
  52   done
  53   AC_MSG_RESULT([$ac_result])
  54   AC_SUBST(MONO_PATH)
  55   AC_SUBST(MONO_PATH_SEPARATOR)
  56   AC_SUBST(HAVE_ILRUN)
  57   AC_SUBST(HAVE_MONO)
  58 ])