external/bsd/am-utils/dist/m4/macros/check_mnt2_cdfs_opt.m4

   1 dnl ######################################################################
   2 dnl Find CDFS-specific mount(2) options (hex numbers)
   3 dnl Usage: AMU_CHECK_MNT2_CDFS_OPT(<fs>)
   4 dnl Check if there is an entry for MS_<fs> or M_<fs> in sys/mntent.h or
   5 dnl mntent.h, then define MNT2_CDFS_OPT_<fs> to the hex number.
   6 AC_DEFUN([AMU_CHECK_MNT2_CDFS_OPT],
   7 [
   8 # what name to give to the fs
   9 ac_fs_name=$1
  10 # store variable name of fs
  11 ac_upcase_fs_name=`echo $ac_fs_name | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
  12 ac_safe=MNT2_CDFS_OPT_$ac_upcase_fs_name
  13 # check for cache and set it if needed
  14 AMU_CACHE_CHECK_DYNAMIC(for CDFS-specific mount(2) option $ac_fs_name,
  15 ac_cv_mnt2_cdfs_opt_$ac_fs_name,
  16 [
  17 # undefine by default
  18 eval "ac_cv_mnt2_cdfs_opt_$ac_fs_name=notfound"
  19 value=notfound
  20
  21 # first, try MS_* (most systems).  Must be the first test!
  22 if test "$value" = notfound
  23 then
  24 AMU_EXPAND_CPP_HEX(
  25 AMU_MOUNT_HEADERS
  26 , MS_$ac_upcase_fs_name)
  27 fi
  28
  29 # if failed, try MNT_* (bsd44 systems)
  30 if test "$value" = notfound
  31 then
  32 AMU_EXPAND_CPP_HEX(
  33 AMU_MOUNT_HEADERS
  34 , MNT_$ac_upcase_fs_name)
  35 fi
  36
  37 # if failed, try MS_*  as an integer (linux systems)
  38 if test "$value" = notfound
  39 then
  40 AMU_EXPAND_CPP_INT(
  41 AMU_MOUNT_HEADERS
  42 , MS_$ac_upcase_fs_name)
  43 fi
  44
  45 # If failed try M_* (must be last test since svr4 systems define M_DATA etc.
  46 # in <sys/stream.h>
  47 # This test was off for now, because of the conflicts with other systems.
  48 # but I turned it back on by faking the inclusion of <sys/stream.h> already.
  49 if test "$value" = notfound
  50 then
  51 AMU_EXPAND_CPP_HEX(
  52 #ifndef _sys_stream_h
  53 # define _sys_stream_h
  54 #endif /* not _sys_stream_h */
  55 #ifndef _SYS_STREAM_H
  56 # define _SYS_STREAM_H
  57 #endif  /* not _SYS_STREAM_H */
  58 AMU_MOUNT_HEADERS
  59 , M_$ac_upcase_fs_name)
  60 fi
  61
  62 # if failed, try ISOFSMNT_* as a hex (bsdi4 systems)
  63 if test "$value" = notfound
  64 then
  65 AMU_EXPAND_CPP_HEX(
  66 AMU_MOUNT_HEADERS
  67 , ISOFSMNT_$ac_upcase_fs_name)
  68 fi
  69
  70 # set cache variable to value
  71 eval "ac_cv_mnt2_cdfs_opt_$ac_fs_name=$value"
  72 ])
  73 # outside cache check, if ok, define macro
  74 ac_tmp=`eval echo '$''{ac_cv_mnt2_cdfs_opt_'$ac_fs_name'}'`
  75 if test "${ac_tmp}" != notfound
  76 then
  77   AC_DEFINE_UNQUOTED($ac_safe, $ac_tmp)
  78 fi
  79 ])
  80 dnl ======================================================================
  81
  82 dnl ######################################################################
  83 dnl run AMU_CHECK_MNT2_CDFS_OPT on each argument given
  84 dnl Usage: AMU_CHECK_MNT2_CDFS_OPTS(arg arg arg ...)
  85 AC_DEFUN([AMU_CHECK_MNT2_CDFS_OPTS],
  86 [
  87 for ac_tmp_arg in $1
  88 do
  89 AMU_CHECK_MNT2_CDFS_OPT($ac_tmp_arg)
  90 done
  91 ])
  92 dnl ======================================================================