lib/libc/compat/arch/arm/gen/compat_setjmp.S

   1 /*      $NetBSD: setjmp.S,v 1.6 2004/08/21 11:20:10 rearnsha Exp $      */
   2
   3 /*
   4  * Copyright (c) 1997 Mark Brinicombe
   5  * All rights reserved.
   6  *
   7  * Redistribution and use in source and binary forms, with or without
   8  * modification, are permitted provided that the following conditions
   9  * are met:
  10  * 1. Redistributions of source code must retain the above copyright
  11  *    notice, this list of conditions and the following disclaimer.
  12  * 2. Redistributions in binary form must reproduce the above copyright
  13  *    notice, this list of conditions and the following disclaimer in the
  14  *    documentation and/or other materials provided with the distribution.
  15  * 3. All advertising materials mentioning features or use of this software
  16  *    must display the following acknowledgement:
  17  *      This product includes software developed by Mark Brinicombe
  18  * 4. Neither the name of the University nor the names of its contributors
  19  *    may be used to endorse or promote products derived from this software
  20  *    without specific prior written permission.
  21  *
  22  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR AND CONTRIBUTORS ``AS IS'' AND
  23  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  24  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  25  * ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE LIABLE
  26  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  27  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  28  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  29  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  30  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  31  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  32  * SUCH DAMAGE.
  33  */
  34
  35 #include <machine/asm.h>
  36 #include <machine/setjmp.h>
  37
  38 /*
  39  * C library -- setjmp, longjmp
  40  *
  41  *      longjmp(a,v)
  42  * will generate a "return(v)" from the last call to
  43  *      setjmp(a)
  44  * by restoring registers from the stack.
  45  * The previous signal state is restored.
  46  */
  47
  48 ENTRY(setjmp)
  49         /* Block all signals and retrieve the old signal mask */
  50         stmfd   sp!, {r0, r14}
  51         mov     r0, #0x00000000
  52
  53         bl      PIC_SYM(_C_LABEL(sigblock), PLT)
  54         mov     r1, r0
  55
  56         ldmfd   sp!, {r0, r14}
  57
  58         /* Store signal mask */
  59         str     r1, [r0, #(25 * 4)]
  60
  61         ldr     r1, .Lsetjmp_magic
  62         str     r1, [r0], #4
  63
  64 #ifdef SOFTFLOAT
  65         add     r0, r0, #52
  66 #else
  67         /* Store fp registers */
  68         sfm     f4, 4, [r0], #48
  69         /* Store fpsr */
  70         rfs     r1
  71         str     r1, [r0], #0x0004
  72 #endif  /*SOFTFLOAT*/
  73         /* Store integer registers */
  74         stmia   r0, {r4-r14}
  75         mov     r0, #0x00000000
  76         RET
  77
  78 .Lsetjmp_magic:
  79         .word   _JB_MAGIC_SETJMP
  80
  81
  82 ENTRY(longjmp)
  83         ldr     r2, .Lsetjmp_magic
  84         ldr     r3, [r0]
  85         teq     r2, r3
  86         bne     botch
  87
  88         /* Fetch signal mask */
  89         ldr     r2, [r0, #(25 * 4)]
  90
  91         /* Set signal mask */
  92         stmfd   sp!, {r0, r1, r14}
  93         sub     sp, sp, #4      /* align the stack */
  94
  95         mov     r0, r2
  96         bl      PIC_SYM(_C_LABEL(sigsetmask), PLT)
  97
  98         add     sp, sp, #4      /* unalign the stack */
  99         ldmfd   sp!, {r0, r1, r14}
 100
 101         add     r0, r0, #4
 102 #ifdef SOFTFLOAT
 103         add     r0, r0, #52
 104 #else
 105         /* Restore fp registers */
 106         lfm     f4, 4, [r0], #48
 107         /* Restore FPSR */
 108         ldr     r4, [r0], #0x0004
 109         wfs     r4
 110 #endif  /* SOFTFLOAT */
 111         /* Restore integer registers */
 112         ldmia   r0, {r4-r14}
 113
 114         /* Validate sp and r14 */
 115         teq     sp, #0
 116         teqne   r14, #0
 117         beq     botch
 118
 119         /* Set return value */
 120
 121         mov     r0, r1
 122         teq     r0, #0x00000000
 123         moveq   r0, #0x00000001
 124         RET
 125
 126         /* validation failed, die die die. */
 127 botch:
 128         bl      PIC_SYM(_C_LABEL(longjmperror), PLT)
 129         bl      PIC_SYM(_C_LABEL(abort), PLT)
 130         b       . - 8           /* Cannot get here */