crypto/dist/heimdal/cf/with-all.m4

   1 dnl
   2 dnl $Heimdal: with-all.m4 14147 2004-08-25 14:14:01Z joda $
   3 dnl $NetBSD$
   4 dnl
   5
   6 dnl AC_WITH_ALL(name)
   7
   8 AC_DEFUN([AC_WITH_ALL], [
   9 AC_ARG_WITH($1,
  10         AS_HELP_STRING([--with-$1=dir],
  11                 [use $1 in dir]))
  12
  13 AC_ARG_WITH($1-lib,
  14         AS_HELP_STRING([--with-$1-lib=dir],
  15                 [use $1 libraries in dir]),
  16 [if test "$withval" = "yes" -o "$withval" = "no"; then
  17   AC_MSG_ERROR([No argument for --with-$1-lib])
  18 elif test "X$with_$1" = "X"; then
  19   with_$1=yes
  20 fi])
  21
  22 AC_ARG_WITH($1-include,
  23         AS_HELP_STRING([--with-$1-include=dir],
  24                 [use $1 headers in dir]),
  25 [if test "$withval" = "yes" -o "$withval" = "no"; then
  26   AC_MSG_ERROR([No argument for --with-$1-include])
  27 elif test "X$with_$1" = "X"; then
  28   with_$1=yes
  29 fi])
  30
  31 case "$with_$1" in
  32 yes)    ;;
  33 no)     ;;
  34 "")     ;;
  35 *)      if test "$with_$1_include" = ""; then
  36                 with_$1_include="$with_$1/include"
  37         fi
  38         if test "$with_$1_lib" = ""; then
  39                 with_$1_lib="$with_$1/lib$abilibdirext"
  40         fi
  41         ;;
  42 esac
  43 ])