lib/libc/arch/m68k/sys/__vfork14.S

   1 /*      $NetBSD: __vfork14.S,v 1.8 2000/12/07 14:12:49 scw Exp $        */
   2
   3 /*-
   4  * Copyright (c) 1990 The Regents of the University of California.
   5  * All rights reserved.
   6  *
   7  * This code is derived from software contributed to Berkeley by
   8  * the Systems Programming Group of the University of Utah Computer
   9  * Science Department.
  10  *
  11  * Redistribution and use in source and binary forms, with or without
  12  * modification, are permitted provided that the following conditions
  13  * are met:
  14  * 1. Redistributions of source code must retain the above copyright
  15  *    notice, this list of conditions and the following disclaimer.
  16  * 2. Redistributions in binary form must reproduce the above copyright
  17  *    notice, this list of conditions and the following disclaimer in the
  18  *    documentation and/or other materials provided with the distribution.
  19  * 3. Neither the name of the University nor the names of its contributors
  20  *    may be used to endorse or promote products derived from this software
  21  *    without specific prior written permission.
  22  *
  23  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  24  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  25  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  26  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  27  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  28  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  29  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  30  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  31  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  32  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  33  * SUCH DAMAGE.
  34  */
  35
  36 #include "SYS.h"
  37
  38 #if defined(LIBC_SCCS) && !defined(lint)
  39 #if 0
  40         RCSID("from: @(#)Ovfork.s       5.1 (Berkeley) 5/12/90")
  41 #else
  42         RCSID("$NetBSD: __vfork14.S,v 1.8 2000/12/07 14:12:49 scw Exp $")
  43 #endif
  44 #endif /* LIBC_SCCS and not lint */
  45
  46 /*
  47  * @(#)vfork.s  4.1 (Berkeley) 12/21/80
  48  * C library -- vfork
  49  */
  50
  51 /*
  52  * pid = vfork();
  53  *
  54  * d1 == 0 in parent process, d1 == 1 in child process.
  55  * d0 == pid of child in parent, d0 == pid of parent in child.
  56  *
  57  * trickery here, due to keith sklower, uses ret to clear the stack,
  58  * and then returns with a jump indirect, since only one person can return
  59  * with a ret off this stack... we do the ret before we vfork!
  60  */
  61
  62 ENTRY(__vfork14)
  63         movl    %sp@+,%a1
  64         movl    #SYS___vfork14,%d0
  65         trap    #0
  66         jcs     err
  67         subql   #1,%d1  /* from 1 to 0 in child, 0 to -1 in parent */
  68         andl    %d1,%d0
  69         jmp     %a1@
  70 err:
  71 #ifdef  _REENTRANT
  72         .globl  _C_LABEL(__errno)
  73         movl    %a1,%sp@-
  74         movl    %d0,%sp@-
  75 #if defined(PIC) && !defined(__ELF__)
  76         movl    #_C_LABEL(_GLOBAL_OFFSET_TABLE_),%a1
  77         lea     %pc@(0,a1:l),%a1
  78         movl    %a1@(_C_LABEL(__errno):l),%a1
  79         jsr     %a1@
  80 #else
  81         jbsr    PIC_PLT(_C_LABEL(__errno))
  82 #endif  /* PIC */
  83 #ifdef  __SVR4_ABI__
  84         movl    %sp@+,%a0@
  85 #else
  86         movl    %d0,%a1
  87         movl    %sp@+,%a1@
  88 #endif
  89         movl    %sp@+,%a1
  90 #else
  91         .globl  _C_LABEL(errno)
  92 #ifdef  PIC
  93 #ifdef  __ELF__
  94         lea     %pc@(_GLOBAL_OFFSET_TABLE_@GOTPC),%a0
  95         movl    %a0@(_C_LABEL(errno)@GOT:w),%a0
  96 #else
  97         movl    #_C_LABEL(_GLOBAL_OFFSET_TABLE_),%a0
  98         lea     %pc@(0,a0:l),%a0
  99         movl    %a0@(_C_LABEL(errno):w),%a0
 100 #endif
 101         movl    %d0,%a0@
 102 #else
 103         movl    %d0,_C_LABEL(errno)
 104 #endif  /* PIC */
 105 #endif  /* _REENTRANT */
 106         moveq   #-1,%d0
 107         jmp     %a1@