lib/libc/compat/arch/i386/gen/compat_sigsetjmp.S

   1 /*      $NetBSD: sigsetjmp.S,v 1.15 2003/08/07 16:42:07 agc Exp $       */
   2
   3 /*-
   4  * Copyright (c) 1990 The Regents of the University of California.
   5  * All rights reserved.
   6  *
   7  * This code is derived from software contributed to Berkeley by
   8  * William Jolitz.
   9  *
  10  * Redistribution and use in source and binary forms, with or without
  11  * modification, are permitted provided that the following conditions
  12  * are met:
  13  * 1. Redistributions of source code must retain the above copyright
  14  *    notice, this list of conditions and the following disclaimer.
  15  * 2. Redistributions in binary form must reproduce the above copyright
  16  *    notice, this list of conditions and the following disclaimer in the
  17  *    documentation and/or other materials provided with the distribution.
  18  * 3. Neither the name of the University nor the names of its contributors
  19  *    may be used to endorse or promote products derived from this software
  20  *    without specific prior written permission.
  21  *
  22  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  23  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  24  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  25  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  26  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  27  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  28  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  29  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  30  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  31  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  32  * SUCH DAMAGE.
  33  *
  34  *      from: @(#)setjmp.s      5.1 (Berkeley) 4/23/90"
  35  */
  36
  37 #include <machine/asm.h>
  38 #if defined(LIBC_SCCS)
  39         RCSID("$NetBSD: sigsetjmp.S,v 1.15 2003/08/07 16:42:07 agc Exp $")
  40 #endif
  41
  42 ENTRY(sigsetjmp)
  43         movl    4(%esp),%ecx
  44         movl    8(%esp),%eax
  45         movl    %eax,28(%ecx)
  46         testl   %eax,%eax
  47         jz      2f
  48
  49         PIC_PROLOGUE
  50         pushl   $0
  51 #ifdef PIC
  52         call    PIC_PLT(_C_LABEL(sigblock))
  53 #else
  54         call    _C_LABEL(sigblock)
  55 #endif
  56         addl    $4,%esp
  57         PIC_EPILOGUE
  58
  59         movl    4(%esp),%ecx
  60         movl    %eax,24(%ecx)
  61 2:      movl    0(%esp),%edx
  62         movl    %edx, 0(%ecx)
  63         movl    %ebx, 4(%ecx)
  64         movl    %esp, 8(%ecx)
  65         movl    %ebp,12(%ecx)
  66         movl    %esi,16(%ecx)
  67         movl    %edi,20(%ecx)
  68         xorl    %eax,%eax
  69         ret
  70
  71 ENTRY(siglongjmp)
  72         movl    4(%esp),%edx
  73         cmpl    $0,28(%edx)
  74         jz      2f
  75
  76         PIC_PROLOGUE
  77         pushl   24(%edx)
  78 #ifdef PIC
  79         call    PIC_PLT(_C_LABEL(sigsetmask))
  80 #else
  81         call    _C_LABEL(sigsetmask)
  82 #endif
  83         addl    $4,%esp
  84         PIC_EPILOGUE
  85
  86 2:      movl    4(%esp),%edx
  87         movl    8(%esp),%eax
  88         movl    0(%edx),%ecx
  89         movl    4(%edx),%ebx
  90         movl    8(%edx),%esp
  91         movl    12(%edx),%ebp
  92         movl    16(%edx),%esi
  93         movl    20(%edx),%edi
  94         testl   %eax,%eax
  95         jnz     3f
  96         incl    %eax
  97 3:      movl    %ecx,0(%esp)
  98         ret