external/bsd/libelf/dist/libelf_fsize.m4

   1 /*      $NetBSD: libelf_fsize.m4,v 1.2 2009/12/19 07:31:04 thorpej Exp $        */
   2
   3 /*-
   4  * Copyright (c) 2006 Joseph Koshy
   5  * All rights reserved.
   6  *
   7  * Redistribution and use in source and binary forms, with or without
   8  * modification, are permitted provided that the following conditions
   9  * are met:
  10  * 1. Redistributions of source code must retain the above copyright
  11  *    notice, this list of conditions and the following disclaimer.
  12  * 2. Redistributions in binary form must reproduce the above copyright
  13  *    notice, this list of conditions and the following disclaimer in the
  14  *    documentation and/or other materials provided with the distribution.
  15  *
  16  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR AND CONTRIBUTORS ``AS IS'' AND
  17  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  18  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  19  * ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE LIABLE
  20  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  21  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  22  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  23  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  24  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  25  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  26  * SUCH DAMAGE.
  27  *
  28  * $FreeBSD: src/lib/libelf/libelf_fsize.m4,v 1.2.10.1.2.1 2009/10/25 01:10:29 kensmith Exp $
  29  */
  30
  31 #include <libelf.h>
  32
  33 #include "_libelf.h"
  34
  35 /*
  36  * Create an array of file sizes from the elf_type definitions
  37  */
  38
  39 divert(-1)
  40 include(SRCDIR`/elf_types.m4')
  41
  42 /*
  43  * Translations from structure definitions to the size of their file
  44  * representations.
  45  */
  46
  47 /* `Basic' types */
  48 define(`BYTE_SIZE',     1)
  49 define(`IDENT_SIZE',    `EI_NIDENT')
  50 define(`NOTE_SIZE',     1) /* Elf_Note structures have variable length. */
  51
  52 /* Currently unimplemented types */
  53 define(`MOVEP_SIZE',    0)
  54
  55 /* Overrides for 32 bit types that do not exist */
  56 define(`XWORD_SIZE32',  0)
  57 define(`SXWORD_SIZE32', 0)
  58
  59 /*
  60  * FSZ{32,64} define the sizes of 32 and 64 bit file structures respectively.
  61  */
  62
  63 define(`FSZ32',`_FSZ32($1_DEF)')
  64 define(`_FSZ32',
  65   `ifelse($#,1,0,
  66     `_BSZ32($1)+_FSZ32(shift($@))')')
  67 define(`_BSZ32',`$2_SIZE32')
  68
  69 define(`FSZ64',`_FSZ64($1_DEF)')
  70 define(`_FSZ64',
  71   `ifelse($#,1,0,
  72     `_BSZ64($1)+_FSZ64(shift($@))')')
  73 define(`_BSZ64',`$2_SIZE64')
  74
  75 /*
  76  * DEFINE_ELF_FSIZES(TYPE,NAME)
  77  *
  78  * Shorthand for defining  for 32 and 64 versions
  79  * of elf type TYPE.
  80  *
  81  * If TYPE`'_SIZE is defined, use its value for both 32 bit and 64 bit
  82  * sizes.
  83  *
  84  * Otherwise, look for a explicit 32/64 bit size definition for TYPE,
  85  * TYPE`'_SIZE32 or TYPE`'_SIZE64. If this definition is present, there
  86  * is nothing further to do.
  87  *
  88  * Otherwise, if an Elf{32,64}_`'NAME structure definition is known,
  89  * compute an expression that adds up the sizes of the structure's
  90  * constituents.
  91  *
  92  * If such a structure definition is not known, treat TYPE as a primitive
  93  * (i.e., integral) type and use sizeof(Elf{32,64}_`'NAME) to get its
  94  * file representation size.
  95  */
  96
  97 define(`DEFINE_ELF_FSIZE',
  98   `ifdef($1`_SIZE',
  99     `define($1_SIZE32,$1_SIZE)
 100      define($1_SIZE64,$1_SIZE)',
 101     `ifdef($1`_SIZE32',`',
 102       `ifdef(`Elf32_'$2`_DEF',
 103         `define($1_SIZE32,FSZ32(Elf32_$2))',
 104         `define($1_SIZE32,`sizeof(Elf32_'$2`)')')')
 105      ifdef($1`_SIZE64',`',
 106       `ifdef(`Elf64_'$2`_DEF',
 107         `define($1_SIZE64,FSZ64(Elf64_$2))',
 108         `define($1_SIZE64,`sizeof(Elf64_'$2`)')')')')')
 109
 110 define(`DEFINE_ELF_FSIZES',
 111   `ifelse($#,1,`',
 112     `DEFINE_ELF_FSIZE($1)
 113      DEFINE_ELF_FSIZES(shift($@))')')
 114
 115 DEFINE_ELF_FSIZES(ELF_TYPE_LIST)
 116 DEFINE_ELF_FSIZE(`IDENT',`')    # `IDENT' is a pseudo type
 117
 118 define(`FSIZE',
 119   `#if  $3
 120     [ELF_T_$1] = { .fsz32 = $1_SIZE32, .fsz64 = $1_SIZE64 },
 121 #endif')
 122 define(`FSIZES',
 123   `ifelse($#,1,`',
 124     `FSIZE($1)
 125 FSIZES(shift($@))')')
 126
 127 divert(0)
 128
 129 struct fsize {
 130         size_t fsz32;
 131         size_t fsz64;
 132 };
 133
 134 static struct fsize fsize[ELF_T_NUM] = {
 135 FSIZES(ELF_TYPE_LIST)
 136 };
 137
 138 size_t
 139 _libelf_fsize(Elf_Type t, int ec, unsigned int v, size_t c)
 140 {
 141         size_t sz;
 142
 143         sz = 0;
 144         if (v != EV_CURRENT)
 145                 LIBELF_SET_ERROR(VERSION, 0);
 146         else if ((int) t < ELF_T_FIRST || t > ELF_T_LAST)
 147                 LIBELF_SET_ERROR(ARGUMENT, 0);
 148         else {
 149                 sz = ec == ELFCLASS64 ? fsize[t].fsz64 : fsize[t].fsz32;
 150                 if (sz == 0)
 151                         LIBELF_SET_ERROR(UNIMPL, 0);
 152         }
 153
 154         return (sz*c);
 155 }
 156