crypto/dist/heimdal/cf/krb-func-getcwd-broken.m4

   1 dnl $Heimdal: krb-func-getcwd-broken.m4 15455 2005-06-16 21:03:43Z lha $
   2 dnl $NetBSD$
   3 dnl
   4 dnl
   5 dnl test for broken getcwd in (SunOS braindamage)
   6 dnl
   7
   8 AC_DEFUN([AC_KRB_FUNC_GETCWD_BROKEN], [
   9 if test "$ac_cv_func_getcwd" = yes; then
  10 AC_MSG_CHECKING(if getcwd is broken)
  11 AC_CACHE_VAL(ac_cv_func_getcwd_broken, [
  12 ac_cv_func_getcwd_broken=no
  13
  14 AC_RUN_IFELSE([AC_LANG_SOURCE([[
  15 #include <errno.h>
  16 char *getcwd(char*, int);
  17
  18 void *popen(char *cmd, char *mode)
  19 {
  20         errno = ENOTTY;
  21         return 0;
  22 }
  23
  24 int main(int argc, char **argv)
  25 {
  26         char *ret;
  27         ret = getcwd(0, 1024);
  28         if(ret == 0 && errno == ENOTTY)
  29                 return 0;
  30         return 1;
  31 }
  32 ]])], [ac_cv_func_getcwd_broken=yes],[:],[:])
  33 ])
  34 if test "$ac_cv_func_getcwd_broken" = yes; then
  35         AC_DEFINE(BROKEN_GETCWD, 1, [Define if getcwd is broken (like in SunOS 4).])dnl
  36         AC_LIBOBJ(getcwd)
  37         AC_MSG_RESULT($ac_cv_func_getcwd_broken)
  38 else
  39         AC_MSG_RESULT([seems ok])
  40 fi
  41 fi
  42 ])