lib/libc/arch/vax/gen/__setjmp14.S

   1 /*
   2  * Copyright (c) 1983, 1993
   3  *      The Regents of the University of California.  All rights reserved.
   4  *
   5  * Redistribution and use in source and binary forms, with or without
   6  * modification, are permitted provided that the following conditions
   7  * are met:
   8  * 1. Redistributions of source code must retain the above copyright
   9  *    notice, this list of conditions and the following disclaimer.
  10  * 2. Redistributions in binary form must reproduce the above copyright
  11  *    notice, this list of conditions and the following disclaimer in the
  12  *    documentation and/or other materials provided with the distribution.
  13  * 3. Neither the name of the University nor the names of its contributors
  14  *    may be used to endorse or promote products derived from this software
  15  *    without specific prior written permission.
  16  *
  17  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  18  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  19  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  20  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  21  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  22  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  23  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  24  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  25  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  26  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  27  * SUCH DAMAGE.
  28  */
  29
  30 #if defined(LIBC_SCCS) && !defined(lint)
  31         /* .asciz "@(#)setjmp.s 8.1 (Berkeley) 6/4/93" */
  32         .asciz "$NetBSD: __setjmp14.S,v 1.9 2004/03/21 18:19:52 matt Exp $"
  33 #endif /* LIBC_SCCS and not lint */
  34
  35 /*
  36  * C library -- setjmp, longjmp
  37  *
  38  *      longjmp(a,v)
  39  * will generate a "return(v)" from
  40  * the last call to
  41  *      setjmp(a)
  42  * by restoring registers from the stack,
  43  * and a struct sigcontext, see <signal.h>
  44  */
  45
  46 #include "DEFS.h"
  47 #include "assym.h"
  48
  49 ENTRY(__setjmp14, R6)
  50         movl    4(%ap),%r2              # construct sigcontext
  51         subl2   $12,%sp                 # space for current struct sigstack
  52         pushl   %sp                     # get current values
  53         pushl   $0                      # no new values
  54         calls   $4,_C_LABEL(__sigaltstack14) # pop args plus signal stack value
  55         movl    4(%ap),%r2              # construct sigcontext
  56         movl    (%sp)+,(%r2)            # save onsigstack status of caller
  57         pushal  28(%r2)
  58         pushl   $0
  59         pushl   $0
  60         calls   $3,_C_LABEL(__sigprocmask14) # get signal mask
  61         addl3   $8,4(%ap),%r2           # point to sp in signal context
  62         clrl    %r0                     # assume no stack arguments
  63         bbc     $13,6(%fp),1f           # handle callg
  64         addl3   $1,(%ap),%r0            # get argument count +1 if calls
  65 1:      moval   24(%fp)[%r0],(%r2)+     # save sp of caller
  66         movl    12(%fp),(%r2)+          # save frame pointer of caller
  67         movl    8(%fp),(%r2)+           # save argument pointer of caller
  68         movl    16(%fp),(%r2)+          # save pc of caller
  69         movpsl  (%r2)                   # save current psl
  70         movw    4(%fp),(%r2)            # save psw of caller
  71 #ifdef __ELF__
  72         addl3   $SC_LEN,4(%ap),%r2      # point to past signal context
  73         movq    %r6,(%r2)+              # save r6/r7
  74         movq    %r8,(%r2)+              # save r8/r9
  75         movq    %r10,(%r2)+             # save r10/r11
  76 #endif
  77         clrl    %r0
  78         ret
  79
  80 #ifndef __ELF__
  81 ENTRY(__longjmp14, 0)
  82         movl    8(%ap),%r0              # return(v)
  83         movl    4(%ap),%r1              # fetch buffer
  84         tstl    12(%r1)                 # is fp non-null?
  85         beql    botch
  86
  87 #ifdef __ELF__
  88         moval   $SC_LEN(%r1),%r2        # get ptr to saved registers
  89         movq    (%r2)+,%r6              # restore r6/r7
  90         movq    (%r2)+,%r8              # restore r8/r9
  91         movq    (%r2)+,%r10             # restore r10/r11
  92 #else
  93 loop:
  94         cmpl    12(%r1),%fp             # are we there yet?
  95         beql    done
  96         blssu   botch
  97         moval   20(%fp),%r2
  98         blbc    6(%fp),1f               # was %r0 saved?
  99         movl    %r0,(%r2)+
 100 1:
 101         bbc     $1,6(%fp),2f            # was %r1 saved?
 102         movl    %r1,(%r2)
 103 2:
 104         movab   loop,16(%fp)
 105         ret                             # pop another frame
 106
 107 done:
 108 #endif /* !__ELF__ */
 109         pushl   %r1                     # pointer to sigcontext
 110         calls   $1,_C_LABEL(__sigreturn14) # restore previous context
 111                                         # we should never return
 112 botch:
 113         calls   $0,_C_LABEL(longjmperror)
 114         halt
 115 #endif