lib/libc/compat/arch/sh3/gen/compat_sigsetjmp.S

   1 /*      $NetBSD: compat_sigsetjmp.S,v 1.4 2006/01/05 04:55:48 uwe Exp $ */
   2
   3 /*-
   4  * Copyright (c) 1990 The Regents of the University of California.
   5  * All rights reserved.
   6  *
   7  * This code is derived from software contributed to Berkeley by
   8  * William Jolitz.
   9  *
  10  * Redistribution and use in source and binary forms, with or without
  11  * modification, are permitted provided that the following conditions
  12  * are met:
  13  * 1. Redistributions of source code must retain the above copyright
  14  *    notice, this list of conditions and the following disclaimer.
  15  * 2. Redistributions in binary form must reproduce the above copyright
  16  *    notice, this list of conditions and the following disclaimer in the
  17  *    documentation and/or other materials provided with the distribution.
  18  * 3. Neither the name of the University nor the names of its contributors
  19  *    may be used to endorse or promote products derived from this software
  20  *    without specific prior written permission.
  21  *
  22  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  23  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  24  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  25  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  26  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  27  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  28  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  29  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  30  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  31  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  32  * SUCH DAMAGE.
  33  *
  34  *      from: @(#)setjmp.s      5.1 (Berkeley) 4/23/90"
  35  */
  36
  37 #include <machine/asm.h>
  38 #include <machine/setjmp.h>
  39
  40 #if defined(LIBC_SCCS)
  41         RCSID("$NetBSD: compat_sigsetjmp.S,v 1.4 2006/01/05 04:55:48 uwe Exp $")
  42 #endif
  43
  44 ENTRY(sigsetjmp)
  45         tst     r5, r5
  46         mov.l   r5, @(_JB_HAS_MASK * 4, r4)
  47         bt      2f                      /* if (savemask == 0) */
  48
  49         PIC_PROLOGUE(.L_got_1)
  50         sts.l   pr, @-sp
  51         mov.l   r4, @-sp
  52
  53         mov.l   .L_sigblock, r0
  54 1:      CALL    r0                      /* int mask = sigblock(0); */
  55          mov    #0, r4
  56
  57         mov.l   @sp+, r4
  58         lds.l   @sp+, pr
  59         PIC_EPILOGUE
  60
  61         mov.l   r0, @(_JB_SIGMASK * 4, r4)
  62
  63 2:      /* identical to _setjmp sans mask */
  64         add     #((_JB_REG_R15 + 1) * 4), r4
  65         mov.l   r15, @-r4
  66         mov.l   r14, @-r4
  67         mov.l   r13, @-r4
  68         mov.l   r12, @-r4
  69         mov.l   r11, @-r4
  70         mov.l   r10, @-r4
  71         mov.l   r9, @-r4
  72         mov.l   r8, @-r4
  73         sts.l   pr, @-r4
  74         rts
  75          xor    r0, r0
  76
  77         .align  2
  78 .L_got_1:       PIC_GOT_DATUM
  79 .L_sigblock:    CALL_DATUM(_C_LABEL(sigblock), 1b)
  80         SET_ENTRY_SIZE(sigsetjmp)
  81
  82
  83 ENTRY(siglongjmp)
  84         mov.l   @(_JB_HAS_MASK * 4, r4), r0
  85         tst     r0, r0
  86         bt      2f                      /* if no mask */
  87
  88         /* we won't return here, so we don't need to save pr and r12 */
  89         PIC_PROLOGUE_NOSAVE(.L_got_2)
  90         mov.l   r5, @-sp
  91         mov.l   r4, @-sp
  92
  93         mov.l   .L_sigsetmask, r0
  94 1:      CALL    r0                      /* sigsetmask(saved mask) */
  95          mov.l  @(_JB_SIGMASK * 4, r4), r4
  96
  97         mov.l   @sp+, r4
  98         mov.l   @sp+, r5
  99
 100 2:      /* identical to _longjmp */
 101         lds.l   @r4+, pr
 102         mov.l   @r4+, r8
 103         mov.l   @r4+, r9
 104         mov.l   @r4+, r10
 105         mov.l   @r4+, r11
 106         mov.l   @r4+, r12
 107         mov.l   @r4+, r13
 108         mov.l   @r4+, r14
 109         mov.l   @r4+, r15
 110
 111         mov     r5, r0
 112         tst     r0, r0  /* make sure return value is non-zero */
 113         bf      .L0
 114         add     #1, r0
 115 .L0:
 116         rts
 117          nop
 118
 119         .align  2
 120 .L_got_2:       PIC_GOT_DATUM
 121 .L_sigsetmask:  CALL_DATUM(_C_LABEL(sigsetmask), 1b)
 122         SET_ENTRY_SIZE(siglongjmp)