lib/libc/arch/m68k/gen/_setjmp.S

   1 /*      $NetBSD: _setjmp.S,v 1.6 1999/10/25 23:48:09 thorpej Exp $      */
   2
   3 /*-
   4  * Copyright (c) 1990 The Regents of the University of California.
   5  * All rights reserved.
   6  *
   7  * This code is derived from software contributed to Berkeley by
   8  * the Systems Programming Group of the University of Utah Computer
   9  * Science Department.
  10  *
  11  * Redistribution and use in source and binary forms, with or without
  12  * modification, are permitted provided that the following conditions
  13  * are met:
  14  * 1. Redistributions of source code must retain the above copyright
  15  *    notice, this list of conditions and the following disclaimer.
  16  * 2. Redistributions in binary form must reproduce the above copyright
  17  *    notice, this list of conditions and the following disclaimer in the
  18  *    documentation and/or other materials provided with the distribution.
  19  * 3. Neither the name of the University nor the names of its contributors
  20  *    may be used to endorse or promote products derived from this software
  21  *    without specific prior written permission.
  22  *
  23  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  24  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  25  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  26  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  27  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  28  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  29  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  30  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  31  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  32  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  33  * SUCH DAMAGE.
  34  */
  35
  36 #include <machine/asm.h>
  37
  38 #if defined(LIBC_SCCS) && !defined(lint)
  39 #if 0
  40         RCSID("from: @(#)_setjmp.s      5.1 (Berkeley) 5/12/90")
  41 #else
  42         RCSID("$NetBSD: _setjmp.S,v 1.6 1999/10/25 23:48:09 thorpej Exp $")
  43 #endif
  44 #endif /* LIBC_SCCS and not lint */
  45
  46 /*
  47  * C library -- _setjmp, _longjmp
  48  *
  49  *      _longjmp(a,v)
  50  * will generate a "return(v)" from
  51  * the last call to
  52  *      _setjmp(a)
  53  * by restoring registers from the stack,
  54  * The previous signal state is NOT restored.
  55  */
  56
  57 ENTRY(_setjmp)
  58         movl    %sp@(4),%a0     /* save area pointer */
  59         clrl    %a0@+           /* no old onstack */
  60         clrl    %a0@+           /* no old sigmask */
  61         movl    %sp,%a0@+       /* save old SP */
  62         movl    %a6,%a0@+       /* save old FP */
  63         clrl    %a0@+           /* no old AP */
  64         movl    %sp@,%a0@+      /* save old PC */
  65         clrl    %a0@+           /* clear PS */
  66         moveml  #0x3CFC,%a0@    /* save other non-scratch regs */
  67         clrl    %d0             /* return zero */
  68         rts
  69
  70 ENTRY(_longjmp)
  71         movl    %sp@(4),%a0     /* save area pointer */
  72         addql   #8,%a0          /* skip onstack/sigmask */
  73         tstl    %a0@            /* ensure non-zero SP */
  74         jeq     botch           /* oops! */
  75         movl    %sp@(8),%d0     /* grab return value */
  76         jne     ok              /* non-zero ok */
  77         moveq   #1,%d0          /* else make non-zero */
  78 ok:
  79         movl    %a0@+,%sp       /* restore SP */
  80         movl    %a0@+,%a6       /* restore FP */
  81         addql   #4,%a0          /* skip AP */
  82         movl    %a0@+,%sp@      /* restore PC */
  83         moveml  %a0@(4),#0x3CFC /* restore non-scratch regs */
  84         rts
  85
  86 botch:
  87         jbsr    PIC_PLT(_C_LABEL(longjmperror))
  88         stop    #0