external/gpl2/xcvs/dist/m4/getline.m4

   1 # getline.m4 serial 13
   2
   3 dnl Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2005 Free Software
   4 dnl Foundation, Inc.
   5 dnl
   6 dnl This file is free software; the Free Software Foundation
   7 dnl gives unlimited permission to copy and/or distribute it,
   8 dnl with or without modifications, as long as this notice is preserved.
   9
  10 AC_PREREQ(2.52)
  11
  12 dnl See if there's a working, system-supplied version of the getline function.
  13 dnl We can't just do AC_REPLACE_FUNCS(getline) because some systems
  14 dnl have a function by that name in -linet that doesn't have anything
  15 dnl to do with the function we need.
  16 AC_DEFUN([gl_FUNC_GETLINE],
  17 [
  18   AC_LIBSOURCES([getline.c, getline.h])
  19
  20   dnl Persuade glibc <stdio.h> to declare getline().
  21   AC_REQUIRE([AC_GNU_SOURCE])
  22
  23   AC_CHECK_DECLS([getline])
  24
  25   gl_getline_needs_run_time_check=no
  26   AC_CHECK_FUNC(getline,
  27                 dnl Found it in some library.  Verify that it works.
  28                 gl_getline_needs_run_time_check=yes,
  29                 am_cv_func_working_getline=no)
  30   if test $gl_getline_needs_run_time_check = yes; then
  31     AC_CACHE_CHECK([for working getline function], am_cv_func_working_getline,
  32     [echo fooN |tr -d '\012'|tr N '\012' > conftest.data
  33     AC_TRY_RUN([
  34 #    include <stdio.h>
  35 #    include <stdlib.h>
  36 #    include <string.h>
  37     int main ()
  38     { /* Based on a test program from Karl Heuer.  */
  39       char *line = NULL;
  40       size_t siz = 0;
  41       int len;
  42       FILE *in = fopen ("./conftest.data", "r");
  43       if (!in)
  44         return 1;
  45       len = getline (&line, &siz, in);
  46       exit ((len == 4 && line && strcmp (line, "foo\n") == 0) ? 0 : 1);
  47     }
  48     ], am_cv_func_working_getline=yes dnl The library version works.
  49     , am_cv_func_working_getline=no dnl The library version does NOT work.
  50     , am_cv_func_working_getline=no dnl We're cross compiling.
  51     )])
  52   fi
  53
  54   if test $am_cv_func_working_getline = no; then
  55     dnl We must choose a different name for our function, since on ELF systems
  56     dnl a broken getline() in libc.so would override our getline() in
  57     dnl libgettextlib.so.
  58     AC_DEFINE([getline], [gnu_getline],
  59       [Define to a replacement function name for getline().])
  60     AC_LIBOBJ(getline)
  61
  62     gl_PREREQ_GETLINE
  63   fi
  64 ])
  65
  66 # Prerequisites of lib/getline.c.
  67 AC_DEFUN([gl_PREREQ_GETLINE],
  68 [
  69   gl_FUNC_GETDELIM
  70 ])