external/bsd/am-utils/dist/m4/macros/check_mnttab_file_name.m4

   1 dnl ######################################################################
   2 dnl Find name of mount table file, and define it as MNTTAB_FILE_NAME
   3 dnl
   4 dnl Solaris defines MNTTAB as /etc/mnttab, the file where /sbin/mount
   5 dnl stores its cache of mounted filesystems.  But under SunOS, the same
   6 dnl macro MNTTAB, is defined as the _source_ of filesystems to mount, and
   7 dnl is set to /etc/fstab.  That is why I have to first check out
   8 dnl if MOUNTED exists, and if not, check for the MNTTAB macro.
   9 dnl
  10 AC_DEFUN([AMU_CHECK_MNTTAB_FILE_NAME],
  11 [
  12 AC_CACHE_CHECK(for name of mount table file name,
  13 ac_cv_mnttab_file_name,
  14 [
  15 # expand cpp value for MNTTAB
  16 AMU_EXPAND_CPP_STRING(
  17 AMU_MOUNT_HEADERS(
  18 [
  19 /* see M4 comment at the top of the definition of this macro */
  20 #ifdef MOUNTED
  21 # define _MNTTAB_FILE_NAME MOUNTED
  22 # else /* not MOUNTED */
  23 # ifdef MNTTAB
  24 #  define _MNTTAB_FILE_NAME MNTTAB
  25 # endif /* MNTTAB */
  26 #endif /* not MOUNTED */
  27 ]),
  28 _MNTTAB_FILE_NAME,
  29 [ ac_cv_mnttab_file_name=$value
  30 ],
  31 [
  32 ac_cv_mnttab_file_name=notfound
  33 # check explicitly for /etc/mnttab
  34 if test "$ac_cv_mnttab_file_name" = notfound
  35 then
  36   if test -f /etc/mnttab
  37   then
  38     ac_cv_mnttab_file_name="/etc/mnttab"
  39   fi
  40 fi
  41 # check explicitly for /etc/mtab
  42 if test "$ac_cv_mnttab_file_name" = notfound
  43 then
  44   if test -f /etc/mtab
  45   then
  46     ac_cv_mnttab_file_name="/etc/mtab"
  47   fi
  48 fi
  49 ])
  50 ])
  51 # test value and create macro as needed
  52 if test "$ac_cv_mnttab_file_name" != notfound
  53 then
  54   AC_DEFINE_UNQUOTED(MNTTAB_FILE_NAME, "$ac_cv_mnttab_file_name")
  55 fi
  56 ])
  57 dnl ======================================================================