external/bsd/am-utils/dist/m4/macros/check_autofs_style.m4

   1 dnl ######################################################################
   2 dnl check the autofs flavor
   3 AC_DEFUN([AMU_CHECK_AUTOFS_STYLE],
   4 [
   5 AC_CACHE_CHECK(autofs style,
   6 ac_cv_autofs_style,
   7 [
   8 # select the correct style to mount(2) a filesystem
   9 case "${host_os}" in
  10        solaris1* | solaris2.[[0-4]] )
  11                ac_cv_autofs_style=default ;;
  12        solaris2.5* )
  13                ac_cv_autofs_style=solaris_v1 ;;
  14        # Solaris 8+ uses the AutoFS V3/V4 protocols, but they are very similar
  15        # to V2, so use one style for all.
  16        solaris* )
  17                ac_cv_autofs_style=solaris_v2_v3 ;;
  18        irix6* )
  19                ac_cv_autofs_style=solaris_v1 ;;
  20        linux* )
  21                ac_cv_autofs_style=linux ;;
  22        * )
  23                ac_cv_autofs_style=default ;;
  24 esac
  25 ])
  26 # always make a link and include the file name, otherwise on systems where
  27 # autofs support has not been ported yet check_fs_{headers, mntent}.m4 add
  28 # ops_autofs.o to AMD_FS_OBJS, but there's no way to build it.
  29 am_utils_link_files=${am_utils_link_files}amd/ops_autofs.c:conf/autofs/autofs_${ac_cv_autofs_style}.c" "amu_autofs_prot.h:conf/autofs/autofs_${ac_cv_autofs_style}.h" "
  30
  31 # set headers in a macro for Makefile.am files to use (for dependencies)
  32 AMU_AUTOFS_PROT_HEADER='${top_builddir}/'amu_autofs_prot.h
  33 AC_SUBST(AMU_AUTOFS_PROT_HEADER)
  34 ])
  35 dnl ======================================================================