crypto/dist/heimdal/cf/telnet.m4

   1 dnl
   2 dnl $Heimdal: telnet.m4 15435 2005-06-16 19:45:52Z lha $
   3 dnl $NetBSD$
   4 dnl
   5 dnl stuff used by telnet
   6
   7 AC_DEFUN([rk_TELNET],[
   8 AC_DEFINE(AUTHENTICATION, 1,
   9         [Define if you want authentication support in telnet.])dnl
  10 AC_DEFINE(ENCRYPTION, 1,
  11         [Define if you want encryption support in telnet.])dnl
  12 AC_DEFINE(DES_ENCRYPTION, 1,
  13         [Define if you want to use DES encryption in telnet.])dnl
  14 AC_DEFINE(DIAGNOSTICS, 1,
  15         [Define this to enable diagnostics in telnet.])dnl
  16 AC_DEFINE(OLD_ENVIRON, 1,
  17         [Define this to enable old environment option in telnet.])dnl
  18 if false; then
  19         AC_DEFINE(ENV_HACK, 1,
  20                 [Define this if you want support for broken ENV_{VAR,VAL} telnets.])
  21 fi
  22
  23 # Simple test for streamspty, based on the existance of getmsg(), alas
  24 # this breaks on SunOS4 which have streams but BSD-like ptys
  25 #
  26 # And also something wierd has happend with dec-osf1, fallback to bsd-ptys
  27
  28 case "$host" in
  29 *-*-aix3*|*-*-sunos4*|*-*-osf*|*-*-hpux1[[01]]*)
  30         ;;
  31 *)
  32         AC_CHECK_FUNC(getmsg)
  33         if test "$ac_cv_func_getmsg" = "yes"; then
  34                 AC_CACHE_CHECK([if getmsg works], ac_cv_func_getmsg_works,
  35                 AC_RUN_IFELSE([AC_LANG_SOURCE([[
  36                         #include <stdio.h>
  37                         #include <errno.h>
  38
  39                         int main(int argc, char **argv)
  40                         {
  41                           int ret;
  42                           ret = getmsg(open("/dev/null", 0), NULL, NULL, NULL);
  43                           if(ret < 0 && errno == ENOSYS)
  44                             return 1;
  45                           return 0;
  46                         }
  47                         ]])], [ac_cv_func_getmsg_works=yes],
  48                         [ac_cv_func_getmsg_works=no],
  49                         [ac_cv_func_getmsg_works=no]))
  50                 if test "$ac_cv_func_getmsg_works" = "yes"; then
  51                         AC_DEFINE(HAVE_GETMSG, 1,
  52                                 [Define if you have a working getmsg.])
  53                         AC_DEFINE(STREAMSPTY, 1,
  54                                 [Define if you have streams ptys.])
  55                 fi
  56         fi
  57         ;;
  58 esac
  59
  60 AH_BOTTOM([
  61 #if defined(ENCRYPTION) && !defined(AUTHENTICATION)
  62 #define AUTHENTICATION 1
  63 #endif
  64
  65 /* Set this to the default system lead string for telnetd
  66  * can contain %-escapes: %s=sysname, %m=machine, %r=os-release
  67  * %v=os-version, %t=tty, %h=hostname, %d=date and time
  68  */
  69 #undef USE_IM
  70
  71 /* Used with login -p */
  72 #undef LOGIN_ARGS
  73
  74 /* set this to a sensible login */
  75 #ifndef LOGIN_PATH
  76 #define LOGIN_PATH BINDIR "/login"
  77 #endif
  78 ])
  79 ])