gnu/dist/gettext/gettext-tools/m4/libgrep.m4

   1 # libgrep.m4 serial 1 (gettext-0.14.2)
   2 dnl Copyright (C) 2005 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gt_LIBGREP],
   8 [
   9   AC_REQUIRE([AM_STDBOOL_H])
  10   AC_REQUIRE([gl_FUNC_MBRTOWC])
  11   m4_pushdef([AC_LIBOBJ], m4_defn([gt_LIBGREP_OBJ]))
  12   m4_pushdef([AC_REPLACE_FUNCS], m4_defn([gt_LIBGREP_REPLACE_FUNCS]))
  13   gl_HARD_LOCALE
  14   gl_FUNC_MEMCHR
  15   gl_FUNC_STRDUP
  16   gl_INCLUDED_REGEX([libgrep/regex.c])
  17   m4_popdef([AC_REPLACE_FUNCS])
  18   m4_popdef([AC_LIBOBJ])
  19   AC_SUBST([LIBGREPOBJS])
  20 ])
  21
  22 # Like AC_LIBOBJ, except that the module name goes into LIBGREPOBJS
  23 # instead of into LIBOBJS.
  24 AC_DEFUN([gt_LIBGREP_OBJ],
  25   [LIBGREPOBJS="$LIBGREPOBJS $1.$ac_objext"])
  26
  27 # Like AC_REPLACE_FUNCS, except that the module name goes into LIBGREPOBJS
  28 # instead of into LIBOBJS.
  29 AC_DEFUN([gt_LIBGREP_REPLACE_FUNCS],
  30   [AC_CHECK_FUNCS([$1], , [gt_LIBGREP_OBJ($ac_func)])])