lib/libc/net/nslexer.l

   1 %{
   2 /*      $NetBSD: nslexer.l,v 1.8 2008/04/28 20:23:00 martin Exp $       */
   3
   4 /*-
   5  * Copyright (c) 1997, 1998, 1999 The NetBSD Foundation, Inc.
   6  * All rights reserved.
   7  *
   8  * This code is derived from software contributed to The NetBSD Foundation
   9  * by Luke Mewburn.
  10  *
  11  * Redistribution and use in source and binary forms, with or without
  12  * modification, are permitted provided that the following conditions
  13  * are met:
  14  * 1. Redistributions of source code must retain the above copyright
  15  *    notice, this list of conditions and the following disclaimer.
  16  * 2. Redistributions in binary form must reproduce the above copyright
  17  *    notice, this list of conditions and the following disclaimer in the
  18  *    documentation and/or other materials provided with the distribution.
  19  *
  20  * THIS SOFTWARE IS PROVIDED BY THE NETBSD FOUNDATION, INC. AND CONTRIBUTORS
  21  * ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
  22  * TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
  23  * PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE FOUNDATION OR CONTRIBUTORS
  24  * BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
  25  * CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
  26  * SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
  27  * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
  28  * CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
  29  * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
  30  * POSSIBILITY OF SUCH DAMAGE.
  31  */
  32
  33 #include <sys/cdefs.h>
  34 #if defined(LIBC_SCCS) && !defined(lint)
  35 __RCSID("$NetBSD: nslexer.l,v 1.8 2008/04/28 20:23:00 martin Exp $");
  36 #endif /* LIBC_SCCS and not lint */
  37
  38 #include "namespace.h"
  39 #include <ctype.h>
  40 #define _NS_PRIVATE
  41 #include <nsswitch.h>
  42 #include <string.h>
  43 #include <syslog.h>
  44
  45 #include "nsparser.h"
  46
  47 %}
  48
  49 %option yylineno nounput
  50 %option never-interactive
  51
  52 BLANK           [ \t]
  53 CR              \n
  54 STRING          [a-zA-Z][a-zA-Z0-9_]*
  55
  56 %%
  57
  58 {BLANK}+        ;                       /* skip whitespace */
  59
  60 #.*             ;                       /* skip comments */
  61
  62 \\{CR}          ;                       /* allow continuation */
  63
  64 {CR}            return NL;
  65
  66 [sS][uU][cC][cC][eE][sS][sS]            return SUCCESS;
  67 [uU][nN][aA][vV][aA][iI][lL]            return UNAVAIL;
  68 [nN][oO][tT][fF][oO][uU][nN][dD]        return NOTFOUND;
  69 [tT][rR][yY][aA][gG][aA][iI][nN]        return TRYAGAIN;
  70
  71 [rR][eE][tT][uU][rR][nN]                return RETURN;
  72 [cC][oO][nN][tT][iI][nN][uU][eE]        return CONTINUE;
  73
  74 {STRING}        {
  75                         char *p;
  76                         size_t i;
  77
  78                         if ((p = strdup(yytext)) == NULL) {
  79                                 syslog(LOG_ERR, "libc nsdispatch: %m");
  80                                 return NL;
  81                         }
  82
  83                         for (i = 0; i < strlen(p); i++) {
  84                                 if (isupper((unsigned char)p[i]))
  85                                         p[i] = tolower((unsigned char)p[i]);
  86                         }
  87                         _nsyylval.str = p;
  88                         return STRING;
  89                 }
  90
  91 .               return yytext[0];
  92
  93 %%
  94
  95 #undef _nsyywrap
  96 int
  97 _nsyywrap()
  98 {
  99         return 1;
 100 } /* _nsyywrap */
 101
 102 void
 103 _nsyyerror(msg)
 104         const char *msg;
 105 {
 106
 107          syslog(LOG_WARNING, "libc nsdispatch: %s line %d: %s at '%s'",
 108             _PATH_NS_CONF, yylineno, msg, yytext);
 109 } /* _nsyyerror */