sys/arch/evbppc/virtex/virtex_start.S

   1 /*      $NetBSD: virtex_start.S,v 1.3 2009/02/13 22:41:01 apb Exp $ */
   2
   3 /*
   4  * Copyright (c) 2006 Jachym Holecek
   5  * All rights reserved.
   6  *
   7  * Written for DFC Design, s.r.o.
   8  *
   9  * Redistribution and use in source and binary forms, with or without
  10  * modification, are permitted provided that the following conditions
  11  * are met:
  12  *
  13  * 1. Redistributions of source code must retain the above copyright
  14  *    notice, this list of conditions and the following disclaimer.
  15  *
  16  * 2. Redistributions in binary form must reproduce the above copyright
  17  *    notice, this list of conditions and the following disclaimer in the
  18  *    documentation and/or other materials provided with the distribution.
  19  *
  20  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
  21  * IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
  22  * OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
  23  * IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
  24  * INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
  25  * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  26  * DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  27  * THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  28  * (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
  29  * THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  30  */
  31
  32 /*
  33  * This file is based on startup code of Walnut and Explora boards.
  34  */
  35
  36 #define _NOREGNAMES
  37
  38 #include "opt_ddb.h"
  39 #include "opt_ipkdb.h"
  40 #include "opt_lockdebug.h"
  41 #include "opt_modular.h"
  42 #include "opt_multiprocessor.h"
  43 #include "opt_ppcarch.h"
  44 #include "opt_ppcparam.h"
  45 #include "opt_virtex.h"
  46 #include "assym.h"
  47 #include "ksyms.h"
  48
  49 #include <sys/syscall.h>
  50
  51 #include <machine/param.h>
  52 #include <machine/psl.h>
  53 #include <machine/trap.h>
  54 #include <machine/asm.h>
  55
  56 #include <powerpc/spr.h>
  57 #include <powerpc/ibm4xx/dcr405gp.h>
  58 #include <powerpc/ibm4xx/pmap.h>
  59
  60
  61 /* N megabytes. */
  62 #define MB(n)                           ((n)*1024*1024)
  63
  64 /* Set bit (beginning with MSB) for each 128MB of RAM. */
  65 #define PHYSMEM_REGIONS_MASK            ~((1 << (32 - MB(PHYSMEM)/MB(128))) - 1)
  66
  67 /* For kvm_mkdb, supposed to mark the start of kernel text. */
  68         .text
  69         .globl  _C_LABEL(kernel_text)
  70 _C_LABEL(kernel_text):
  71
  72 /* Startup entry. This must be the first thing in the text segment! */
  73         .text
  74         .globl  __start
  75 __start:
  76         /* Disable MMU/exceptions */
  77         lis     %r0, 0
  78         mtmsr   %r0
  79
  80         /* Disable timers */
  81         lis     %r0, 0
  82         mttcr   %r0
  83
  84         sync
  85         isync
  86
  87         /* Disable caches */
  88         mtdccr  %r0
  89         mticcr  %r0
  90         sync
  91         isync
  92
  93         /* Invalidate I$, operands ignored on the 405 */
  94         li      %r0,0                   /* just in case... */
  95         iccci   %r0,%r0
  96
  97         /* Invalidate D$, hardcoded for 16KB size, 32B line */
  98         li      %r7,256                 /* # of congruence classes */
  99         mtctr   %r7
 100         li      %r6,0
 101 1:
 102         dccci   %r0,%r6                 /* invalidates both ways */
 103         addi    %r6,%r6,32
 104         bdnz    1b
 105
 106         /*
 107          * Errata 213:  Incorrect data may be flushed from the data cache.
 108          * Cores:       PPC405D5X1, PPC405D5X2
 109          * Workaround:  #1, CCR0 modification sequence #2
 110          * Note:        Meaning of bits we need to set is undocumented.
 111          */
 112         sync
 113         mfccr0  %r0
 114         oris    %r0,%r0,0x50000000@h
 115         mtccr0  %r0
 116         isync
 117
 118         /*
 119          * Errata  58:  Load string instructions may write incorrect
 120          *              data into the last GPR targeted in operation.
 121          * Cores:       PPC405GP
 122          * Workaround:  set OCM0_DSCNTL[DSEN]=0 and OCM0_DSCNTL[DOF]=0
 123          */
 124         mtdcr   DCR_OCM0_DSCNTL,%r0    /* Disable Data access to OCM */
 125
 126 #if 0
 127         /* Allow cacheing for whole RAM. */
 128         lis     %r0,PHYSMEM_REGIONS_MASK@ha
 129         ori     %r0,%r0,PHYSMEM_REGIONS_MASK@l
 130 #else
 131 #ifndef PPC_4XX_NOCACHE
 132         /* Allow cacheing for only the first 1GB of RAM */
 133         lis     %r0,0xff00
 134         mtdccr  %r0
 135         mticcr  %r0
 136 #endif /* PPC_4XX_NOCACHE */
 137 #endif
 138
 139         /* Invalidate all TLB entries */
 140         tlbia
 141         sync
 142         isync
 143
 144         /* Set kernel MMU context, we'll enable MMU in initppc() */
 145         li      %r0,KERNEL_PID
 146         mtpid   %r0
 147         sync
 148         isync
 149
 150         /* Setup endkernel argument for initppc() and INIT_CPUINFO */
 151         lis     %r4,_C_LABEL(end)@h
 152         ori     %r4,%r4,_C_LABEL(end)@l
 153
 154         /* Clear .bss segment */
 155         lis     %r7,_C_LABEL(edata)-4@h
 156         ori     %r7,%r7,_C_LABEL(edata)-4@l
 157         li      %r3,0
 158 2:      stwu    %r3,4(%r7)
 159         cmpw    %r7,%r4
 160         bne+    2b
 161
 162 #if NKSYMS || defined(DDB) || defined(MODULAR)
 163         /* We don't have a symbol table, so set startsym = endsym = end */
 164         lis     %r7,_C_LABEL(startsym)@ha
 165         ori     %r7,%r7,_C_LABEL(startsym)@l
 166         stw     %r4,0(%r7)
 167         lis     %r7,_C_LABEL(endsym)@ha
 168         ori     %r7,%r7,_C_LABEL(endsym)@l
 169         stw     %r4,0(%r7)
 170 #endif
 171
 172         /* INIT_CPUINFO will 'addi', so clean up. */
 173         lis     %r1,0
 174
 175         INIT_CPUINFO(4,1,9,0)
 176
 177         /* startkernel argument for initppc */
 178         lis     %r3,__start@h
 179         addi    %r3,%r3,__start@l
 180
 181         bl      _C_LABEL(initppc)
 182         bl      _C_LABEL(main)
 183
 184 loop:   /* UNREACHED */
 185         b       loop
 186
 187 #include <powerpc/ibm4xx/4xx_locore.S>