lib/libc/arch/sh3/gen/setjmp.S

   1 /*      $NetBSD: setjmp.S,v 1.9 2006/01/05 04:18:01 uwe Exp $   */
   2
   3 /*-
   4  * Copyright (c) 1990 The Regents of the University of California.
   5  * All rights reserved.
   6  *
   7  * This code is derived from software contributed to Berkeley by
   8  * William Jolitz.
   9  *
  10  * Redistribution and use in source and binary forms, with or without
  11  * modification, are permitted provided that the following conditions
  12  * are met:
  13  * 1. Redistributions of source code must retain the above copyright
  14  *    notice, this list of conditions and the following disclaimer.
  15  * 2. Redistributions in binary form must reproduce the above copyright
  16  *    notice, this list of conditions and the following disclaimer in the
  17  *    documentation and/or other materials provided with the distribution.
  18  * 3. Neither the name of the University nor the names of its contributors
  19  *    may be used to endorse or promote products derived from this software
  20  *    without specific prior written permission.
  21  *
  22  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  23  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  24  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  25  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  26  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  27  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  28  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  29  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  30  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  31  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  32  * SUCH DAMAGE.
  33  *
  34  *      from: @(#)setjmp.s      5.1 (Berkeley) 4/23/90
  35  */
  36
  37 #include <machine/asm.h>
  38 #include <machine/setjmp.h>
  39
  40 #if defined(LIBC_SCCS)
  41         RCSID("$NetBSD: setjmp.S,v 1.9 2006/01/05 04:18:01 uwe Exp $")
  42 #endif
  43
  44 /*
  45  * C library -- setjmp, longjmp
  46  *
  47  *      longjmp(a,v)
  48  * will generate a "return(v)" from the last call to
  49  *      setjmp(a)
  50  * by restoring registers from the stack.
  51  * The previous signal state is restored.
  52  */
  53
  54 ENTRY(__setjmp14)
  55         PIC_PROLOGUE(.L_got_1)
  56         sts.l   pr, @-sp
  57         mov.l   r4, @-sp
  58
  59         mov.l   .L___sigprocmask14_1, r0
  60         mov     r4, r6
  61         mov     #1, r4                  /* how = SIG_BLOCK */
  62         mov     #0, r5                  /* new = NULL */
  63 1:      CALL    r0
  64          add    #(_JB_SIGMASK * 4), r6  /* old = &sigmask */
  65
  66         mov.l   @sp+, r4
  67         lds.l   @sp+, pr
  68         PIC_EPILOGUE
  69
  70         /* identical to _setjmp except that _JB_HAS_MASK is non-zero */
  71         add     #((_JB_HAS_MASK + 1) * 4), r4
  72         mov     #1, r0
  73         mov.l   r0, @-r4                /* has signal mask */
  74         mov.l   r15, @-r4
  75         mov.l   r14, @-r4
  76         mov.l   r13, @-r4
  77         mov.l   r12, @-r4
  78         mov.l   r11, @-r4
  79         mov.l   r10, @-r4
  80         mov.l   r9, @-r4
  81         mov.l   r8, @-r4
  82         sts.l   pr, @-r4
  83         rts
  84          xor    r0, r0
  85
  86         .align  2
  87 .L_got_1:               PIC_GOT_DATUM
  88 .L___sigprocmask14_1:   CALL_DATUM(_C_LABEL(__sigprocmask14), 1b)
  89         SET_ENTRY_SIZE(__setjmp14)
  90
  91
  92 ENTRY(__longjmp14)
  93         /* we won't return here, so we don't need to save pr and r12 */
  94         PIC_PROLOGUE_NOSAVE(.L_got_2)
  95         mov.l   r5, @-sp
  96         mov.l   r4, @-sp
  97
  98         mov.l   .L___sigprocmask14_2, r0
  99         mov     r4, r5
 100         mov     #3, r4                  /* how = SIG_SETMASK */
 101         add     #(_JB_SIGMASK * 4), r5  /* new = &sigmask */
 102 1:      CALL    r0
 103          mov    #0, r6                  /* old = NULL */
 104
 105         mov.l   @sp+, r4
 106         mov.l   @sp+, r5
 107
 108         /* identical to _longjmp */
 109         lds.l   @r4+, pr
 110         mov.l   @r4+, r8
 111         mov.l   @r4+, r9
 112         mov.l   @r4+, r10
 113         mov.l   @r4+, r11
 114         mov.l   @r4+, r12
 115         mov.l   @r4+, r13
 116         mov.l   @r4+, r14
 117         mov.l   @r4+, r15
 118
 119         mov     r5, r0
 120         tst     r0, r0  /* make sure return value is non-zero */
 121         bf      .L0
 122         add     #1, r0
 123 .L0:
 124         rts
 125          nop
 126
 127         .align  2
 128 .L_got_2:               PIC_GOT_DATUM
 129 .L___sigprocmask14_2:   CALL_DATUM(_C_LABEL(__sigprocmask14), 1b)
 130         SET_ENTRY_SIZE(__longjmp14)