lib/libc/arch/hppa/string/strlcpy.S

   1 /*      $NetBSD: strlcpy.S,v 1.2 2003/10/06 05:30:21 matt Exp $ */
   2
   3 /*
   4  * Copyright (c) 2002 The NetBSD Foundation, Inc.
   5  * All rights reserved.
   6  *
   7  * This code is derived from software contributed to The NetBSD Foundation
   8  * by Matthew Fredette.
   9  *
  10  * Redistribution and use in source and binary forms, with or without
  11  * modification, are permitted provided that the following conditions
  12  * are met:
  13  * 1. Redistributions of source code must retain the above copyright
  14  *    notice, this list of conditions and the following disclaimer.
  15  * 2. Redistributions in binary form must reproduce the above copyright
  16  *    notice, this list of conditions and the following disclaimer in the
  17  *    documentation and/or other materials provided with the distribution.
  18  *
  19  * THIS SOFTWARE IS PROVIDED BY THE NETBSD FOUNDATION, INC. AND CONTRIBUTORS
  20  * ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
  21  * TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
  22  * PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE FOUNDATION OR CONTRIBUTORS
  23  * BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
  24  * CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
  25  * SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
  26  * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
  27  * CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
  28  * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
  29  * POSSIBILITY OF SUCH DAMAGE.
  30  */
  31
  32 #include <machine/asm.h>
  33
  34 #if defined(LIBC_SCCS) && !defined(lint)
  35         RCSID("$NetBSD: strlcpy.S,v 1.2 2003/10/06 05:30:21 matt Exp $")
  36 #endif /* LIBC_SCCS and not lint */
  37
  38 /*
  39  * size_t strlcpy(char *dst, const char *src, size_t size);
  40  */
  41 LEAF_ENTRY(_strlcpy)
  42         .weak strlcpy
  43         strlcpy = _strlcpy
  44
  45         /* Always load the first byte of the source string. */
  46         ldbs,ma         1(%arg1), %r1
  47
  48         /*
  49          * If our dst buffer is zero bytes, branch immediately
  50          * to the code that counts the (remaining) length
  51          * of the src string.
  52          */
  53         comb,=          %r0, %arg2, $strlcpy_dst_done
  54         copy            %arg1, %ret0
  55
  56         /*
  57          * If our dst buffer is one byte, branch immediately
  58          * to the code that NUL-terminates the dst buffer and
  59          * counts the (remaining) length of the src string.
  60          */
  61         addib,=,n       -1, %arg2, $strlcpy_dst_full
  62
  63         /*
  64          * Loop copying bytes.  At the top of this loop,
  65          * %arg2 is always the number of bytes we can still
  66          * store, and %r1 holds the next byte to store.
  67          */
  68 $strlcpy_loop:
  69         comb,=          %r0, %r1, $strlcpy_exit
  70         stbs,ma         %r1, 1(%arg0)
  71         addib,<>        -1, %arg2, $strlcpy_loop
  72         ldbs,ma         1(%arg1), %r1
  73
  74 $strlcpy_dst_full:
  75         stbs,ma         %r0, 1(%arg0)
  76
  77 $strlcpy_dst_done:
  78         comb,<>,n       %r0, %r1, $strlcpy_dst_done
  79         ldbs,ma         1(%arg1), %r1
  80
  81 $strlcpy_exit:
  82         bv              %r0(%rp)
  83         sub             %arg1, %ret0, %ret0
  84 EXIT(strlcpy)