lib/libc/arch/powerpc/gen/_setjmp.S

   1 /*      $NetBSD: _setjmp.S,v 1.1 1997/03/29 20:55:53 thorpej Exp $      */
   2
   3 #include <machine/asm.h>
   4
   5 #if defined(LIBC_SCCS)
   6         .text
   7         .asciz "$NetBSD: _setjmp.S,v 1.1 1997/03/29 20:55:53 thorpej Exp $"
   8 #endif
   9
  10 /*
  11  * C library -- _setjmp, _longjmp
  12  *
  13  *      _longjmp(a,v)
  14  * will generate a "return(v?v:1)" from the last call to
  15  *      _setjmp(a)
  16  * by restoring registers from the stack.
  17  * The previous signal state is NOT restored.
  18  */
  19
  20 ENTRY(_setjmp)
  21         mflr    %r11                    /* save return address */
  22         mfcr    %r12                    /* save condition register */
  23         mr      %r10,%r1                /* save stack pointer */
  24         mr      %r9,%r2                 /* save GPR2 (not needed) */
  25         stmw    %r9,8(%r3)              /* save r9..r31 */
  26         li      %r3,0                   /* indicate success */
  27         blr                             /* return */
  28
  29 ENTRY(_longjmp)
  30         lmw     %r9,8(%r3)              /* save r9..r31 */
  31         mtlr    %r11                    /* restore LR */
  32         mtcr    %r12                    /* restore CR */
  33         mr      %r2,%r9                 /* restore GPR2 (not needed) */
  34         mr      %r1,%r10                /* restore stack */
  35         or.     %r3,%r4,%r4             /* get return value */
  36         bnelr                           /* return if not 0 */
  37         li      %r3,1                   /* what's the point? */
  38         blr                             /* return */