gnu/dist/gettext/gettext-tools/m4/stpncpy.m4

   1 # stpncpy.m4 serial 3
   2 dnl Copyright (C) 2002-2003, 2005 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_STPNCPY],
   8 [
   9   dnl Persuade glibc <string.h> to declare stpncpy().
  10   AC_REQUIRE([AC_GNU_SOURCE])
  11
  12   dnl Both glibc and AIX (4.3.3, 5.1) have an stpncpy() function
  13   dnl declared in <string.h>. Its side effects are the same as those
  14   dnl of strncpy():
  15   dnl      stpncpy (dest, src, n)
  16   dnl overwrites dest[0..n-1], min(strlen(src),n) bytes coming from src,
  17   dnl and the remaining bytes being NULs.  However, the return value is
  18   dnl   in glibc:   dest + min(strlen(src),n)
  19   dnl   in AIX:     dest + max(0,n-1)
  20   dnl Only the glibc return value is useful in practice.
  21
  22   AC_CACHE_CHECK([for working stpncpy], gl_cv_func_stpncpy, [
  23     AC_TRY_RUN([
  24 #include <stdlib.h>
  25 extern char *stpncpy (char *dest, const char *src, size_t n);
  26 int main () {
  27   const char *src = "Hello";
  28   char dest[10];
  29   /* AIX 4.3.3 and AIX 5.1 stpncpy() returns dest+1 here.  */
  30   strcpy (dest, "\377\377\377\377\377\377");
  31   if (stpncpy (dest, src, 2) != dest + 2) exit(1);
  32   /* AIX 4.3.3 and AIX 5.1 stpncpy() returns dest+4 here.  */
  33   strcpy (dest, "\377\377\377\377\377\377");
  34   if (stpncpy (dest, src, 5) != dest + 5) exit(1);
  35   /* AIX 4.3.3 and AIX 5.1 stpncpy() returns dest+6 here.  */
  36   strcpy (dest, "\377\377\377\377\377\377");
  37   if (stpncpy (dest, src, 7) != dest + 5) exit(1);
  38   exit(0);
  39 }
  40 ], gl_cv_func_stpncpy=yes, gl_cv_func_stpncpy=no,
  41   [AC_EGREP_CPP([Thanks for using GNU], [
  42 #include <features.h>
  43 #ifdef __GNU_LIBRARY__
  44   Thanks for using GNU
  45 #endif
  46 ], gl_cv_func_stpncpy=yes, gl_cv_func_stpncpy=no)])])
  47
  48   if test $gl_cv_func_stpncpy = yes; then
  49     AC_DEFINE(HAVE_STPNCPY, 1,
  50       [Define if you have the stpncpy() function and it works.])
  51   else
  52     AC_LIBOBJ([stpncpy])
  53     gl_PREREQ_STPNCPY
  54   fi
  55 ])
  56
  57 # Prerequisites of lib/stpncpy.c.
  58 AC_DEFUN([gl_PREREQ_STPNCPY], [
  59   :
  60 ])
  61