sys/arch/ews4800mips/stand/common/coffboot.ldscript

   1 OUTPUT_FORMAT("ecoff-bigmips")
   2 OUTPUT_ARCH(mips)
   3 ENTRY(start)
   4
   5 /*
   6  * 0xa0190000 : EWS-UX 1stboot /usr/lib/boot
   7  * 0xa0700000 : EWS-UX 2ndboot /stand/iopboot
   8  *
   9  * EWS4800/350 IPL tftp booter can load COFF OMAGIC file only.
  10  */
  11
  12 MEMORY {
  13         ram     : o = 0xa0a00000, l = 8M
  14 }
  15
  16 SECTIONS {
  17         . = 0xa0a00000;
  18         .text ALIGN(4) :
  19         {
  20                 _ftext = .;
  21                 *(.text)
  22                 _etext = .;
  23         } > ram
  24         .data ALIGN(4) :
  25         {
  26                 _fdata = .;
  27                 *(.rodata)
  28                 *(.data)
  29                 _edata = .;
  30         } > ram
  31         .bss ALIGN(4) :
  32         {
  33                 _fbss = .;
  34                 *(.bss)
  35                 *(.*)
  36                 _ebss = .;
  37         } > ram
  38         end = .;        /* libsa/alloc.c use this symbol */
  39 }