crypto/dist/heimdal/cf/auth-modules.m4

   1 dnl $Heimdal: auth-modules.m4 13338 2004-02-12 14:21:14Z lha $
   2 dnl $NetBSD$
   3 dnl
   4 dnl Figure what authentication modules should be built
   5 dnl
   6 dnl rk_AUTH_MODULES(module-list)
   7
   8 AC_DEFUN([rk_AUTH_MODULES],[
   9 AC_MSG_CHECKING([which authentication modules should be built])
  10
  11 z='m4_ifval([$1], $1, [sia pam afskauthlib])'
  12 LIB_AUTH_SUBDIRS=
  13 for i in $z; do
  14 case $i in
  15 sia)
  16 if test "$ac_cv_header_siad_h" = yes; then
  17         LIB_AUTH_SUBDIRS="$LIB_AUTH_SUBDIRS sia"
  18 fi
  19 ;;
  20 pam)
  21 case "${host}" in
  22 *-*-freebsd*)   ac_cv_want_pam_krb4=no ;;
  23 *)              ac_cv_want_pam_krb4=yes ;;
  24 esac
  25
  26 if test "$ac_cv_want_pam_krb4" = yes -a \
  27     "$ac_cv_header_security_pam_modules_h" = yes -a \
  28     "$enable_shared" = yes; then
  29         LIB_AUTH_SUBDIRS="$LIB_AUTH_SUBDIRS pam"
  30 fi
  31 ;;
  32 afskauthlib)
  33 case "${host}" in
  34 *-*-irix[[56]]*) LIB_AUTH_SUBDIRS="$LIB_AUTH_SUBDIRS afskauthlib" ;;
  35 esac
  36 ;;
  37 esac
  38 done
  39 if test "$LIB_AUTH_SUBDIRS"; then
  40         AC_MSG_RESULT($LIB_AUTH_SUBDIRS)
  41 else
  42         AC_MSG_RESULT(none)
  43 fi
  44
  45 AC_SUBST(LIB_AUTH_SUBDIRS)dnl
  46 ])